Flashゲームプログラミング講座 for ActionScript3.0

 

経過した時間を調べる

 

サンプルをダウンロード
 
 


■Flash の実行を開始してから、経過した現在の時間を調べる

 
Flash の実行を開始してから、経過した現在の時間を調べるには、getTimer() 関数を使用します。
 
単位は、ミリ秒です。
 
Flash の実行を開始してから、経過した時間を取得

import flash.utils.getTimer;

// Flash の実行を開始してから、経過した時間を取得
var time:int = getTimer();
 

■ストップウォッチを作成する

 
getTimer() メソッドを使用して、ストップウォッチを作成します。
 
1.測定を開始する
 
測定を開始したい時点で、getTimer() メソッドを呼び出します。
 
得られた時間を、変数に残しておきます。
 
測定を開始したい時点で、現在の経過時間を変数に残す

import flash.utils.getTimer;

// 測定開始時に経過時間を変数に残す
var time_old:int = getTimer();
 
2.測定中の経過時間を調べる
 
計測したい時点で、もう一度、getTimer() メソッドを呼び出します。
 
「今回得られた時間」から「測定開始時に取得した時間」を減算すると、経過時間を知ることができます。
 
測定中に経過している時間(Flash 6 以降)

import flash.utils.getTimer;
import flash.events.Event;

// ------------------------------------------------------------
// 初期化処理
// ------------------------------------------------------------
// 測定開始時に経過時間を変数に残す
var time_old:int = getTimer();


// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
addEventListener(Event.ENTER_FRAME,function (e:Event):void{

	// 現在の経過時間
	var time_now:int = getTimer();

	// 測定を開始してから経過した時間
	var time:Number = time_now - time_old;

	// 出力テスト
	trace(time);
});
 

■総ミリ秒から『時:分:秒.ミリ秒』表記の文字列を取得する

 
総ミリ秒から、『時:分:秒.ミリ秒』表記の文字列を取得します。
 
総ミリ秒から、『時:分:秒.ミリ秒』を取得する(Flash 6 以降)

import flash.utils.getTimer;
import flash.events.Event;

// ------------------------------------------------------------
// 総ミリ秒から、『時:分:秒.ミリ秒』を取得する関数
// ------------------------------------------------------------
function TimeGetTimeString(time:Number):String{

	var milli_sec:Number = time % 1000;
	time = (time - milli_sec) / 1000;
	var sec:Number = time % 60;
	time = (time - sec) / 60;
	var min:Number = time % 60;
	var hou:Number = (time - min) / 60;

	// 文字列として連結
	return hou  + ":" +
		((min < 10) ? "0" : "") + min + ":" +
		((sec < 10) ? "0" : "") + sec + "." +
		((milli_sec < 100) ? "0" : "") + ((milli_sec < 10) ? "0" : "") + milli_sec;
}


// ------------------------------------------------------------
// 初期化処理
// ------------------------------------------------------------
// 測定開始時に経過時間を変数に残す
var time_old:int = getTimer();

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
addEventListener(Event.ENTER_FRAME,function (e:Event):void{

	// 現在の経過時間
	var time_now:int = getTimer();

	// 測定を開始してから経過した時間
	var time:Number = time_now - time_old;

	// 出力テスト
	trace(TimeGetTimeString(time));
});
 
 

 

現在のローカルの日付/時間を取得する

 

サンプルをダウンロード
 
 


■Date クラスについて

 
new 演算子を使って、Date クラスをインスタンス化します。
 
■現在のローカルの日付/時間を取得する
 
引数を省略した場合、
 
現在のローカルの日付/時間が格納された、Date オブジェクトを作成する事ができます。
 
現在のローカル時間が格納された、Date オブジェクトを作成する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 出力テスト
trace(date_obj.toString());
 
■1970年01月01日 00:00:00 から開始して、指定ミリ秒経過後の、Date オブジェクトを作成する
 
引数を1つだけ指定した場合、
 
協定世界時の 1970/01/01 00:00:00 から開始して、
 
指定ミリ秒経過後
の、Date オブジェクトを作成する事ができます。
 
第01引数に、協定世界時を基準としたミリ秒を指定します。
 
