文字列について（String）

// ------------------------------------------------------------
// 文字列を作成する
// ------------------------------------------------------------
var str:String = new String("あいうえお");

// 出力テスト
trace(typeof(str)); // "string"
trace(str); // "あいうえお"

// 文字列を作成する
var str:String = 'あいうえお';

// 文字列を作成する
var str:String = "かきくけこ";

var str:String;

str = '<element attribute = "value" >';
str = "<element attribute = 'value' >";

str = '<element attribute = \'value\' >';
str = "<element attribute = \"value\" >";

// ------------------------------------------------------------
// 文字列を作成する
// ------------------------------------------------------------
var str:String = "あいうえお";

// ------------------------------------------------------------
// 文字列の最後尾に、任意の文字列を連結する
// ------------------------------------------------------------
str += "かきくけこ";

// 出力テスト
trace(str); // "あいうえおかきくけこ"

// ------------------------------------------------------------
// 文字列を作成する
// ------------------------------------------------------------
var str0:String = "あいうえお";
var str1:String = "かきくけこ";

// ------------------------------------------------------------
// 文字列同士を連結し、新しい文字列を生成する
// ------------------------------------------------------------
var str2:String = str0 + str1;

// 出力テスト
trace(str2); // "あいうえおかきくけこ"

// 文字列を作成する
var str:String = 123 + "あいう";

// 出力テスト
trace(str); // "123あいう

// 文字列を作成する
var str:String = 1 + 2 + 3 + "あいう" + 49 + 58 + 67 + "かきく";

// 出力テスト
trace(str); // "6あいう495867かきく"

// 文字列を作成する
var str:String = (1 + 2 + 3) + "あいう" + (49 + 58 + 67) + "かきく";

// 出力テスト
trace(str); // "6あいう174かきく"

// ------------------------------------------------------------
// 文字列を作成する
// ------------------------------------------------------------
var str0:String = "あいうえお";
var str1:String = "あいうえお";

// ------------------------------------------------------------
// 文字列が一致しているか調べる
// ------------------------------------------------------------
var result:Boolean = (str0 === str1);

// 出力テスト
trace(result); // true

// ------------------------------------------------------------
// 文字列を作成する
// ------------------------------------------------------------
var str0:String = "あああああ";
var str1:String = "ああああい";

// ------------------------------------------------------------
// 文字列を比較する
// ------------------------------------------------------------
if(str0 === str1){

	trace("厳密に等しい");

}else if(str0 < str1){

	trace(str0 + " < " + str1);

}else if(str0 > str1){

	trace(str0 + " > " + str1);

}

// 文字列を作成する
var str:String = "あいうえお";

// 文字の総数を取得
var num:int = str.length;

// 出力テスト
trace(num); // 5

// 文字コードを指定して、１文字を取得する
var c0:String = String.fromCharCode(0x41);
var c1:String = String.fromCharCode(0x3042);

// 出力テスト
trace(c0); // "A"
trace(c1); // "あ"

// 文字コードを順番に指定して、文字列を取得する。
var str:String = String.fromCharCode(0x41,0x42,0x43,0x44,0x45,0x46,0x47);

// 出力テスト
trace(str); // "ABCDEFG"

// 文字列を作成
var str:String = "あいうえお";

// 位置を指定して、文字列から１文字を取得する
var c0:String = str.charAt(1);
var c1:String = str.charAt(3);

// 出力テスト
trace(c0); // "い"
trace(c1); // "え"

// 文字列を作成
var str:String = "あいうえお";

// 位置を指定して、文字列から文字コードを取得する
var c0:Number = str.charCodeAt(0);
var c1:Number = str.charCodeAt(3);

// 出力テスト
trace(c0); // 12354 (0x3042)
trace(c1); // 12360 (0x3048)

// 'あ' の文字コードを取得
var c:Number = 'あ'.charCodeAt();

// 出力テスト
trace(c); // 12354 (0x3042)

// 文字列を作成
var str0:String = "あいうえお";
var str1:String = "かきくけこ";

// 文字列を結合して、新しい文字列を取得する
var str2:String = str0.concat(str1);

// 出力テスト
trace(str2); // "あいうえおかきくけこ"

