マイクについて

import flash.media.Microphone;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// 出力テスト
trace(mic_obj);

import flash.media.Microphone;

// 0 番目のマイクオブジェクトを取得
var mic_obj0:Microphone = Microphone.getMicrophone(0);

// 1 番目のマイクオブジェクトを取得
var mic_obj1:Microphone = Microphone.getMicrophone(1);

// 出力テスト
trace(mic_obj0);
trace(mic_obj1);

import flash.media.Microphone;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){

	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack(true);

	// スピーカー出力を止める
	//mic_obj.setLoopBack(false);

}

import flash.media.Microphone;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){

	trace("マイク機能のミュート設定:" + mic_obj.muted);

}

import flash.media.Microphone;
import flash.events.StatusEvent;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// マイクへのアクセス許可が変化した時に実行されるイベント
	mic_obj.addEventListener(StatusEvent.STATUS,function (e:StatusEvent):void{
		switch(e.code){
		case "Microphone.Unmuted":
			trace("マイク利用可能");
			break;
		case "Microphone.Muted":
			trace("マイク利用不可能");
			break;
		}
	});
}

import flash.media.Microphone;

// マイクデバイスの総数を取得
var num:int = Microphone.names.length;

// 出力テスト
trace(num);

import flash.media.Microphone;

// マイクデバイスの名称をまとめて取得する
var camera_names:Array = Microphone.names;

var i:int;
var num:int = camera_names.length;
for(i=0;i < num;i++){
	// デバイス名を出力
	trace("id:" + i + " name:" + camera_names[i]);
}

import flash.media.Microphone;

var i:int;
var num:int = Microphone.names.length;
for(i=0;i < num;i++){

	// マイクオブジェクトを取得
	var mic_obj:Microphone = Microphone.getMicrophone(i);

	// デバイス名を出力
	trace("id:" + i + " name:" + mic_obj.name);
}

import flash.media.Microphone;
import flash.text.TextField;

// テキストフィールドを作成
var text_field:TextField = new TextField();
text_field.x = 10;
text_field.y = 10;
text_field.width = stage.stageWidth - 20;
text_field.height = 20;
text_field.border = true;
stage.addChild(text_field);

text_field.text = "マイク機能が利用可能:" + Microphone.isSupported;

<?xml version="1.0" encoding="UTF-8" standalone="no" ?>
<application xmlns="http://ns.adobe.com/air/application/2.0">

  ～略～

  <android>
    <manifestAdditions>
      <![CDATA[<manifest>
<uses-permission android:name="android.permission.RECORD_AUDIO"/>
      </manifest>]]>
    </manifestAdditions>
  </android>

</application>

import flash.media.Microphone;

// デフォルトの「強化版マイクオブジェクト」を取得
var mic_obj:Microphone = Microphone.getEnhancedMicrophone();

// 出力テスト
trace(mic_obj);

import flash.media.Microphone;

// 0 番目の「強化版マイクオブジェクト」を取得
var mic_obj0:Microphone = Microphone.getEnhancedMicrophone(0);

// 1 番目の「強化版マイクオブジェクト」を取得
var mic_obj1:Microphone = Microphone.getEnhancedMicrophone(1);

// 出力テスト
trace(mic_obj0);
trace(mic_obj1);

import flash.media.Microphone;
import flash.media.MicrophoneEnhancedOptions;

// デフォルトの「強化版マイクオブジェクト」を取得
var mic_obj:Microphone = Microphone.getEnhancedMicrophone();

// マイクが利用可能
if(mic_obj){

	// MicrophoneEnhancedOptions オブジェクトを取得
	var mic_enhanced_options:MicrophoneEnhancedOptions = mic_obj.enhancedOptions;

	// 出力テスト
	trace(mic_enhanced_options);
}

import flash.media.Microphone;
import flash.media.MicrophoneEnhancedOptions;

// デフォルトの「強化版マイクオブジェクト」を取得
var mic_obj:Microphone = Microphone.getEnhancedMicrophone();

// マイクが利用可能
if(mic_obj){

	// MicrophoneEnhancedOptions オブジェクトを取得
	var mic_enhanced_options:MicrophoneEnhancedOptions = mic_obj.enhancedOptions;

	// MicrophoneEnhancedOptions オブジェクトの変更を反映する
	mic_obj.enhancedOptions = mic_enhanced_options;

}

import flash.media.Microphone;
import flash.media.MicrophoneEnhancedOptions;
import flash.media.MicrophoneEnhancedMode;

// デフォルトの「強化版マイクオブジェクト」を取得
var mic_obj:Microphone = Microphone.getEnhancedMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// MicrophoneEnhancedOptions オブジェクトを取得
	var mic_enhanced_options:MicrophoneEnhancedOptions = mic_obj.enhancedOptions;

	// 拡張マイクモードを設定する
	mic_enhanced_options.mode = MicrophoneEnhancedMode.HALF_DUPLEX;

	// MicrophoneEnhancedOptions オブジェクトの変更を反映する
	mic_obj.enhancedOptions = mic_enhanced_options;

}