new Date( ミリ秒 ) :Date
第01引数 Numberミリ秒を指定
戻り値 Date1970年01月01日 00:00:00 から開始して、指定ミリ秒経過後の Date オブジェクト
 
協定世界時の 1970/01/01 00:00:00 から開始して、指定ミリ秒経過した、Date オブジェクトを作成する

// 協定世界時の 1970/01/01 00:00:00 から開始して、指定ミリ秒経過した、Date オブジェクトを作成する
var date_obj:Date = new Date(0);

// 出力テスト
trace(date_obj.toString());
 
■日付/時間を指定して、Date オブジェクトを作成する
 
2つ以上の引数を指定した場合、
 
日付/時間を指定して、Date オブジェクトを作成する事ができます。
 
現地時間を基準に指定します。
 
協定世界時を基準に指定したい場合は、こちらで解説しています。
 
new Date( 年 , 月 , 日 , 時 , 分 , 秒 , ミリ秒 ) :Date
第01引数 Number年を指定。(99 以下の数値を指定した場合 1900 年代となる。よって 99 年以下を指定するには「西暦 - 1900」をセットする)
第02引数 Number月を指定。0 ~ 11 (1月~12月)
第03引数(略可)Number日を指定。1 ~ 31
第04引数(略可)Number時を指定。0 ~ 23
第05引数(略可)Number分を指定。0 ~ 59
第06引数(略可)Number秒を指定。0 ~ 59
第07引数(略可)Numberミリ秒を指定。0 ~ 999
戻り値 DateDate オブジェクト
 
日付/時間を指定して、Date オブジェクトを作成する

// 日付/時間を指定して、Date オブジェクトを作成する
var date_obj:Date = new Date(2000,10,1,13,30,59,999);

// 出力テスト
trace(date_obj.toString());
 

■Date クラスの get 系のメソッド一覧


Date クラスには、以下の get 系のメソッドがあります。
 
メソッド 説明
getTime() 協定世界時の 1970/01/01 00:00:00 から開始して、経過した時間をミリ秒で取得する
getFullYear() 西暦を取得する(現地時間)
getUTCFullYear() 西暦を取得する(協定世界時)
getMonth() 月を取得する(現地時間) (0 ~ 11)
getUTCMonth() 月を取得する(協定世界時) (0 ~ 11)
getDate() 日を取得する(現地時間) (1 ~ 31)
getUTCDate() 日を取得する(協定世界時) (1 ~ 31)
getDay() 曜日を取得する(現地時間) (0 ~ 6)
getUTCDay() 曜日を取得する(協定世界時) (0 ~ 6)
getHours() 時を取得する(現地時間) (0 ~ 23)
getUTCHours() 時を取得する(協定世界時) (0 ~ 23)
getMinutes() 分を取得する(現地時間) (0 ~ 59)
getUTCMinutes() 分を取得する(協定世界時) (0 ~ 59)
getSeconds() 秒を取得する(現地時間) (0 ~ 59)
getUTCSeconds() 秒を取得する(協定世界時) (0 ~ 59)
getMilliseconds() ミリ秒を取得する(現地時間) (0 ~ 999)
getUTCMilliseconds() ミリ秒を取得する(協定世界時) (0 ~ 999)
getTimezoneOffset() 協定世界時と現地時間との時間差を取得する(単位:分)
 

■Date クラスの set 系のメソッド一覧


Date クラスには、以下の set 系のメソッドがあります。
 
メソッド 説明
setTime() 協定世界時の 1970/01/01 00:00:00 から開始して、経過した時間をミリ秒で設定する
setFullYear() 西暦を設定する(現地時間)
setUTCFullYear() 西暦を設定する(協定世界時)
setMonth() 月を設定する(現地時間) (0 ~ 11)
setUTCMonth() 月を設定する(協定世界時) (0 ~ 11)
setDate() 日を設定する(現地時間) (1 ~ 31)
setUTCDate() 日を設定する(協定世界時) (1 ~ 31)
setHours() 時を設定する(現地時間) (0 ~ 23)
setUTCHours() 時を設定する(協定世界時) (0 ~ 23)
setMinutes() 分を設定する(現地時間) (0 ~ 59)
setUTCMinutes() 分を設定する(協定世界時) (0 ~ 59)
setSeconds() 秒を設定する(現地時間) (0 ~ 59)
setUTCSeconds() 秒を設定する(協定世界時) (0 ~ 59)
setMilliseconds() ミリ秒を設定する(現地時間) (0 ~ 999)
setUTCMilliseconds() ミリ秒を設定する(協定世界時) (0 ~ 999)
 

