Flash の描画について(Flash 6 以降)

// ------------------------------------------------------------
// オブジェクトを作成
// ------------------------------------------------------------
var mtx = new Object();

// ------------------------------------------------------------
// 行列のタイプ
// ------------------------------------------------------------
mtx.matrixType = "box";

// ------------------------------------------------------------
// グラデーションの矩形
// ------------------------------------------------------------
mtx.x =   0; // x 座標
mtx.y =   0; // y 座標
mtx.w = 400; // 幅
mtx.h = 300; // 高さ

// ------------------------------------------------------------
// グラデーションの角度（ラジアン）
// ------------------------------------------------------------
mtx.r = 60 * (Math.PI / 180);

import flash.geom.Matrix;

// ------------------------------------------------------------
// 行列を作成
// ------------------------------------------------------------
var mtx:Matrix = new Matrix();

// ------------------------------------------------------------
// グラデーションを矩形の中に収める行列を生成
// ------------------------------------------------------------
mtx.createGradientBox(
	400, // 幅
	300, // 高さ
	60 * (Math.PI / 180), // 角度（ラジアン）
	0, // x 座標
	0  // y 座標
);

// ------------------------------------------------------------
// オブジェクトを作成
// ------------------------------------------------------------
var mtx = new Object();

// ------------------------------------------------------------
// 単位行列化
// ------------------------------------------------------------
mtx.a = 1.0; mtx.b = 0.0; mtx.c = 0.0;
mtx.d = 0.0; mtx.e = 1.0; mtx.f = 0.0;
mtx.g = 0.0; mtx.h = 0.0; mtx.i = 1.0;

import flash.geom.Matrix;

// ------------------------------------------------------------
// 行列を作成
// ------------------------------------------------------------
var mtx:Matrix = new Matrix();

// 単位行列化
mtx.identity();

// 拡大縮小成分を乗算
mtx.scale( 1.0/1638.4 , 1.0/1638.4 );

// 角度成分を乗算
mtx.rotate( 0.0 * (Math.PI / 180) );

// 移動成分を乗算
mtx.translate( 0.0 , 0.0 );

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineStyle(10 , 0x000000 , 100);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
mc.moveTo (  10.0 ,  10.0 );
// 終了位置
mc.lineTo ( 100.0 ,  50.0 );

// ------------------------------------------------------------
// 描画済みグラフィックをすべてクリアする
// ------------------------------------------------------------
mc.clear();

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineStyle (10 , 0x000000 , 100);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
mc.moveTo (  10.0 ,  10.0 );
// 直線を描画
mc.lineTo ( 100.0 ,  50.0 );

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線の単一色塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness = 20;
// 線の色 (RGBカラー値)
var line_color = 0x000000;
// 線の透明度 (0 ～ 100)
var line_alpha = 100;
// ヒンティングの有無
var pixel_hinting = true;
// スケールモード
var scale_mode = "normal";
// 線先の種類
var caps_style = "square";
// 角の種類
var joints_style = "miter";
// マイターの尖りの延長サイズ (1.0 ～)
var miter_limit = 255;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineStyle ( thickness , line_color , line_alpha , pixel_hinting , scale_mode , caps_style , joints_style , miter_limit );

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
mc.moveTo (  20.0 ,  20.0 );
// 直線を描画
mc.lineTo ( 200.0 , 100.0 );
// 直線を描画
mc.lineTo (  20.0 , 100.0 );

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc:MovieClip = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線の単一色塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 20;
// 線の色 (RGBカラー値)
var line_color:Number = 0x000000;
// 線の透明度 (0 ～ 100)
var line_alpha:Number = 100;
// ヒンティングの有無
var pixel_hinting:Boolean = true;
// スケールモード
var scale_mode:String = "normal";
// 線先の種類
var caps_style:String = "square";
// 角の種類
var joints_style:String = "miter";
// マイターの尖りの延長サイズ (1.0 ～)
var miter_limit:Number = 255;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineStyle ( thickness , line_color , line_alpha , pixel_hinting , scale_mode , caps_style , joints_style , miter_limit );

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
mc.moveTo (  20.0 ,  20.0 );
// 直線を描画
mc.lineTo ( 200.0 , 100.0 );
// 直線を描画
mc.lineTo (  20.0 , 100.0 );

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線のグラデーション塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness = 30;
// グラデーションの種類
var gradient_type = "radial";
// グラデーション
var gradient_colors = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas = [      100 ,      100 ,      100 ];	// 透明度リスト
var gradient_ratios = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx = new flash.geom.Matrix();
// スプレッドの種類
var spread_method = "pad";
// 補間の種類
var interpolation_method = "linearRGB";
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio = 0.0;