import flash.media.Microphone;
import flash.media.MicrophoneEnhancedOptions;

// デフォルトの「強化版マイクオブジェクト」を取得
var mic_obj:Microphone = Microphone.getEnhancedMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// MicrophoneEnhancedOptions オブジェクトを取得
	var mic_enhanced_options:MicrophoneEnhancedOptions = mic_obj.enhancedOptions;

	// 音声エコー除去機能のエコーパスを設定する
	mic_enhanced_options.echoPath = 256;

	// MicrophoneEnhancedOptions オブジェクトの変更を反映する
	mic_obj.enhancedOptions = mic_enhanced_options;

}

import flash.media.Microphone;
import flash.media.MicrophoneEnhancedOptions;

// デフォルトの「強化版マイクオブジェクト」を取得
var mic_obj:Microphone = Microphone.getEnhancedMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// MicrophoneEnhancedOptions オブジェクトを取得
	var mic_enhanced_options:MicrophoneEnhancedOptions = mic_obj.enhancedOptions;

	// ノンリニア処理を設定する
	mic_enhanced_options.nonLinearProcessing = true;

	// MicrophoneEnhancedOptions オブジェクトの変更を反映する
	mic_obj.enhancedOptions = mic_enhanced_options;

}

import flash.media.Microphone;
import flash.media.MicrophoneEnhancedOptions;

// デフォルトの「強化版マイクオブジェクト」を取得
var mic_obj:Microphone = Microphone.getEnhancedMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// MicrophoneEnhancedOptions オブジェクトを取得
	var mic_enhanced_options:MicrophoneEnhancedOptions = mic_obj.enhancedOptions;

	// オートゲイン処理を設定する
	mic_enhanced_options.autoGain = true;

	// MicrophoneEnhancedOptions オブジェクトの変更を反映する
	mic_obj.enhancedOptions = mic_enhanced_options;

}

import flash.media.Microphone;
import flash.media.MicrophoneEnhancedOptions;
import flash.events.Event;

// デフォルトの「強化版マイクオブジェクト」を取得
var mic_obj:Microphone = Microphone.getEnhancedMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// 毎フレーム実行されるイベント
	stage.addEventListener(Event.ENTER_FRAME,function (e:Event):void{

		// MicrophoneEnhancedOptions オブジェクトを取得
		var mic_enhanced_options:MicrophoneEnhancedOptions = mic_obj.enhancedOptions;

		trace("音声検出:" + mic_enhanced_options.isVoiceDetected);
	});
}

import flash.media.Microphone;
import flash.media.SoundTransform;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// サウンドトランスフォームオブジェクトを取得
	var sound_transform : SoundTransform = mic_obj.soundTransform;

	// ボリュームを設定 (0.0 ～ 1.0)
	sound_transform.volume = 0.5;

	// サウンドトランスフォームオブジェクトをセットして反映
	mic_obj.soundTransform = sound_transform;
}

import flash.media.Microphone;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// ゲインを設定
	mic_obj.gain = 50;
}

import flash.media.Microphone;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// キャプチャーレートを設定
	mic_obj.rate = 44;
}

import flash.media.Microphone;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// エコー抑制を設定する
	mic_obj.setUseEchoSuppression(true);
}

import flash.media.Microphone;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// エコー抑制を設定する
	mic_obj.setUseEchoSuppression(true);

	// エコー抑制の状態を取得する
	trace(mic_obj.useEchoSuppression);
}

import flash.media.Microphone;
import flash.events.ActivityEvent;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// アクティビティの有無が切り替わると呼び出されるイベント
	mic_obj.addEventListener(ActivityEvent.ACTIVITY,function (e:ActivityEvent):void{
		if(e.activating){
			trace("有音状態");
		}else{
			trace("無音状態");
		}
	});
}

import flash.media.Microphone;
import flash.events.ActivityEvent;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// アクティビティ検出のしきい値を設定
	mic_obj.setSilenceLevel(10,0);

	// アクティビティの有無が切り替わると呼び出されるイベント
	mic_obj.addEventListener(ActivityEvent.ACTIVITY,function (e:ActivityEvent):void{
		if(e.activating){
			trace("有音状態");
		}else{
			trace("無音状態");
		}
	});
}

import flash.media.Microphone;
import flash.events.ActivityEvent;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// アクティビティ検出のしきい値を設定
	mic_obj.setSilenceLevel(10,0);

	// アクティビティ検出のしきい値を取得する
	trace(mic_obj.silenceLevel);

	// 無音状態と判定するまでの時間を取得
	trace(mic_obj.silenceTimeout);
}