■1970年01月01日 00:00:00 から開始して、経過したミリ秒について

 
■1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で取得する
 
協定世界時の 1970/01/01 00:00:00 から開始して、
 
経過した時間をミリ秒で取得するには、getTime() メソッドを使用します。
 
現在のローカル時間が、1970年01月01日 00:00:00 から開始して、何ミリ秒経過したか調べる

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 協定世界時の 1970/01/01 00:00:00 から開始して、経過した時間をミリ秒で取得
var milliseconds:Number = date_obj.getTime();

// 出力テスト
trace(milliseconds);
 
■UNIX 時間を取得する
 
UNIX 時間とは、協定世界時の 1970年01月01日 00:00:00 から開始して、経過した数です。
 
getTime() メソッドで取得した値を 1000 で割ります。
 
UNIX 時間を取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// UNIX 時間を取得する
var unix_time:Number = Math.floor(date_obj.getTime() / 1000);

// 出力テスト
trace(unix_time);
 
■2つの Date オブジェクトの時間差をミリ秒で取得する
 
getTime() メソッドで、日付/時間をミリ秒に変換します。
 
ミリ秒に変換すると、2つの日付/時間から、時間差を計算するのが簡単になります。
 
例えば、3日以上経過してるか調べるには、
 
3(日)×24(時)×60(分)×60(秒)×1000(ミリ秒) ⇒ 259200000(ミリ秒) 以上差があるか調べます。
 
2つの Date オブジェクトの時間差をミリ秒で取得する

// 日付/時間を指定して、Date オブジェクトを作成する
var date_obj_a:Date = new Date(2000,10,1,13,30,59,999);
var date_obj_b:Date = new Date(2000,10,2, 8,10,22,100);

// 1970/01/01 00:00:00 から開始して、経過した時間をミリ秒で取得
var milliseconds_a:Number = date_obj_a.getTime();
var milliseconds_b:Number = date_obj_b.getTime();

// 2つの Date オブジェクトの時間差をミリ秒で取得
var difference:Number = milliseconds_b - milliseconds_a;

// 出力テスト
trace(difference);
 
■日付/時間を指定して、1970年01月01日 00:00:00 から開始して、経過したミリ秒を取得する
 
世界協定時の日付/時間を指定して、
 
1970年01月01日 00:00:00 から開始して経過したミリ秒を取得するには、Date.UTC() メソッドを使用します。
 
Date.UTC( 年 , 月 , 日 , 時 , 分 , 秒 , ミリ秒 ) :Date
第01引数 Number年を指定。(99 以下の数値を指定した場合 1900 年代となる。よって 99 年以下を指定するには「西暦 - 1900」をセットする)
第02引数 Number月を指定。0 ~ 11 (1月~12月)
第03引数(略可)Number日を指定。1 ~ 31
第04引数(略可)Number時を指定。0 ~ 23
第05引数(略可)Number分を指定。0 ~ 59
第06引数(略可)Number秒を指定。0 ~ 59
第07引数(略可)Numberミリ秒を指定。0 ~ 999
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
世界協定時の日付/時間を指定して、Date オブジェクトを作成する

// 世界協定時の日付/時間を指定して、1970年01月01日 00:00:00 から開始して経過したミリ秒を取得する
var milliseconds:Number = Date.UTC(2000,10,1,13,30,59,999);

// 協定世界時の 1970/01/01 00:00:00 から開始して指定ミリ秒経過した、Date オブジェクトを作成する
var date_obj:Date = new Date(milliseconds);

// 出力テスト
trace(date_obj.toString());
 
■1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で設定する
 
協定世界時の 1970/01/01 00:00:00 から開始して、
 