// ------------------------------------------------------------
// グラデーションの行列
// ------------------------------------------------------------
// 単位行列化
gradient_mtx.identity();
// 拡大縮小成分を乗算
gradient_mtx.scale( 256/1638.4 , 256/1638.4 );
// 角度成分を乗算
gradient_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
gradient_mtx.translate( 128.0 , 128.0 );

// ------------------------------------------------------------
// 線の基礎的なスタイルを指定する
// ------------------------------------------------------------
mc.lineStyle( thickness );

// ------------------------------------------------------------
// 線に「グラデーション塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineGradientStyle( gradient_type , gradient_colors , gradient_alphas , gradient_ratios , gradient_mtx , spread_method , interpolation_method , focal_point_ratio );

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
var i = 0;
for(i=0;i < 8;i++){

	var pos_y = i * 32.0 + 16.0;

	// 開始位置
	mc.moveTo (   0.0 , pos_y );
	// 直線を描画
	mc.lineTo ( 256.0 , pos_y );
}

import flash.geom.Matrix;

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc:MovieClip = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線のグラデーション塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 30;
// グラデーションの種類
var gradient_type:String = "radial";
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [      100 ,      100 ,      100 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = "pad";
// 補間の種類
var interpolation_method:String = "linearRGB";
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// グラデーションの行列
// ------------------------------------------------------------
// 単位行列化
gradient_mtx.identity();
// 拡大縮小成分を乗算
gradient_mtx.scale( 256/1638.4 , 256/1638.4 );
// 角度成分を乗算
gradient_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
gradient_mtx.translate( 128.0 , 128.0 );

// ------------------------------------------------------------
// 線の基礎的なスタイルを指定する
// ------------------------------------------------------------
mc.lineStyle( thickness );

// ------------------------------------------------------------
// 線に「グラデーション塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineGradientStyle( gradient_type , gradient_colors , gradient_alphas , gradient_ratios , gradient_mtx , spread_method , interpolation_method , focal_point_ratio );

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
var i:Number = 0;
for(i=0;i < 8;i++){

	var pos_y:Number = i * 32.0 + 16.0;

	// 開始位置
	mc.moveTo (   0.0 , pos_y );
	// 直線を描画
	mc.lineTo ( 256.0 , pos_y );
}

import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc:MovieClip = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// ２つの座標
// ------------------------------------------------------------
var pos_a:Point = new Point( Stage.width/2 , Stage.height/2 );
var pos_b:Point = new Point( 0 , 0 );

// ------------------------------------------------------------
// 線のグラデーション塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 100;
// グラデーションの種類
var gradient_type:String = "linear";
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [        0 ,      100 ,        0 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = "pad";
// 補間の種類
var interpolation_method:String = "linearRGB";
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
mc.onEnterFrame = function ():Void{

	// ------------------------------------------------------------
	// 座標Ｂにマウス座標をセット
	// ------------------------------------------------------------
	pos_b.x = _root._xmouse;
	pos_b.y = _root._ymouse;

	// ------------------------------------------------------------
	// グラデーションの行列
	// ------------------------------------------------------------
	// 差分ベクトル
	var vec:Point = pos_b.subtract(pos_a);
	// 法線ベクトルの角度
	var rad:Number = Math.atan2(vec.y , vec.x) + Math.PI * 0.5;

	// 単位行列化
	gradient_mtx.identity();
	// 拡大縮小成分を乗算
	gradient_mtx.scale(thickness/1638.4 , 1.0);
	// 角度成分を乗算
	gradient_mtx.rotate(rad);
	// 移動成分を乗算
	gradient_mtx.translate(pos_a.x , pos_a.y);

	// ------------------------------------------------------------
	// 描画済みグラフィックをすべてクリアする
	// ------------------------------------------------------------
	mc.clear();

	// ------------------------------------------------------------
	// 線の基礎的なスタイルを指定する
	// ------------------------------------------------------------
	mc.lineStyle( thickness );

	// ------------------------------------------------------------
	// 線に「グラデーション塗り」スタイルを指定する
	// ------------------------------------------------------------
	mc.lineGradientStyle(
		gradient_type,
		gradient_colors,
		gradient_alphas,
		gradient_ratios,
		gradient_mtx,
		spread_method,
		interpolation_method,
		focal_point_ratio
	);

	// ------------------------------------------------------------
	// 直線を描画する
	// ------------------------------------------------------------
	// 開始位置
	mc.moveTo ( pos_a.x , pos_a.y );
	// 直線を描画
	mc.lineTo ( pos_b.x , pos_b.y );

};

import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc:MovieClip = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// ２つの座標
// ------------------------------------------------------------
var pos_a:Point = new Point( Stage.width/2 , Stage.height/2 );
var pos_b:Point = new Point( 0 , 0 );

// ------------------------------------------------------------
// 線のグラデーション塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 100;
// グラデーションの種類
var gradient_type:String = "linear";
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [      100 ,      100 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = "pad";
// 補間の種類
var interpolation_method:String = "rgb";
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
mc.onEnterFrame = function ():Void{

	// ------------------------------------------------------------
	// 座標Ｂにマウス座標をセット
	// ------------------------------------------------------------
	pos_b.x = _root._xmouse;
	pos_b.y = _root._ymouse;

	// ------------------------------------------------------------
	// グラデーションの行列
	// ------------------------------------------------------------
	// 差分ベクトル
	var vec:Point = pos_b.subtract(pos_a);
	// 中間座標
	var pos:Point = Point.interpolate(pos_a , pos_b , 0.5);
	// ベクトルの角度
	var rad:Number = Math.atan2(vec.y , vec.x);
	// ベクトルの長さ
	var len:Number = vec.length;

	// 単位行列化
	gradient_mtx.identity();
	// 拡大縮小成分を乗算
	gradient_mtx.scale(len/1638.4 , 1.0);
	// 角度成分を乗算
	gradient_mtx.rotate(rad);
	// 移動成分を乗算
	gradient_mtx.translate(pos.x , pos.y);

	// ------------------------------------------------------------
	// 描画済みグラフィックをすべてクリアする
	// ------------------------------------------------------------
	mc.clear();

	// ------------------------------------------------------------
	// 線の基礎的なスタイルを指定する
	// ------------------------------------------------------------
	mc.lineStyle( thickness );

	// ------------------------------------------------------------
	// 線に「グラデーション塗り」スタイルを指定する
	// ------------------------------------------------------------
	mc.lineGradientStyle(
		gradient_type,
		gradient_colors,
		gradient_alphas,
		gradient_ratios,
		gradient_mtx,
		spread_method,
		interpolation_method,
		focal_point_ratio
	);

	// ------------------------------------------------------------
	// 直線を描画する
	// ------------------------------------------------------------
	// 開始位置
	mc.moveTo ( pos_a.x , pos_a.y );
	// 直線を描画
	mc.lineTo ( pos_b.x , pos_b.y );

};

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineStyle (10 , 0x000000 , 100);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
mc.moveTo (  20.0 ,  10.0 );
// 直線を描画
mc.lineTo ( 420.0 ,  10.0 );

// ------------------------------------------------------------
// 線の描画スタイルをリセットする（引数を省略した場合）
// ------------------------------------------------------------
mc.lineStyle ();

// ------------------------------------------------------------
// 面に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.beginFill ( 0xff8800 , 100 );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
mc.moveTo (  20.0 ,  20.0 );
mc.lineTo ( 420.0 ,  20.0 );
mc.lineTo ( 420.0 , 320.0 );
mc.lineTo (  20.0 , 320.0 );

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 面に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.beginFill ( 0xff8800 , 100 );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
mc.moveTo (  20.0 ,  20.0 );
mc.lineTo ( 420.0 ,  20.0 );
mc.lineTo ( 420.0 , 320.0 );
mc.lineTo (  20.0 , 320.0 );

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 面のグラデーション塗り設定
// ------------------------------------------------------------
// グラデーションの種類
var gradient_type = "radial";
// グラデーション
var gradient_colors = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas = [      100 ,      100 ,      100 ];	// 透明度リスト
var gradient_ratios = [        0 ,    127.5 ,      255 ];	// 配分リスト

// ------------------------------------------------------------
// グラデーションの行列
// ------------------------------------------------------------
var gradient_mtx = new Object();

// 行列のタイプ
gradient_mtx.matrixType = "box";

// グラデーションの矩形
gradient_mtx.x =   0; // x 座標
gradient_mtx.y =   0; // y 座標
gradient_mtx.w = 256; // 幅
gradient_mtx.h = 256; // 高さ

// グラデーションの角度（ラジアン）
gradient_mtx.r = 0.0 * (Math.PI / 180);

// ------------------------------------------------------------
// 面に「グラデーション塗り」スタイルを指定する
// ------------------------------------------------------------
mc.beginGradientFill( gradient_type , gradient_colors , gradient_alphas , gradient_ratios , gradient_mtx );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
var i = 0;
for(i=0;i < 8;i++){

	var pos_y = i * 32.0;

	// 矩形を描画
	mc.moveTo (   0.0 , pos_y +  0.0 );
	mc.lineTo ( 256.0 , pos_y +  0.0 );
	mc.lineTo ( 256.0 , pos_y + 30.0 );
	mc.lineTo (   0.0 , pos_y + 30.0 );
}

import flash.geom.Matrix;

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc:MovieClip = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 面のグラデーション塗り設定
// ------------------------------------------------------------
// グラデーションの種類
var gradient_type:String = "radial";
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [      100 ,      100 ,      100 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = "pad";
// 補間の種類
var interpolation_method:String = "linearRGB";
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// グラデーションの行列
// ------------------------------------------------------------
// 単位行列化
gradient_mtx.identity();
// 拡大縮小成分を乗算
gradient_mtx.scale( 256/1638.4 , 256/1638.4 );
// 角度成分を乗算
gradient_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
gradient_mtx.translate( 128.0 , 128.0 );

// ------------------------------------------------------------
// 面に「グラデーション塗り」スタイルを指定する
// ------------------------------------------------------------
mc.beginGradientFill( gradient_type , gradient_colors , gradient_alphas , gradient_ratios , gradient_mtx , spread_method , interpolation_method , focal_point_ratio );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
var i:Number = 0;
for(i=0;i < 8;i++){

	var pos_y:Number = i * 32.0;

	// 矩形を描画
	mc.moveTo (   0.0 , pos_y +  0.0 );
	mc.lineTo ( 256.0 , pos_y +  0.0 );
	mc.lineTo ( 256.0 , pos_y + 30.0 );
	mc.lineTo (   0.0 , pos_y + 30.0 );
}

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 矩形
// ------------------------------------------------------------
var rect = {
	x:10,
	y:10,
	width :Stage.width  - 20,
	height:Stage.height - 20
};

// ------------------------------------------------------------
// 面のグラデーション塗り設定
// ------------------------------------------------------------
// グラデーションの種類
var gradient_type = "radial";
// グラデーション
var gradient_colors = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas = [      100 ,      100 ,      100 ];	// 透明度リスト
var gradient_ratios = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx = new Object();

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
mc.onEnterFrame = function (){

	// ------------------------------------------------------------
	// 矩形の右下端をマウス座標にフィット
	// ------------------------------------------------------------
	rect.width  = _root._xmouse - rect.x;
	rect.height = _root._ymouse - rect.y;

	// ------------------------------------------------------------
	// グラデーションの行列
	// ------------------------------------------------------------
	gradient_mtx.matrixType = "box";
	gradient_mtx.x = rect.x;
	gradient_mtx.y = rect.y;
	gradient_mtx.w = rect.width;
	gradient_mtx.h = rect.height;
	gradient_mtx.r = 0.0 * (Math.PI / 180);

	// ------------------------------------------------------------
	// 描画済みグラフィックをすべてクリアする
	// ------------------------------------------------------------
	mc.clear();

	// ------------------------------------------------------------
	// 面に「グラデーション塗り」スタイルを指定する
	// ------------------------------------------------------------
	mc.beginGradientFill(
		gradient_type,
		gradient_colors,
		gradient_alphas,
		gradient_ratios,
		gradient_mtx
	);

	// ------------------------------------------------------------
	// 矩形を描画する
	// ------------------------------------------------------------
	mc.moveTo ( rect.x + 0.0        , rect.y + 0.0 );
	mc.lineTo ( rect.x + rect.width , rect.y + 0.0 );
	mc.lineTo ( rect.x + rect.width , rect.y + rect.height );
	mc.lineTo ( rect.x + 0.0        , rect.y + rect.height );

};

import flash.geom.Rectangle;
import flash.geom.Matrix;

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc:MovieClip = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 矩形
// ------------------------------------------------------------
var rect:Rectangle = new Rectangle( 10 , 10 , Stage.width - 20 , Stage.height - 20 );

// ------------------------------------------------------------
// 面のグラデーション塗り設定
// ------------------------------------------------------------
// グラデーションの種類
var gradient_type:String = "radial";
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [      100 ,      100 ,      100 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = "pad";
// 補間の種類
var interpolation_method:String = "linearRGB";
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
mc.onEnterFrame = function ():Void{

	// ------------------------------------------------------------
	// 矩形の右下端をマウス座標にフィット
	// ------------------------------------------------------------
	rect.width  = _root._xmouse - rect.x;
	rect.height = _root._ymouse - rect.y;

	// ------------------------------------------------------------
	// グラデーションの行列
	// ------------------------------------------------------------
	// 中間座標
	var pos_x:Number = rect.x + rect.width  * 0.5;
	var pos_y:Number = rect.y + rect.height * 0.5;

	// 単位行列化
	gradient_mtx.identity();
	// 拡大縮小成分を乗算
	gradient_mtx.scale(rect.width/1638.4 , rect.height/1638.4);
	// 角度成分を乗算
	gradient_mtx.rotate(0.0 * (Math.PI / 180));
	// 移動成分を乗算
	gradient_mtx.translate(pos_x , pos_y);

	// ------------------------------------------------------------
	// 描画済みグラフィックをすべてクリアする
	// ------------------------------------------------------------
	mc.clear();

	// ------------------------------------------------------------
	// 面に「グラデーション塗り」スタイルを指定する
	// ------------------------------------------------------------
	mc.beginGradientFill(
		gradient_type,
		gradient_colors,
		gradient_alphas,
		gradient_ratios,
		gradient_mtx,
		spread_method,
		interpolation_method,
		focal_point_ratio
	);

	// ------------------------------------------------------------
	// 矩形を描画する
	// ------------------------------------------------------------
	mc.moveTo ( rect.x + 0.0        , rect.y + 0.0 );
	mc.lineTo ( rect.x + rect.width , rect.y + 0.0 );
	mc.lineTo ( rect.x + rect.width , rect.y + rect.height );
	mc.lineTo ( rect.x + 0.0        , rect.y + rect.height );

};

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 埋め込んだ画像ファイルから、BitmapData オブジェクトを作成する (リンケージ識別子 "my_bitmap" )
// ------------------------------------------------------------
var bitmap_data = flash.display.BitmapData.loadBitmap("my_bitmap");

// ------------------------------------------------------------
// 面のテクスチャ塗り設定
// ------------------------------------------------------------
// テクスチャの行列
var texture_mtx = new flash.geom.Matrix();
// タイリング描画の有無
var texture_repeat = false;
// スムージングの有無
var texture_smooth = true;

// ------------------------------------------------------------
// テクスチャの行列
// ------------------------------------------------------------
// 単位行列化
texture_mtx.identity();
// 拡大縮小成分を乗算
texture_mtx.scale( 1.0 , 1.0 );
// 角度成分を乗算
texture_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
texture_mtx.translate( 0.0 , 0.0 );

// ------------------------------------------------------------
// 面に「テクスチャ塗り」スタイルを指定する
// ------------------------------------------------------------
mc.beginBitmapFill( bitmap_data , texture_mtx , texture_repeat , texture_smooth );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
var i = 0;
for(i=0;i < 16;i++){

	var pos_y = i * 32.0;

	// 矩形を描画
	mc.moveTo (   0.0 , pos_y +  0.0 );
	mc.lineTo ( 512.0 , pos_y +  0.0 );
	mc.lineTo ( 512.0 , pos_y + 30.0 );
	mc.lineTo (   0.0 , pos_y + 30.0 );

}

import flash.display.BitmapData;
import flash.geom.Matrix;

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc:MovieClip = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 埋め込んだ画像ファイルから、BitmapData オブジェクトを作成する (リンケージ識別子 "my_bitmap" )
// ------------------------------------------------------------
var bitmap_data:BitmapData = BitmapData.loadBitmap("my_bitmap");

// ------------------------------------------------------------
// 面のテクスチャ塗り設定
// ------------------------------------------------------------
// テクスチャの行列
var texture_mtx:Matrix = new Matrix();
// タイリング描画の有無
var texture_repeat:Boolean = false;
// スムージングの有無
var texture_smooth:Boolean = true;

// ------------------------------------------------------------
// テクスチャの行列
// ------------------------------------------------------------
// 単位行列化
texture_mtx.identity();
// 拡大縮小成分を乗算
texture_mtx.scale( 1.0 , 1.0 );
// 角度成分を乗算
texture_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
texture_mtx.translate( 0.0 , 0.0 );

// ------------------------------------------------------------
// 面に「テクスチャ塗り」スタイルを指定する
// ------------------------------------------------------------
mc.beginBitmapFill( bitmap_data , texture_mtx , texture_repeat , texture_smooth );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
var i:Number = 0;
for(i=0;i < 16;i++){

	var pos_y:Number = i * 32.0;

	// 矩形を描画
	mc.moveTo (   0.0 , pos_y +  0.0 );
	mc.lineTo ( 512.0 , pos_y +  0.0 );
	mc.lineTo ( 512.0 , pos_y + 30.0 );
	mc.lineTo (   0.0 , pos_y + 30.0 );

}

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineStyle (1 , 0x000000 , 100);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
mc.moveTo (  20.0 ,  40.0 );
// 直線を描画
mc.lineTo ( 200.0 , 100.0 );

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineStyle (1 , 0x000000 , 100);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
mc.moveTo (  20.0 ,  40.0 );
// 直線を描画
mc.lineTo ( 100.0 , 100.0 );
// 直線を描画
mc.lineTo ( 200.0 ,  80.0 );
// 直線を描画
mc.lineTo ( 300.0 , 150.0 );

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
mc.lineStyle (1 , 0x000000 , 100);

// ------------------------------------------------------------
// ２次ベジェ曲線を描画する
// ------------------------------------------------------------
// ３つの座標
var pos0 = { x: 20.0 , y:280.0 };
var pos1 = { x:150.0 , y: 20.0 };
var pos2 = { x:400.0 , y:150.0 };

// 開始位置
mc.moveTo ( pos0.x,pos0.y );
// ２次ベジェ曲線を描画
mc.curveTo ( pos1.x,pos1.y , pos2.x,pos2.y );

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

(function(){

	// マウス座標のリスト
	var mouse_pos_list = new Array();

	// ------------------------------------------------------------
	// マウスの左ボタンを押すと実行されるイベント
	// ------------------------------------------------------------
	mc.onMouseDown = function (){
		// マウスカーソルの位置を取得
		var pos = { x:mc._xmouse , y:mc._ymouse };
		// 座標リストを初期化 (要素数:1)
		mouse_pos_list = [pos];
	};

	// ------------------------------------------------------------
	// マウスの左ボタンを離すと実行されるイベント
	// ------------------------------------------------------------
	mc.onMouseUp = function (){
		// 座標リストをクリア (要素数:0)
		mouse_pos_list = new Array();
	};

	// ------------------------------------------------------------
	// マウスカーソルを移動すると実行されるイベント
	// ------------------------------------------------------------
	mc.onMouseMove = function (){
		// ドラッグ操作中か
		if(mouse_pos_list.length < 1) return;

		// マウスカーソルの位置を取得
		var pos = { x:mc._xmouse , y:mc._ymouse };
		// 座標リストに追加
		mouse_pos_list.push(pos);
	};

	// ------------------------------------------------------------
	// 毎フレーム実行されるイベント
	// ------------------------------------------------------------
	mc.onEnterFrame = function(){

		// ------------------------------------------------------------
		// 座標リストの総数
		// ------------------------------------------------------------
		var num = mouse_pos_list.length
		if(num < 2) return;

		// ------------------------------------------------------------
		// 線に「単一色塗り」スタイルを指定する
		// ------------------------------------------------------------
		mc.lineStyle ( 5 , 0x000000 , 100 );

		// ------------------------------------------------------------
		// 開始位置を指定する
		// ------------------------------------------------------------
		var pos = mouse_pos_list[0];
		mc.moveTo ( pos.x , pos.y );

		// ------------------------------------------------------------
		// 連続で直線を描画する
		// ------------------------------------------------------------
		var i;
		for(i=1;i < num;i++){
			pos = mouse_pos_list[i];

			// 直線を描画する
			mc.lineTo ( pos.x , pos.y );
		}

		// ------------------------------------------------------------
		// 座標リストを初期化する
		// ------------------------------------------------------------
		mouse_pos_list = [pos];
	};

}).call();

// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
mc.lineStyle (5 , 0x000000 , 100);
// 面に「単一色塗り」スタイルを指定する
mc.beginFill (0x808080 , 100);

// ------------------------------------------------------------
// 描画パスで囲んで面を描画する
// ------------------------------------------------------------
// 描画パスを開始する
mc.moveTo ( 25.0 , 100.0 );

// 描画パスを指定して囲む
mc.lineTo (  75.0 ,  35.0 );
mc.lineTo ( 165.0 ,  55.0 );
mc.lineTo ( 325.0 ,  25.0 );
mc.lineTo ( 375.0 ,  95.0 );
mc.lineTo ( 265.0 , 165.0 );
mc.lineTo ( 205.0 , 135.0 );
mc.lineTo (  75.0 , 165.0 );

// 描画パスを閉じて、塗りつぶしを確定する
mc.endFill ();

// ------------------------------------------------------------
// 円を描画する関数
// ------------------------------------------------------------
function MovieClipDrawCircle ( mc , x , y , radius ) {

	var q = 8; // 品質（8 で Flash の図形と同等）

	var i;
	var t;
	var r = -Math.PI * 0.5;
	var a = 1 / q * Math.PI * 2;
	var p0;
	var p1;
	p0 = {
		x:Math.cos(r) * radius,
		y:Math.sin(r) * radius
	};
	mc.moveTo (
		x + (p0.x),
		y + (p0.y)
	);
	for(i=0;i < q;i++){
		r += a;
		p1 = {
			x:Math.cos(r) * radius,
			y:Math.sin(r) * radius
		};
		t = -(p1.x * p0.x + p1.y * p0.y - (p1.x * p1.x + p1.y * p1.y)) / (p1.x * (-p0.y) + p1.y * p0.x);
		mc.curveTo(
			x + ((p0.x) + t * (-p0.y)),
			y + ((p0.y) + t * ( p0.x)),
			x + (p1.x),
			y + (p1.y)
		);
		p0 = p1;
	}

	return true;
}


// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
mc.lineStyle (5 , 0x000000 , 100);
// 面に「単一色塗り」スタイルを指定する
mc.beginFill (0x808080 , 100);

// ------------------------------------------------------------
// 円を描画する
// ------------------------------------------------------------
MovieClipDrawCircle ( mc , 120.0 , 150.0 , 100.0 );
MovieClipDrawCircle ( mc , 350.0 , 150.0 ,  80.0 );

// ------------------------------------------------------------
// 楕円を描画する関数
// ------------------------------------------------------------
function MovieClipDrawEllipse ( mc , x , y , width , height ) {

	var q = 8; // 品質（8 で Flash の図形と同等）

	var i;
	var t;
	var r = -Math.PI * 0.5;
	var a = 1 / q * Math.PI * 2;
	var p0;
	var p1;
	var sx;
	var sy;
	var radius;
	if(width > height){
		sx = width / height;
		sy = 1.0;
		radius = height * 0.5;
	}else{
		sx = 1.0;
		sy = height / width;
		radius = width * 0.5;
	}
	x += width  * 0.5;
	y += height * 0.5;
	p0 = {
		x:Math.cos(r) * radius,
		y:Math.sin(r) * radius
	};
	mc.moveTo (
		x + (p0.x) * sx,
		y + (p0.y) * sy
	);
	for(i=0;i < q;i++){
		r += a;
		p1 = {
			x:Math.cos(r) * radius,
			y:Math.sin(r) * radius
		};
		t = -(p1.x * p0.x + p1.y * p0.y - (p1.x * p1.x + p1.y * p1.y)) / (p1.x * (-p0.y) + p1.y * p0.x);
		mc.curveTo(
			x + ((p0.x) + t * (-p0.y)) * sx,
			y + ((p0.y) + t * ( p0.x)) * sy,
			x + (p1.x) * sx,
			y + (p1.y) * sy
		);
		p0 = p1;
	}

	return true;
}


// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
mc.lineStyle (5 , 0x000000 , 100);
// 面に「単一色塗り」スタイルを指定する
mc.beginFill (0x808080 , 100);

// ------------------------------------------------------------
// 楕円を描画する
// ------------------------------------------------------------
MovieClipDrawEllipse ( mc ,  50.0 , 20.0 , 100.0 , 250.0 );
MovieClipDrawEllipse ( mc , 200.0 , 50.0 , 300.0 , 150.0 );

// ------------------------------------------------------------
// 矩形を描画する関数
// ------------------------------------------------------------
function MovieClipDrawRect ( mc , x , y , width , height ) {
	mc.moveTo ( x + 0.0   , y + 0.0 );
	mc.lineTo ( x + width , y + 0.0 );
	mc.lineTo ( x + width , y + height );
	mc.lineTo ( x + 0.0   , y + height );

	return true;
}


// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
mc.lineStyle (5 , 0x000000 , 100);
// 面に「単一色塗り」スタイルを指定する
mc.beginFill (0x808080 , 100);

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
MovieClipDrawRect ( mc ,  50.0 , 20.0 , 100.0 , 250.0 );
MovieClipDrawRect ( mc , 200.0 , 50.0 , 300.0 , 150.0 );

// ------------------------------------------------------------
// 角丸矩形を描画する関数
// ------------------------------------------------------------
function MovieClipDrawRoundRect ( mc , x , y , width , height , ellipseWidth , ellipseHeight ) {
	if(ellipseHeight === undefined) ellipseHeight = ellipseWidth;
	if(ellipseWidth  > width ) ellipseWidth  = width;
	if(ellipseHeight > height) ellipseHeight = height;

	var px;
	var py;
	var w0 = ellipseWidth  * 0.5;
	var h0 = ellipseHeight * 0.5;
	var w1 = 0.707106781186548 * w0;
	var h1 = 0.707106781186548 * h0;
	var w2 = 0.414213562373095 * w0;
	var h2 = 0.414213562373095 * h0;

	px = x + width - w0;
	py = y + h0;
	mc.moveTo  ( px      , py - h0 );
	mc.curveTo ( px + w2 , py - h0 , px + w1 , py - h1 );
	mc.curveTo ( px + w0 , py - h2 , px + w0 , py      );

	py = y + height - h0;
	mc.lineTo  ( px + w0 , py );
	mc.curveTo ( px + w0 , py + h2 , px + w1 , py + h1 );
	mc.curveTo ( px + w2 , py + h0 , px      , py + h0 );

	px = x + w0;
	mc.lineTo  ( px      , py + h0 );
	mc.curveTo ( px - w2 , py + h0 , px - w1 , py + h1 );
	mc.curveTo ( px - w0 , py + h2 , px - w0 , py      );

	py = y + h0;
	mc.lineTo  ( px - w0 , py      );
	mc.curveTo ( px - w0 , py - h2 , px - w1 , py - h1 );
	mc.curveTo ( px - w2 , py - h0 , px      , py - h0 );

	return true;
}


// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
mc.lineStyle (5 , 0x000000 , 100);
// 面に「単一色塗り」スタイルを指定する
mc.beginFill (0x808080 , 100);

// ------------------------------------------------------------
// 角丸矩形を描画する
// ------------------------------------------------------------
MovieClipDrawRoundRect ( mc ,  50.0 , 20.0 , 100.0 , 250.0 , 20 , 20 );
MovieClipDrawRoundRect ( mc , 200.0 , 50.0 , 300.0 , 150.0 , 40 , 60 );

// ------------------------------------------------------------
// 正多角形を描画する関数
// ------------------------------------------------------------
function MovieClipDrawRegularPolygon ( mc , x , y , radius , vertex , angle ) {

	if(vertex < 3) return false;

	angle -= Math.PI * 0.5;
	mc.moveTo (
		x + Math.cos(angle) * radius,
		y + Math.sin(angle) * radius
	);

	var a = 1 / vertex * Math.PI * 2;
	var i;
	for(i=0;i < vertex;i++){
		angle += a;
		mc.lineTo(
			x + Math.cos(angle) * radius,
			y + Math.sin(angle) * radius
		);
	}

	return true;
}


// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
mc.lineStyle (5 , 0x000000 , 100);
// 面に「単一色塗り」スタイルを指定する
mc.beginFill (0x808080 , 100);

// ------------------------------------------------------------
// 正多角形を描画する
// ------------------------------------------------------------
MovieClipDrawRegularPolygon ( mc , 120.0 , 150.0 , 100.0 , 5 ,  15.0 * (Math.PI/180) );
MovieClipDrawRegularPolygon ( mc , 350.0 , 150.0 ,  80.0 , 7 ,   0.0 * (Math.PI/180) );

// ------------------------------------------------------------
// 星を描画する関数
// ------------------------------------------------------------
function MovieClipDrawStar ( mc , x , y , radius , vertex , angle , indent ) {

	if(vertex < 3) return false;

	vertex *= 2;
	angle -= Math.PI * 0.5;
	mc.moveTo (
		x + Math.cos(angle) * radius,
		y + Math.sin(angle) * radius
	);

	var a = 1 / vertex * Math.PI * 2;
	var r;
	var i;
	for(i=0;i < vertex;i++){
		angle += a;
		r = (i % 2) ? (radius):(radius * indent);
		mc.lineTo(
			x + Math.cos(angle) * r,
			y + Math.sin(angle) * r
		);
	}

	return true;
}


// ------------------------------------------------------------
// ムービークリップを作成
// ------------------------------------------------------------
var mc = _root.createEmptyMovieClip("new_mc" , 0);

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
mc.lineStyle (5 , 0x000000 , 100);
// 面に「単一色塗り」スタイルを指定する
mc.beginFill (0x808080 , 100);

// ------------------------------------------------------------
// 星を描画する
// ------------------------------------------------------------
MovieClipDrawStar ( mc , 120.0 , 150.0 , 100.0 , 5 ,  15.0 * (Math.PI/180) , 0.5 );
MovieClipDrawStar ( mc , 350.0 , 150.0 ,  80.0 , 7 ,   0.0 * (Math.PI/180) , 0.8 );