// 文字列を結合して、新しい文字列を取得する
var str:String = "あいう".concat("え" , "おか" , "き" , "くけこ");

// 出力テスト
trace(str); // "あいうえおかきくけこ"

// 文字列を作成
var str0:String = "あいうえおかきくけこ";

// 開始位置と終了位置を指定して、新しい文字列を取得する
var str1:String = str0.slice(2,5);

// 出力テスト
trace(str1); // "うえお"

// 文字列を作成
var str0:String = "あいうえおかきくけこ";

// 開始位置と終了位置を指定して、新しい文字列を取得する
var str1:String = str0.substring(2,5);

// 出力テスト
trace(str1); // "うえお"

// 文字列を作成
var str0:String = "あいうえおかきくけこ";

// 開始位置と個数を指定して、新しい文字列を取得する
var str1:String = str0.substr(5,3);

// 出力テスト
trace(str1); // "かきく"

// 文字列を作成
var str:String = "---あいう-----";

// 最先頭から文字列内を検索する
var pos:Number = str.indexOf("あいう");

// 出力テスト
trace(pos); // 3

// 検索本文
var source:String = "--あいう------あいう--あいう------あいう--------";

// 検索ワード
var search:String = "あいう";

// 検索位置
var pos:Number = 0;

while(true){

	// 指定位置から文字列内を検索する
	pos = source.indexOf(search,pos);

	// 見つからなかった場合終了
	if(pos == -1) break;

	// 出力テスト
	trace("pos:" + pos);

	// 次の検索開始位置
	pos += search.length;
}

// 文字列を作成
var str:String = "-----あいう---";

// 最後尾から文字列内を検索する
var pos:Number = str.lastIndexOf("あいう");

// 出力テスト
trace(pos); // 5

// 検索本文
var source:String = "--あいう------あいう--あいう------あいう--------";

// 検索ワード
var search:String = "あいう";

// 検索位置
var pos:Number = source.length;

while(pos >= 0){

	// 指定位置から文字列内を検索する
	pos = source.lastIndexOf(search,pos);

	// 見つからなかった場合終了
	if(pos == -1) break;

	// 出力テスト
	trace("pos:" + pos);

	// 次の検索開始位置
	pos -= search.length;
}

// 文字列を作成
var str0:String = "あああああ";
var str1:String = "ああああい";

// 文字列同士を比較する
var result:int = str0.localeCompare(str1);

// 出力テスト
trace(result); // -2

// 文字列を作成
var str0:String = "AbCdEfG";

// 大文字を小文字に変換する
var str1:String = str0.toLowerCase();

// 出力テスト
trace(str1); // "abcdefg"

// 文字列を作成
var str0:String = "AbCdEfG";

// 小文字を大文字に変換する
var str1:String = str0.toUpperCase();

// 出力テスト
trace(str1); // "ABCDEFG"

// 文字列を作成
var str0:String = "AbCdEfG";

// 大文字を小文字に変換する（実行環境のロケールを考慮）
var str1:String = str0.toLocaleLowerCase();

// 出力テスト
trace(str1); // "abcdefg"

// 文字列を作成
var str0:String = "AbCdEfG";

// 小文字を大文字に変換する（実行環境のロケールを考慮）
var str1:String = str0.toLocaleUpperCase();

// 出力テスト
trace(str1); // "ABCDEFG"

// 文字列を作成
var str:String = "あ=いい=ううう=ええ=お";

// 文字列を分割し、配列を取得する
var ary:Array = str.split("=");

// 出力テスト
trace(ary); // [ "あ" , "いい" , "ううう" , "ええ" , "お" ]

// 文字列を作成
var str:String = "ＡＡＡandＢＢandＣＣＣandＤandＥＥＥ";

// 文字列を最大で２回まで分割し、配列を取得する
var ary:Array = str.split("and" , 2);

// 出力テスト
trace(ary); // [ "ＡＡＡ" , "ＢＢ" ]

// ------------------------------------------------------------
// 文字列を作成
// ------------------------------------------------------------
var str:String = "ＡＡＡ--ＢＢ----ＣＣＣ--Ｄ--------ＥＥＥ";