経過した時間をミリ秒で設定するには、setTime() メソッドを使用します。
 
第01引数に、協定世界時を基準としたミリ秒を指定します。
 
1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 協定世界時の 1970/01/01 00:00:00 から開始して、経過した時間をミリ秒で設定
date_obj.setTime(0);

// 出力テスト
trace(date_obj.toString());
 

■西暦について

 
■西暦を現地時間で取得する
 
西暦を、現地時間で取得するには、getFullYear() メソッドを使用します。
 
西暦を現地時間で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 西暦を現地時間で取得する
var full_year:Number = date_obj.getFullYear();

// 出力テスト
trace(full_year);
 
■西暦を協定世界時で取得する
 
西暦を、協定世界時で取得するには、getUTCFullYear() メソッドを使用します。
 
西暦を協定世界時で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 西暦を協定世界時で取得する
var full_year:Number = date_obj.getUTCFullYear();

// 出力テスト
trace(full_year);
 
■西暦を現地時間で設定する
 
西暦を、現地時間で設定するには、setFullYear() メソッドを使用します。
 
引数に、西暦を指定します。
 
Date.setFullYear( 年 , 月 , 日 ) :Number
第01引数 Number年を指定。
第02引数(略可)Number月を指定。0 ~ 11 (1月~12月)
第03引数(略可)Number日を指定。1 ~ 31
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
西暦を現地時間で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 西暦を現地時間で設定する
date_obj.setFullYear(2000);

// 出力テスト
trace(date_obj.toString());
 
■西暦を協定世界時で設定する
 
西暦を、協定世界時で設定するには、setUTCFullYear() メソッドを使用します。
 
引数に、西暦を指定します。
 
Date.setUTCFullYear( 年 , 月 , 日 ) :Number
第01引数 Number年を指定。
第02引数(略可)Number月を指定。0 ~ 11 (1月~12月)
第03引数(略可)Number日を指定。1 ~ 31
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
西暦を協定世界時で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 西暦を協定世界時で設定する
date_obj.setUTCFullYear(2000);

// 出力テスト
trace(date_obj.toString());
 

■月について

 
■月を現地時間で取得する
 
月を、現地時間で取得するには、getMonth() メソッドを使用します。
 
0 から 11 までの数値が取得できるので、 +1 して使用します。
 
月を現地時間で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 月を現地時間で取得する
var month:Number = date_obj.getMonth() + 1;

// 出力テスト
trace(month);
 
■月を協定世界時で取得する
 
月を、協定世界時で取得するには、getUTCMonth() メソッドを使用します。
 
0 から 11 までの数値が取得できるので、 +1 して使用します。
 
月を協定世界時で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 月を協定世界時で取得する
var month:Number = date_obj.getUTCMonth() + 1;

// 出力テスト
trace(month);
 
■月を現地時間で設定する
 
月を、現地時間で設定するには、setMonth() メソッドを使用します。
 
引数に、0 から 11 までの数値を指定します。月に -1 してセットします。
 
Date.setMonth( 月 , 日 ) :Number
第01引数 Number月を指定。0 ~ 11 (1月~12月)
第02引数(略可)Number日を指定。1 ~ 31
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
月を現地時間で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 月を現地時間で設定する
date_obj.setMonth(12 - 1);

// 出力テスト
trace(date_obj.toString());
 
■月を協定世界時で設定する
 
月を、協定世界時で設定するには、setUTCMonth() メソッドを使用します。
 
引数に、0 から 11 までの数値を指定します。月に -1 してセットします。
 
Date.setUTCMonth( 月 , 日 ) :Number
第01引数 Number月を指定。0 ~ 11 (1月~12月)
第02引数(略可)Number日を指定。1 ~ 31
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
月を協定世界時で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 月を協定世界時で設定する
date_obj.setUTCMonth(12 - 1);

// 出力テスト
trace(date_obj.toString());
 

■日について

 
■日を現地時間で取得する
 
日を、現地時間で取得するには、getDate() メソッドを使用します。
 
1 から 31 までの数値が取得できます。
 
日を現地時間で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 日を現地時間で取得する
var date:Number = date_obj.getDate();