import flash.media.Microphone;
import flash.events.Event;
import flash.events.ActivityEvent;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// アクティビティ検出のしきい値を設定
	mic_obj.setSilenceLevel(10,0);

	// アクティビティの有無が切り替わると呼び出されるイベント
	mic_obj.addEventListener(ActivityEvent.ACTIVITY,function (e:ActivityEvent):void{
		trace("アクティビティ:" + e.activating);
	});

	// 毎フレーム実行されるイベント
	stage.addEventListener(Event.ENTER_FRAME,function (e:Event):void{
		trace("アクティビティレベル:" + mic_obj.activityLevel);
	});
}

import flash.media.Microphone;
import flash.utils.ByteArray;
import flash.events.Event;
import flash.events.SampleDataEvent;

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// サウンドデータが一定量貯まるたびに呼び出されるイベント
	mic_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, function (e:SampleDataEvent):void{

		// 現在のサンプリング位置
		var pos:Number = e.position;

		// サウンドのバイナリデータ
		var data:ByteArray = e.data;

		// 出力テスト
		trace("現在のサンプリング位置:" + pos);
		trace("サウンドバッファのサイズ:" + data.length);
	});
}

import flash.media.Microphone;
import flash.utils.ByteArray;
import flash.events.Event;
import flash.events.SampleDataEvent;

// 録音用バッファ
var record_buffer:ByteArray = new ByteArray();

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// キャプチャレートを設定する
	mic_obj.rate = 44;

	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// サウンドデータが一定量貯まるたびに呼び出されるイベント
	mic_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, function (e:SampleDataEvent):void{
		var data:ByteArray = e.data;

		// 欠落区間があれば 0.0 で埋める
		var add:Number = e.position * 4 - record_buffer.length;
		if(add > 0){
			record_buffer.length += add;
		}

		// サウンドデータを録音用バッファの最後尾に追加
		data.readBytes(record_buffer,record_buffer.length,data.length);
	});
}

import flash.media.Microphone;
import flash.media.Sound;
import flash.utils.ByteArray;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.events.SampleDataEvent;

// 録音用バッファ
var record_buffer:ByteArray = new ByteArray();

// デフォルトのマイクオブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// マイクが利用可能
if(mic_obj){
	// マイクから入力した音をスピーカーから出力
	mic_obj.setLoopBack();

	// キャプチャレートを設定する
	mic_obj.rate = 44;

	// 実際に採用されたキャプチャーレートを取得する
	var capture_rate:Number = mic_obj.rate;
	switch(capture_rate){
	case  5: capture_rate =  5512; break;
	case 11: capture_rate = 11025; break;
	case 22: capture_rate = 22050; break;
	case 44: capture_rate = 44100; break;
	default: capture_rate = capture_rate * 1000; break;
	}

	// ------------------------------------------------------------
	// サウンドデータが一定量貯まるたびに呼び出されるイベント
	// ------------------------------------------------------------
	mic_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, function (e:SampleDataEvent):void{
		var data:ByteArray = e.data;

		// 欠落区間があれば 0.0 で埋める
		var add:Number = e.position * 4 - record_buffer.length;
		if(add > 0){
			record_buffer.length += add;
		}

		// サウンドデータを録音用バッファの最後尾に追加
		data.readBytes(record_buffer,record_buffer.length,data.length);
	});


	// ------------------------------------------------------------
	// マウスの左ボタンを押下すると実行されるイベント
	// ------------------------------------------------------------
	stage.addEventListener(MouseEvent.MOUSE_DOWN,function (e:MouseEvent):void{

		// 1 度に転送するサンプリング数
		var sampling:int = 2048;

		// ------------------------------------------------------------
		// サウンドオブジェクト
		// ------------------------------------------------------------
		// サウンドオブジェクトを作成
		var sound_obj:Sound = new Sound();

		// サウンドデータ要求時に呼び出されるイベント
		sound_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, function (e:SampleDataEvent):void{
			var i:int;
			var d:Number;
			var data:ByteArray = e.data;

			// 録音バッファの位置を残す
			var record_buffer_pos:Number = record_buffer.position;

			try{
				for(i=0;i < sampling;i++){
					// 再生サンプリング位置から録音バッファの位置を計算
					record_buffer.position = Math.floor((i + e.position) * (capture_rate / 44100)) * 4;

					// 録音バッファから１つ分のデータを取得
					d = record_buffer.readFloat();

					// L と R に書き込み
					data.writeFloat(d);
					data.writeFloat(d);
				}

			}catch(e:Error){
				// 0.0 で埋める
				data.length = sampling * 2 * 4;
			}

			// 録音バッファの位置を戻す
			record_buffer.position = record_buffer_pos;
		});

		// 再生開始
		sound_obj.play();
	});
}