// ------------------------------------------------------------
// 正規表現オブジェクトを作成
// ------------------------------------------------------------
var re:RegExp = new RegExp("[-]+","");

// ------------------------------------------------------------
// 文字列を分割し、配列を取得する
// ------------------------------------------------------------
var ary:Array = str.split(re);

// ------------------------------------------------------------
// 出力テスト
// ------------------------------------------------------------
trace(ary); // [ "ＡＡＡ" , "ＢＢ" , "ＣＣＣ" , "Ｄ" , "ＥＥＥ" ]

// 文字列を作成
var str:String = "あいうえおかきくけこさしすせそ";

// マッチする位置を取得する
var index:int = str.search("かきくけこ");

// 出力テスト
trace(index); // 5

// ------------------------------------------------------------
// 文字列を作成
// ------------------------------------------------------------
var str:String = "あいうえおかきくけこさしすせそ";

// ------------------------------------------------------------
// 正規表現オブジェクトを作成
// ------------------------------------------------------------
var re:RegExp = new RegExp("(か)(.+)(こ)","");

// ------------------------------------------------------------
// 正規表現とマッチする位置を取得する
// ------------------------------------------------------------
var index:int = str.search(re);

// マッチした
if(index >= 0){

	// ------------------------------------------------------------
	// 出力テスト
	// ------------------------------------------------------------
	trace(index); // 5

}

// ------------------------------------------------------------
// 文字列を作成
// ------------------------------------------------------------
var str:String = "あいうえおかきくけこさしすせそ";

// ------------------------------------------------------------
// 正規表現オブジェクトを作成
// ------------------------------------------------------------
var re:RegExp = new RegExp("(か)(.+)(こ)","");

// ------------------------------------------------------------
// 正規表現とマッチした部分の文字列を取得する
// ------------------------------------------------------------
var m:Object = str.match(re);

// マッチした
if(m){

	// ------------------------------------------------------------
	// 出力テスト
	// ------------------------------------------------------------
	// 全体マッチ
	trace(m[0]); // "かきくけこ"

	// 丸括弧内のマッチ
	trace(m[1]); // "か"
	trace(m[2]); // "きくけ"
	trace(m[3]); // "こ"

	// その他のプロパティ
	trace(m.input); // "あいうえおかきくけこさしすせそ"
	trace(m.index); // 5

}

// ------------------------------------------------------------
// 文字列を作成
// ------------------------------------------------------------
var str:String = "あいうえおかきくけこさしすせそ";

// ------------------------------------------------------------
// 正規表現オブジェクトを作成
// ------------------------------------------------------------
var re:RegExp = new RegExp("[あ-ん]{5}","g");

// ------------------------------------------------------------
// 正規表現とマッチした部分の文字列を取得する
// ------------------------------------------------------------
var m:Array = str.match(re);

// マッチした
if(m){

	// ------------------------------------------------------------
	// 出力テスト
	// ------------------------------------------------------------
	// マッチ総数
	trace(m.length); // 3

	// １回目の全体マッチ
	trace(m[0]); // "あいうえお"

	// ２回目の全体マッチ
	trace(m[1]); // "かきくけこ"

	// ３回目の全体マッチ
	trace(m[2]); // "さしすせそ"

}

// ------------------------------------------------------------
// 文字列を作成
// ------------------------------------------------------------
var str0:String = "あい▲▲▲えお";

// ------------------------------------------------------------
// "▲▲▲" を "う" に置換する
// ------------------------------------------------------------
var str1:String = str0.replace("▲▲▲","う");

// ------------------------------------------------------------
// 出力テスト
// ------------------------------------------------------------
trace(str1); // "あいうえお"

// 正規表現オブジェクトを作成（繰り返しフラグ付き）
var re:RegExp = new RegExp("(.)","g");

// 文字列を作成
var str0:String = "あいうえおかき";

// 正規表現オブジェクトを作成
var re:RegExp = new RegExp("(う)(え)(お)","");

// 文字列を置換する
var str1:String = str0.replace(re,"| left:$` match:$& p1:$1 p2:$2 p3:$3 right:$' |");

// 出力テスト
trace(str1); // "...| left:あい match:うえお p1:う p2:え p3:お right:かき |..."