// 出力テスト
trace(date);
 
■日を協定世界時で取得する
 
日を、協定世界時で取得するには、getUTCDate() メソッドを使用します。
 
1 から 31 までの数値が取得できます。
 
日を協定世界時で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 日を協定世界時で取得する
var date:Number = date_obj.getUTCDate();

// 出力テスト
trace(date);
 
■日を現地時間で設定する
 
日を、現地時間で設定するには、setDate() メソッドを使用します。
 
引数に、1 から 31 までの数値を指定します。
 
Date.setDate( 日 ) :Number
第01引数 Number日を指定。1 ~ 31
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
日を現地時間で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 日を現地時間で設定する
date_obj.setDate(20);

// 出力テスト
trace(date_obj.toString());
 
■日を協定世界時で設定する
 
日を、協定世界時で設定するには、setUTCDate() メソッドを使用します。
 
引数に、1 から 31 までの数値を指定します。
 
Date.setUTCDate( 日 ) :Number
第01引数 Number日を指定。1 ~ 31
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
日を協定世界時で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 日を協定世界時で設定する
date_obj.setUTCDate(20);

// 出力テスト
trace(date_obj.toString());
 

■曜日について

 
■曜日を現地時間で取得する
 
曜日を、現地時間で取得するには、getDay() メソッドを使用します。
 
0 から 6 までの数値が取得できます。(日曜 ~ 土曜)
 
曜日を文字列として取得したい場合は、配列に好きな文字列を格納してアクセスします。
 
曜日を現地時間で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 曜日を現地時間で取得する
var week:Number = date_obj.getDay();

// 曜日を配列で用意
var ary:Array = ["日","月","火","水","木","金","土"];

// 出力テスト
trace(ary[week]);
 
■曜日を協定世界時で取得する
 
曜日を、協定世界時で取得するには、getUTCDay() メソッドを使用します。
 
0 から 6 までの数値が取得できます。(日曜 ~ 土曜)
 
曜日を文字列として取得したい場合は、配列に好きな文字列を格納してアクセスします。
 
曜日を協定世界時で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 曜日を協定世界時で取得する
var week:Number = date_obj.getUTCDay();

// 曜日を配列で用意
var ary:Array = ["日","月","火","水","木","金","土"];

// 出力テスト
trace(ary[week]);
 
■曜日の設定について
 
曜日を設定することはできません。
 

■時について

 
■時を現地時間で取得する
 
時を、現地時間で取得するには、getHours() メソッドを使用します。
 
0 から 23 までの数値が取得できます。
 
時を現地時間で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 時を現地時間で取得する
var hours:Number = date_obj.getHours();

// 出力テスト
trace(hours);
 
■時を協定世界時で取得する
 
時を、協定世界時で取得するには、getUTCHours() メソッドを使用します。
 
0 から 23 までの数値が取得できます。
 
時を協定世界時で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 時を協定世界時で取得する
var hours:Number = date_obj.getUTCHours();

// 出力テスト
trace(hours);
 
■時を現地時間で設定する
 
時を、現地時間で設定するには、setHours() メソッドを使用します。
 
引数に、0 から 23 までの数値を指定します。
 
Date.setHours( 時 , 分 , 秒 , ミリ秒 ) :Number
第01引数 Number時を指定。0 ~ 23
第02引数(略可)Number分を指定。0 ~ 59
第03引数(略可)Number秒を指定。0 ~ 59
第04引数(略可)Numberミリ秒を指定。0 ~ 999
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
時を現地時間で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 時を現地時間で設定する
date_obj.setHours(23);

// 出力テスト
trace(date_obj.toString());
 
■時を協定世界時で設定する
 
時を、協定世界時で設定するには、setUTCHours() メソッドを使用します。
 
引数に、0 から 23 までの数値を指定します。
 
Date.setUTCHours( 時 , 分 , 秒 , ミリ秒 ) :Number
第01引数 Number時を指定。0 ~ 23
第02引数(略可)Number分を指定。0 ~ 59
第03引数(略可)Number秒を指定。0 ~ 59
第04引数(略可)Numberミリ秒を指定。0 ~ 999
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
時を協定世界時で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 時を協定世界時で設定する
date_obj.setUTCHours(23);

// 出力テスト
trace(date_obj.toString());
 

■分について

 
■分を現地時間で取得する
 
分を、現地時間で取得するには、getMinutes() メソッドを使用します。
 
0 から 59 までの数値が取得できます。
 
分を現地時間で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 分を現地時間で取得する
var minutes:Number = date_obj.getMinutes();

// 出力テスト
trace(minutes);
 
■分を協定世界時で取得する
 
分を、協定世界時で取得するには、getUTCMinutes() メソッドを使用します。
 
0 から 59 までの数値が取得できます。
 
分を協定世界時で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 分を協定世界時で取得する
var minutes:Number = date_obj.getUTCMinutes();

// 出力テスト
trace(minutes);
 
■分を現地時間で設定する
 
分を、現地時間で設定するには、setMinutes() メソッドを使用します。
 
引数に、0 から 59 までの数値を指定します。
 
Date.setMinutes( 分 , 秒 , ミリ秒 ) :Number
第01引数Number分を指定。0 ~ 59
第02引数(略可)Number秒を指定。0 ~ 59
第03引数(略可)Numberミリ秒を指定。0 ~ 999
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
分を現地時間で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 分を現地時間で設定する
date_obj.setMinutes(59);

// 出力テスト
trace(date_obj.toString());
 
■分を協定世界時で設定する
 
分を、協定世界時で設定するには、setUTCMinutes() メソッドを使用します。
 
引数に、0 から 59 までの数値を指定します。
 
Date.setUTCMinutes( 分 , 秒 , ミリ秒 ) :Number
第01引数Number分を指定。0 ~ 59
第02引数(略可)Number秒を指定。0 ~ 59
第03引数(略可)Numberミリ秒を指定。0 ~ 999
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
分を協定世界時で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 分を協定世界時で設定する
date_obj.setUTCMinutes(59);

// 出力テスト
trace(date_obj.toString());
 

■秒について

 
■秒を現地時間で取得する
 
秒を、現地時間で取得するには、getSeconds() メソッドを使用します。
 
0 から 59 までの数値が取得できます。
 
秒を現地時間で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 秒を現地時間で取得する
var seconds:Number = date_obj.getSeconds();

// 出力テスト
trace(seconds);
 
■秒を協定世界時で取得する
 
秒を、協定世界時で取得するには、getUTCSeconds() メソッドを使用します。
 
0 から 59 までの数値が取得できます。
 
秒を協定世界時で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 秒を協定世界時で取得する
var seconds:Number = date_obj.getUTCSeconds();

// 出力テスト
trace(seconds);
 
■秒を現地時間で設定する
 
秒を、現地時間で設定するには、setSeconds() メソッドを使用します。
 
引数に、0 から 59 までの数値を指定します。
 
Date.setSeconds( 秒 , ミリ秒 ) :Number
第01引数 Number秒を指定。0 ~ 59
第02引数(略可)Numberミリ秒を指定。0 ~ 999
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
秒を現地時間で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 秒を現地時間で設定する
date_obj.setSeconds(59);

// 出力テスト
trace(date_obj.toString());
 
■秒を協定世界時で設定する
 
秒を、協定世界時で設定するには、setUTCSeconds() メソッドを使用します。
 
引数に、0 から 59 までの数値を指定します。
 
Date.setUTCSeconds( 秒 , ミリ秒 ) :Number
第01引数 Number秒を指定。0 ~ 59
第02引数(略可)Numberミリ秒を指定。0 ~ 999
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
秒を協定世界時で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 秒を協定世界時で設定する
date_obj.setUTCSeconds(59);

// 出力テスト
trace(date_obj.toString());
 

■ミリ秒について

 
■ミリ秒を現地時間で取得する
 
ミリ秒を、現地時間で取得するには、getMilliseconds() メソッドを使用します。
 
0 から 999 までの数値が取得できます。
 
ミリ秒を現地時間で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// ミリ秒を現地時間で取得する
var milliseconds:Number = date_obj.getMilliseconds();

// 出力テスト
trace(milliseconds);
 
■ミリ秒を協定世界時で取得する
 