// ------------------------------------------------------------
// 文字列を作成
// ------------------------------------------------------------
var str0:String = "□●●□□●●●□";

// ------------------------------------------------------------
// 正規表現オブジェクトを作成（繰り返しフラグ付き）
// ------------------------------------------------------------
var re:RegExp = new RegExp("□","g");


// ------------------------------------------------------------
// "□" を "■" に置換する（文字列指定）
// ------------------------------------------------------------
var str1:String = str0.replace(re,"■");

// ------------------------------------------------------------
// 出力テスト
// ------------------------------------------------------------
trace(str1); // "■●●■■●●●■"


// ------------------------------------------------------------
// "□" を "■" に置換する（コールバック関数指定）
// ------------------------------------------------------------
var str2:String = str0.replace(re,function ( m:String , index:Number , str:String ) :String {

	// 出力テスト
	trace("index:" + index);

	// 置換する文字列を返す
	return "■";
});

// ------------------------------------------------------------
// 出力テスト
// ------------------------------------------------------------
trace(str2); // "■●●■■●●●■"

// ------------------------------------------------------------
// 文字列を作成
// ------------------------------------------------------------
var str0:String = "★★★http://sub.example.com/aaa/bbb/ccc.html★★★";

// ------------------------------------------------------------
// 正規表現オブジェクトを作成
// ------------------------------------------------------------
var re:RegExp = new RegExp("([a-z]*:)[/]*([^/]+)/([^?#]*)","");


// ------------------------------------------------------------
// ドルエスケープ文字を使って、丸括弧内を展開する
// ------------------------------------------------------------
var str1:String = str0.replace(re,"「$1」「$2」「$3」");

// ------------------------------------------------------------
// 出力テスト
// ------------------------------------------------------------
trace(str1); // "★★★「http:」「sub.example.com」「aaa/bbb/ccc.html」★★★"


// ------------------------------------------------------------
// コールバック関数を使って、丸括弧内を展開する
// ------------------------------------------------------------
var str2:String = str0.replace(re,function ( m:String , p1:String , p2:String , p3:String , index:Number , str:String ) :String {

	// 出力テスト
	trace(arguments);

	// 置換する文字列を返す
	return "「" + p1 + "」「" + p2 + "」「" + p3 + "」";
});

// ------------------------------------------------------------
// 出力テスト
// ------------------------------------------------------------
trace(str2); // "★★★「http:」「sub.example.com」「aaa/bbb/ccc.html」★★★"

// ------------------------------------------------------------
// HTML 文字列を作成
// ------------------------------------------------------------
var text_html:String = 
'<html>\n' +
'  <body>\n' +
'    <img src="http://sub.example.com/graphics/aaa.jpg">\n' +
'    <img src="http://sub.example.com/graphics/bbb.jpg">\n' +
'    <img src="http://sub.example.com/graphics/ccc.jpg">\n' +
'  </body>\n' +
'</html>';

// ------------------------------------------------------------
// 正規表現オブジェクトを作成（繰り返しフラグ付き）
// ------------------------------------------------------------
var re:RegExp = new RegExp('<img[ \t\r\n]+[^>]*src[ \t\r\n]*=[ \t\r\n]*"([^"]+)"',"g");

// ------------------------------------------------------------
// 繰り返し検索（置換機能を無視）
// ------------------------------------------------------------
text_html.replace(re,function ( m:String , p1:String , index:Number , str:String ) :void {

	// 出力テスト
	trace(arguments);
	trace("index:" + index);
	trace("p1:" + p1);
	trace(" --- ");

});

// 数値を作成する
var value:Number = 123.456;

// 文字列に変換する
var str:String = String(value);

// 出力テスト
trace(str); // "123.456"
trace(typeof(str)); // "string"

// 数値を作成する
var value:Number = 123.456;

// 空文字と連結して、文字列に変換する
var str:String = "" + value;

// 出力テスト
trace(str); // "123.456"
trace(typeof(str)); // "string"

var str:String = "\tあいうえお\n\tかきくけこ";

var str:String = "\u3042 \u3044 \u3046 \u3048 \u304a";

var str:String = "\x41 \x44 \x47 \x4a \x4c";