ミリ秒を、協定世界時で取得するには、getUTCMilliseconds() メソッドを使用します。
 
0 から 999 までの数値が取得できます。
 
ミリ秒を協定世界時で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// ミリ秒を協定世界時で取得する
var milliseconds:Number = date_obj.getUTCMilliseconds();

// 出力テスト
trace(milliseconds);
 
■ミリ秒を現地時間で設定する
 
ミリ秒を、現地時間で設定するには、setMilliseconds() メソッドを使用します。
 
引数に、0 から 999 までの数値を指定します。
 
Date.setMilliseconds( ミリ秒 ) :Number
第01引数 Numberミリ秒を指定。0 ~ 999
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
ミリ秒を現地時間で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// ミリ秒を現地時間で設定する
date_obj.setMilliseconds(999);

// 出力テスト
trace(date_obj.toString());
 
■ミリ秒を協定世界時で設定する
 
ミリ秒を、協定世界時で設定するには、setUTCMilliseconds() メソッドを使用します。
 
引数に、0 から 999 までの数値を指定します。
 
Date.setUTCMilliseconds( ミリ秒 ) :Number
第01引数 Numberミリ秒を指定。0 ~ 999
戻り値 Number1970年01月01日 00:00:00 から開始して、経過した時間をミリ秒で得られる
 
ミリ秒を協定世界時で設定する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// ミリ秒を協定世界時で設定する
date_obj.setUTCMilliseconds(999);

// 出力テスト
trace(date_obj.toString());
 

■協定世界時と現地時間との時間差を取得する

 
協定世界時と現地時間との時間差を取得するには、getTimezoneOffset() メソッドを使用します。
 
単位は、分です。
 
日本では -540 (分) が得られます。
 
現在のローカル時間に、得られた値を加算すると、協定世界時に変換できます。
 
協定世界時とローカルとの時間差を取得

// Date オブジェクトを作成する
var date_obj:Date = new Date();

// 協定世界時とローカルとの時間差を取得
var timezone_offset:Number = date_obj.getTimezoneOffset();

// 出力テスト
trace(timezone_offset);
 
 

 

デジタル時計を作成する

 

サンプルをダウンロード
 
 


■『日付と時刻』を取得する

 
■『日付と時刻』を取得する(『年/月/日 (曜日) 時:分:秒.ミリ秒』表記)
 
『日付と時刻』を、『年/月/日 (曜日) 時:分:秒.ミリ秒』表記で取得します。
 
西暦、月、日、曜日、時、分、秒、ミリ秒を取得して、文字列として連結します。
 
『日付と時刻』を、『年/月/日 (曜日) 時:分:秒.ミリ秒』表記で取得

// ------------------------------------------------------------
// Date オブジェクトから、『年/月/日 (曜日) 時:分:秒.ミリ秒』を取得する関数
// ------------------------------------------------------------
function DateGetStringJp(date_obj:Date):String{

	// 曜日
	var ary:Array = ["日","月","火","水","木","金","土"];

	// 日付/時間を取得
	var year:Number = date_obj.getFullYear();
	var month:Number = date_obj.getMonth() + 1;
	var date:Number = date_obj.getDate();
	var week:Number = date_obj.getDay();
	var hours:Number = date_obj.getHours();
	var minutes:Number = date_obj.getMinutes();
	var seconds:Number = date_obj.getSeconds();
	var milliseconds:Number = date_obj.getMilliseconds();

	// 文字列として連結
	return year  + "/" +
		((month < 10) ? "0" : "") + month + "/" +
		((date  < 10) ? "0" : "") + date +
		" (" + ary[week] + ") " +
		((hours   < 10) ? "0" : "") + hours   + ":" +
		((minutes < 10) ? "0" : "") + minutes + ":" +
		((seconds < 10) ? "0" : "") + seconds + "." +
		((milliseconds < 100) ? "0" : "") + ((milliseconds < 10) ? "0" : "") + milliseconds;
}


// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// Date オブジェクトから、『年/月/日 (曜日) 時:分:秒.ミリ秒』を取得
var str:String = DateGetStringJp(date_obj);

// 出力テスト
trace(str);
 
■『日付と時刻』を取得する(現地時間表記)

『日付と時刻』を、現地時間表記で取得するには、toString() メソッドを使用します。
 
『日付と時刻』を、現地時間表記で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 『日付と時刻』を、現地時間表記で取得する
var str:String = date_obj.toString();

// 出力テスト
trace(str);
 
■『日付と時刻』を取得する(ロケール表記)

『日付と時刻』を、ロケール表記で取得するには、toLocaleString() メソッドを使用します。
 
『日付と時刻』を、ロケール表記で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 『日付と時刻』を、ロケール表記で取得する
var str:String = date_obj.toLocaleString();

// 出力テスト
trace(str);
 
■『日付と時刻』を取得する(協定世界時表記)

『日付と時刻』を、協定世界時表記で取得するには、toUTCString() メソッドを使用します。
 
『日付と時刻』を、協定世界時表記で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 『日付と時刻』を、協定世界時表記で取得する
var str:String = date_obj.toUTCString();

// 出力テスト
trace(str);
 

■『日付』を取得する

 
■『日付』を取得する(現地時間表記)

『日付』を、現地時間表記で取得するには、toDateString() メソッドを使用します。
 
『日付』を、現地時間表記で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 『日付』を、現地時間表記で取得する
var str:String = date_obj.toDateString();

// 出力テスト
trace(str);
 
■『日付』を取得する(ロケール表記)

『日付』を、ロケール表記で取得するには、toLocaleDateString() メソッドを使用します。
 
『日付』を、ロケール表記で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 『日付』を、ロケール表記で取得する
var str:String = date_obj.toLocaleDateString();

// 出力テスト
trace(str);
 

■『時刻』を取得する

 
■『時刻』を取得する(現地時間表記)

『時刻』を、現地時間表記で取得するには、toTimeString() メソッドを使用します。
 
『時刻』を、現地時間表記で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 『時刻』を、現地時間表記で取得する
var str:String = date_obj.toTimeString();

// 出力テスト
trace(str);
 
■『時刻』を取得する(ロケール表記)

『時刻』を、ロケール表記で取得するには、toLocaleTimeString() メソッドを使用します。
 
『時刻』を、ロケール表記で取得する

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 『時刻』を、ロケール表記で取得する
var str:String = date_obj.toLocaleTimeString();

// 出力テスト
trace(str);
 
 

 

アナログ時計を作成する

 

サンプルをダウンロード
 


■アナログ時計を作成する

 
■針が描かれたムービークリップを用意する
 
針が、上方向を向いている、ムービークリップを3種類用意します。
 
短針用ムービークリップを "tansin"
 
長針用ムービークリップを "tyousin"
 
秒針用ムービークリップを "byousin"
 
とします。
 
■秒針の角度について
 
秒を取得するには、getSeconds() メソッドを使用します。
 
60 で割り、0.0 ~ 1.0 の大きさにします。
 
360 を掛けて、角度に変換します。
 
秒針の角度

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 秒針の角度をセットする
byousin.rotation = date_obj.getSeconds() / 60 * 360;
 
■長針の角度について
 
分を取得するには、getMinutes() メソッドを使用します。
 
60 で割り、0.0 ~ 1.0 の大きさにします。
 
360 を掛けて、角度に変換します。
 
長針の角度

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 長針の角度をセットする
tyousin.rotation = date_obj.getMinutes() / 60 * 360;
 
■短針の角度について
 
時を取得するには、getHours() メソッドを使用します。
 
分を取得するには、getMinutes() メソッドを使用します。
 
時を、24 で割り、0.0 ~ 1.0 の大きさにします。
 
短針は 1 日 2 周するので、720 を掛けて、角度に変換します。
 
分を、60 で割り、0.0 ~ 1.0 の大きさにします。
 
短針は 1 時間に 30 度回転するので、30 を掛けて、角度に加算します。
 
短針の角度

// 現在のローカル時間が格納された、Date オブジェクトを作成する
var date_obj:Date = new Date();

// 短針の角度をセットする
tansin.rotation = (date_obj.getHours() / 24 * 720) + (date_obj.getMinutes() / 60 * 30);