キーボード操作について

・	キーボードが押されたか調べる
・	キーコードの一覧表
・	２つのキーが同時に押されたか調べる
・	キーボードが押された瞬間を調べる
・	キーボードが離された瞬間を調べる
・	すべてのキーが押されていないかを調べる
・	キーボードを押してムービークリップを動かす
・	キーボード操作の割り当てを変更する

前のページに戻る

キーボードが押されたか調べる

サンプルをダウンロード

key_00_fla05_as1.fla MacroMedia Flash 5

key_00_fla06_as1.fla Macromedia Flash MX ActionScript1.0

■ボタンイベントを使用する

■ Key クラスの取得用のメソッドを使用する

■イベントリスナーを使って調べる(Flash 6 以降)

■ボタンイベントを使用する

on ハンドラの keyPress イベントを使用すると、キーボードの入力を検出する事ができます。

キーを押しっぱなし時の入力検出タイミングは、タイピング風となります。

on ハンドラは、ボタンインスタンスに直接記述することができる命令文です。

Flash 6 以降であれば、ムービークリップインスタンスにも記述する事ができます。

"" の部分にアルファベットを指定するとそのキーが押されたときに実行されます。

大文字を指定すると、Shiftキーと同時に押されたときに実行されます。

例) キーボードが押されたときに実行されるイベント


on( keyPress "a" ){
	trace("A が押された");
}

on( keyPress "A" ){
	trace("shift + A が押された");
}

■ Key クラスの取得用のメソッドを使用する

キーボードが押されているかを調べるには、Key.isDown() メソッドを使用します。

引数に、キーコードを指定します。

例えば、 A キーが押されたか調べたいなら、65 を指定します。

例えば、 B キーが押されたか調べたいなら、66 を指定します。

指定したキーが押されていれば、戻り値から true が得られます。

Key.isDown ( キーコード ) :Boolean

第01引数	Number	キーコードを数値で指定
戻り値	Boolean	押されていれば true、押されていなければ false

■キーボードの入力状態を毎フレームごとに調べる

キーボードを、ゲームの操作として使用する場合、キーボードの入力状態を、毎フレームごとに調べます。

onEnterFrame イベントを利用します。

例) onClipEvent ハンドラの enterFrame イベントを使用する


// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {

	if(Key.isDown(65)){
		trace("A キーが押された");
	}else{
		trace("A キーが押されていない");
	}

	if(Key.isDown(Key.SPACE)){
		trace("スペースキーが押された");
	}else{
		trace("スペースキーが押されていない");
	}

}

例) MovieClip クラスの onEnterFrame イベントハンドラを使用する (Flash 6 以降)


// 毎フレーム実行されるイベント
_root.onEnterFrame = function (){

	if(Key.isDown(65)){
		trace("A キーが押された");
	}else{
		trace("A キーが押されていない");
	}

	if(Key.isDown(Key.SPACE)){
		trace("スペースキーが押された");
	}else{
		trace("スペースキーが押されていない");
	}
};

■キーボードの入力状態をタイピング風に取得する

キーボードを、タイピング風に取得したい場合、onKeyDown イベントを使用します。

例) onClipEvent ハンドラの keyDown イベントを使用する


// キーボードを押したときに実行されるイベント
onClipEvent (keyDown) {

	if(Key.isDown(65)){
		trace("A キーが押された");
	}

	if(Key.isDown(Key.SPACE)){
		trace("スペースキーが押された");
	}

}

例) MovieClip クラスの onKeyDown イベントハンドラを使用する (Flash 6 以降)


// 任意のムービークリップオブジェクトの参照
var mc = _root.mc;

// キーボードを押したときに実行されるイベント
mc.onKeyDown = function (){

	if(Key.isDown(65)){
		trace("A キーが押された");
	}

	if(Key.isDown(Key.SPACE)){
		trace("スペースキーが押された");
	}
};

// フォーカスを許可する
mc.focusEnabled = true;

// フォーカスを与える (onKeyDown イベントはフォーカスを与えないと動作しない)
Selection.setFocus(mc);

■最後に押されたキーを調べる

最後に押されたキーのキーコードを調べるには、Key.getCode() メソッドを使用します。

戻り値から、最後に押されたキーコードを取得できます。

例) 最後に押されたキーのキーコードを調べる


// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {

	// 最後に押されたキーを調べる
	var code = Key.getCode();
	trace( code );

}

例) 最後に押されたキーのキーコードを調べる (Flash 6 以降)


// 毎フレーム実行されるイベント
_root.onEnterFrame = function (){

	// 最後に押されたキーを調べる
	var code = Key.getCode();
	trace( code );

};

■イベントリスナーを使って調べる(Flash 6 以降)

イベントリスナーについて

イベントハンドラを使用すると、一人のハンドラーがイベント通知を得ることができます。

イベントリスナーを使用すると、複数のリスナーがイベント通知を得ることができます。

キーイベントリスナーを使用すると、キーボード入力関係のイベント通知を知ることができます。

キーを押しっぱなし時の入力検出タイミングは、タイピング風となります。

オブジェクトを作成する

オブジェクトを作成します。

このオブジェクトは、リスナーに相当します。

オブジェクト作成


// オブジェクトを作成
var listener = new Object();

オブジェクトに関数を登録する

オブジェクトに、以下のプロパティを追加します。

各プロパティには、コールバック関数を登録します。

プロパティ名	解説
onKeyDown	キーを押したときに実行される
onKeyUp	キーを離したときに実行される

オブジェクトに関数を登録


// オブジェクトを作成
var listener = new Object();

// キーを押したときに実行されるイベント
listener.onKeyDown = function (){
	trace("キーを押した");
};

// キーを離したときに実行されるイベント
listener.onKeyUp = function (){
	trace("キーを離した");
};

どのキーが押されたか調べる

どのキーが押されたか調べるには、Key.getCode() メソッドを使用します。

得られるキーコードについては、こちらで解説しています。

コールバック関数の中で呼び出します。

押されたキーコードを取得する


// オブジェクトを作成
var listener = new Object();

// キーを押したときに実行されるイベント
listener.onKeyDown = function (){
	var code = Key.getCode();
	trace("キーを押した:" + code);
};

// キーを離したときに実行されるイベント
listener.onKeyUp = function (){
	var code = Key.getCode();
	trace("キーを離した:" + code);
};

リスナーを登録する（リッスンを開始する）

システムにリスナーを登録するには、Key.addListener() メソッドを使用します。

引数に、「コールバック関数をセットしたオブジェクト」を渡します。

これで、キーボードの入力があるたびに、コールバック関数が実行されるようになります。

リッスンを開始する


// ------------------------------------------------------------
// リスナー用オブジェクトを作成
// ------------------------------------------------------------
// オブジェクトを作成
var listener = new Object();


// ------------------------------------------------------------
// リスナーにコールバック関数を登録
// ------------------------------------------------------------
// キーボードを押したときに実行されるイベント
listener.onKeyDown = function (){
	var code = Key.getCode();
	trace("キーを押した:" + code);
};

// キーボードを離したときに実行されるイベント
listener.onKeyUp = function (){
	var code = Key.getCode();
	trace("キーを離した:" + code);
};


// ------------------------------------------------------------
// システムにリスナーを登録
// ------------------------------------------------------------
// リスナーを登録（リッスンを開始する）
Key.addListener( listener );

リスナーを除外する（リッスンを終了する）

イベント通知を止めたいときは、Key.removeListener() メソッドを使用します。

引数に、「Key.addListener() メソッドの引数で指定したオブジェクト」と同じものを渡します。

リッスンを終了する


// ------------------------------------------------------------
// リスナー用オブジェクトを作成
// ------------------------------------------------------------
// オブジェクトを作成
var listener = new Object();


// ------------------------------------------------------------
// リスナーにコールバック関数を登録
// ------------------------------------------------------------
// キーボードを押したときに実行されるイベント
listener.onKeyDown = function (){
	var code = Key.getCode();
	trace("キーを押した:" + code);
};

// キーボードを離したときに実行されるイベント
listener.onKeyUp = function (){
	var code = Key.getCode();
	trace("キーを離した:" + code);
};


// ------------------------------------------------------------
// システムにリスナーを登録
// ------------------------------------------------------------
// リスナーを登録（リッスンを開始する）
Key.addListener( listener );

// リスナーを除外（リッスンを終了する）
Key.removeListener( listener );

上に戻る

キーコードの一覧表

サンプルをダウンロード

key_01_fla05_as1.fla MacroMedia Flash 5

key_01_fla06_as1.fla Macromedia Flash MX ActionScript1.0

■キーコードの一覧表

■英数字キー

Ａ～Ｚ、０～９までのキーコードの一覧表です。

キー	keyCode
0	48
1	49
2	50
3	51
4	52
5	53
6	54
7	55
8	56
9	57
A	65
B	66
C	67
D	68
E	69
F	70
G	71
H	72
I	73
J	74
K	75
L	76
M	77
N	78
O	79
P	80
Q	81
R	82
S	83
T	84
U	85
V	86
W	87
X	88
Y	89
Z	90

■テンキー

テンキーのキーコードの一覧表です。

キー	keyCode
0	96
1	97
2	98
3	99
4	100
5	101
6	102
7	103
8	104
9	105
*	106
+	107
Enter	108
-	109
.	110
/	111

■ファンクションキー

ファンクションキーのキーコードの一覧表です。

キー	keyCode
F1	112
F2	113
F3	114
F4	115
F5	116
F6	117
F7	118
F8	119
F9	120
F10	121
F11	122
F12	123
F13	124
F14	125
F15	126

■その他

その他のキーコードの一覧表です。

キー	keyCode
BackSpace	8
Tab	9
Clear	12
Enter	13
Shift	16
Ctrl	17
Alt	18
CapsLock	20
Esc	27
スペースバー	32
PageUp	33
PageDown	34
End	35
Home	36
← (左矢印)	37
↑ (上矢印)	38
→ (右矢印)	39
↓ (下矢印)	40
Insert	45
Delete	46
Help	47
NumLock	144
: *	186
; +	187
, <	188
- =	189
. >	190
/ ?	191
@ `	192
[ {	219
\ \|	220
] }	221
^ ~	222

■キーコードの定数

キーコードの定数一覧表です。

キー	プロパティ
BackSpace	Key.TAB
Enter	Key.ENTER
Shift	Key.SHIFT
Ctrl	Key.CONTROL
CapsLock	Key.CAPSLOCK
Esc	Key.ESCAPE
スペースバー	Key.SPACE
PgUP	Key.PGUP
PgDn	Key.PGDN
End	Key.END
Home	Key.HOME
← (左矢印)	Key.LEFT
↑ (上矢印)	Key.UP
→ (右矢印)	Key.RIGHT
↓ (下矢印)	Key.DOWN
Insert	Key.INSERT
Delete	Key.DELETEKEY

■おまけ

Key.isDown()で一応識別できるキーコードの一覧表です。(Windows 環境で確認)

キー	keyCode
マウス左ボタン	1
マウス右ボタン	2
マウス中央ボタン	4

上に戻る

２つのキーが同時に押されたか調べる

サンプルをダウンロード

key_02_fla05_as1.fla MacroMedia Flash 5

key_02_fla06_as1.fla Macromedia Flash MX ActionScript1.0

■２つのキーが同時に押されたか調べる

２つのキーが同時に押されたか調べるには、 if 文でそれぞれのキーの入力状態を調べます。

どちらも真であれば、同時に押されている事がわかります。

例えば、A キーと B キーが同時に押されているか調べたい場合は、以下のように if 文で入れ子にします。

例) A キーと B キーが同時に押されたか調べる


// A キーが押されているか
if(Key.isDown(65)){

	// A キーが押されているか
	if(Key.isDown(66)){

		trace(" A キーと B キーが同時に押された");

	}
}

比較演算子を使って、「AND 条件」 "&&" で調べる事も可能です。

例) A キーと B キーが同時に押されたか調べる


if( Key.isDown(65) && Key.isDown(66) ){

	trace(" A キーと B キーが同時に押された");

}

■２つのキーのどちらでもいいので押されたか調べる

２つのキーのどちらか片方でも押されたかを調べたい場合は、

比較演算子の、「OR 条件」"||" を使用します。

例) A キーと B キーどちらか片方でも押されたかを調べる


if( Key.isDown(65) || Key.isDown(66) ){

	trace(" A キーと B キーのどちらかが押された");

}

上に戻る

キーボードが押された瞬間を調べる

サンプルをダウンロード

key_03_fla05_as1.fla MacroMedia Flash 5

key_03_fla06_as1.fla Macromedia Flash MX ActionScript1.0

■キーボードが押された瞬間とは？

キーが押された瞬間とはどういう状態でしょうか。

「１フレーム前は押されていない」、「現在のフレームで押されている」状態です。

また、キーが押しっぱなしとはどういう状態でしょうか。

「１フレーム前は押されている」、「現在のフレームも押されている」状態です。

■キーボードが押された瞬間を調べる

調べたいキーの入力状態を、毎フレーム変数に残しておきます。

例) A キーの入力を変数に格納


// 初回に一度だけ実行されるイベント
onClipEvent (load) {
	key_a = 0;
}

// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {
	key_a = Key.isDown(65);
}

例) A キーの入力を変数に格納 (Flash 6 以降)


// 初期化処理
var key_a = 0;

// 毎フレーム実行されるイベント
onEnterFrame = function (){
	key_a = Key.isDown(65);
};

そして、if 文で『１フレーム前は押されていない』かつ『現在は押されている』かを調べます。

この両方の条件を満たす場合、キーボードが押された瞬間である事がわかります。

例) A キーが押された瞬間を調べる


// 初回に一度だけ実行されるイベント
onClipEvent (load) {
	key_a = 0;
}

// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {

	if(!key_a && Key.isDown(65)){
		trace("A キーが押された");
	}

	if(key_a && Key.isDown(65)){
		trace("A キーが押しっぱなし");
	}

	key_a = Key.isDown(65);
}

例) A キーが押された瞬間を調べる (Flash 6 以降)


// 初期化処理
var key_a = 0;

// 毎フレーム実行されるイベント
onEnterFrame = function (){

	if(!key_a && Key.isDown(65)){
		trace("A キーが押された");
	}

	if(key_a && Key.isDown(65)){
		trace("A キーが押しっぱなし");
	}

	key_a = Key.isDown(65);
};

上に戻る

キーボードが離された瞬間を調べる

サンプルをダウンロード

key_04_fla05_as1.fla MacroMedia Flash 5

key_04_fla06_as1.fla Macromedia Flash MX ActionScript1.0

■キーボードが離された瞬間とは？

キーが離された瞬間とはどういう状態でしょうか。

「１フレーム前は押された」、「現在のフレームは押されていない」状態です。

また、キーが押されていないとはどういう状態でしょうか。

「１フレーム前は押されていない」、「現在のフレームも押されていない」状態です。

■キーボードが離された瞬間を調べる

調べたいキーの入力状態を、毎フレーム変数に残しておきます。

例) A キーの入力を変数に格納


// 初回に一度だけ実行されるイベント
onClipEvent (load) {
	key_a = 0;
}

// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {
	key_a = Key.isDown(65);
}

例) A キーの入力を変数に格納 (Flash 6 以降)


// 初期化処理
var key_a = 0;

// 毎フレーム実行されるイベント
onEnterFrame = function (){
	key_a = Key.isDown(65);
};

そして、if 文で『１フレーム前はキーが押されている』かつ『現在は押されていない』かを調べます。

この両方の条件を満たす場合、キーボードが離された瞬間である事がわかります。

例) A キーが離された瞬間を調べる


// 初回に一度だけ実行されるイベント
onClipEvent (load) {
	key_a = 0;
}

// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {

	if(key_a && !Key.isDown(65)){
		trace("A キーが離された");
	}

	if(!key_a && !Key.isDown(65)){
		trace("A キーは押されていない");
	}

	key_a = Key.isDown(65);
}

例) A キーが離された瞬間を調べる (Flash 6 以降)


// 初期化処理
var key_a = 0;

// 毎フレーム実行されるイベント
onEnterFrame = function (){

	if(key_a && !Key.isDown(65)){
		trace("A キーが離された");
	}

	if(!key_a && !Key.isDown(65)){
		trace("A キーは押されていない");
	}

	key_a = Key.isDown(65);
};

上に戻る

すべてのキーが押されていないかを調べる

サンプルをダウンロード

key_05_fla05_as1.fla MacroMedia Flash 5

key_05_fla06_as1.fla Macromedia Flash MX ActionScript1.0

■すべてのキーが押されていない事を調べる

キーコード表で対応しているキーを、Key.isDown() メソッドを使って順番に調べていきます。

すべての結果が false だったときに押されていない事がわかります。

下の例は、キーボードが１つでも押されているかを調べる関数です。

false が返ってきたときは、どのキーも押されていない事がわかります。

例) 何かキーが押されたか調べる関数


// ------------------------------------------------------------
// 何らかのキーボードが押されているかを調べる関数
// ------------------------------------------------------------
function KeyPushCheck(){
	var i;
	
	for(i=7;i<126;i++){
		if(Key.isDown(i))	return true;
	}

	for(i=143;i<145;i++){
		if(Key.isDown(i))	return true;
	}
	
	for(i=185;i<223;i++){
		if(Key.isDown(i))	return true;
	}

	return false;
}

上に戻る

キーボードを押してムービークリップを動かす

サンプルをダウンロード

key_06_fla05_as1.fla MacroMedia Flash 5

key_06_fla06_as1.fla Macromedia Flash MX ActionScript1.0

■キーが押されたか調べて、ムービークリップの座標を変更する

キーボードが押されたか調べます。

押されていれば、以下のようにムービークリップを動かしてみます。

・	上キーが押されたら、ムービークリップを上に少し移動
・	下キーが押されたら、ムービークリップを下に少し移動
・	右キーが押されたら、ムービークリップを右に少し移動
・	左キーが押されたら、ムービークリップを左に少し移動

例)キーが押されたらムービークリップ "mc" を少し動かす


// 上キーが押された
if (Key.isDown(Key.UP)) {
	mc._y -= 10;	// 上に移動
}

// 下キーが押された
if (Key.isDown(Key.DOWN)) {
	mc._y += 10;	// 下に移動
}

// 左キーが押された
if (Key.isDown(Key.LEFT)) {
	mc._x -= 10;	// 左に移動
}

// 右キーが押された
if (Key.isDown(Key.RIGHT)) {
	mc._x += 10;	// 右に移動
}

■一連の処理を毎フレーム実行する

キーボードが押されていれば、ムービークリップを少しだけ動かす処理を、毎フレーム実行します。

これで、キーボードが押されている間は、ムービークリップが動き続けます。

毎フレーム処理をする為には、以下のイベント中に記述します。

「onClipEvent ハンドラの enterFrame イベント」

「MovieClip クラスの onEnterFrame イベントハンドラ」

例)キーが押されている間ムービークリップを動かす


// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {

	if (Key.isDown(Key.UP))	_y -= 10;	// 上に移動
	if (Key.isDown(Key.DOWN))	_y += 10;	// 下に移動
	if (Key.isDown(Key.LEFT))	_x -= 10;	// 左に移動
	if (Key.isDown(Key.RIGHT))	_x += 10;	// 右に移動

}

例)キーが押されている間ムービークリップ "mc" を動かす (Flash 6 以降)


// 毎フレーム実行されるイベント
mc.onEnterFrame = function (){

	if (Key.isDown(Key.UP))	this._y -= 10;	// 上に移動
	if (Key.isDown(Key.DOWN))	this._y += 10;	// 下に移動
	if (Key.isDown(Key.LEFT))	this._x -= 10;	// 左に移動
	if (Key.isDown(Key.RIGHT))	this._x += 10;	// 右に移動

};

加速や減速させながら移動する方法は、基本的な移動方法についてにまとめています。

上に戻る

キーボード操作の割り当てを変更する

サンプルをダウンロード

key_07_fla05_as1.fla MacroMedia Flash 5

key_07_fla06_as1.fla Macromedia Flash MX ActionScript1.0

■キーコンフィグ機能を追加する

「キーボードを押してムービークリップを動かす」のソースを修正して、キーコンフィグ機能を追加してみます。

例)キーが押されている間ムービークリップを動かす


// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {

	if (Key.isDown(Key.UP))	_y -= 10;	// 上に移動
	if (Key.isDown(Key.DOWN))	_y += 10;	// 下に移動
	if (Key.isDown(Key.LEFT))	_x -= 10;	// 左に移動
	if (Key.isDown(Key.RIGHT))	_x += 10;	// 右に移動

}

例)キーが押されている間ムービークリップ "mc" を動かす (Flash 6 以降)


// 毎フレーム実行されるイベント
mc.onEnterFrame = function (){

	if (Key.isDown(Key.UP))	this._y -= 10;	// 上に移動
	if (Key.isDown(Key.DOWN))	this._y += 10;	// 下に移動
	if (Key.isDown(Key.LEFT))	this._x -= 10;	// 左に移動
	if (Key.isDown(Key.RIGHT))	this._x += 10;	// 右に移動

};

１．キーコードの数値や定数を使って処理している部分を、すべて変数に置き換える

Key.isDown()メソッドの引数に、キーコードの定数を使用しています。

キーコードの数値や定数を使って処理している部分を、すべて変数に置き換えます。

上キー、下キー、左キー、右キー、と４つのキーを使用しているので、４つの変数に置き換えます。

キーコードの数値や定数を使って処理している部分を、変数に置き換える


// 初回に一度だけ実行されるイベント
onClipEvent (load) {
	key_code_up = Key.UP;
	key_code_down = Key.DOWN;
	key_code_left = Key.LEFT;
	key_code_right = Key.RIGHT;
}

// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {

	if (Key.isDown(key_code_up))		_y -= 10;	// 上に移動
	if (Key.isDown(key_code_down))	_y += 10;	// 下に移動
	if (Key.isDown(key_code_left))	_x -= 10;	// 左に移動
	if (Key.isDown(key_code_right))	_x += 10;	// 右に移動

}

キーコードの数値や定数を使って処理している部分を、変数に置き換える (Flash 6 以降)


// 初期化処理
var key_code_up = Key.UP;
var key_code_down = Key.DOWN;
var key_code_left = Key.LEFT;
var key_code_right = Key.RIGHT;

// 毎フレーム実行されるイベント
mc.onEnterFrame = function (){

	if (Key.isDown(key_code_up))		_y -= 10;	// 上に移動
	if (Key.isDown(key_code_down))	_y += 10;	// 下に移動
	if (Key.isDown(key_code_left))	_x -= 10;	// 左に移動
	if (Key.isDown(key_code_right))	_x += 10;	// 右に移動

};

２．キーコード用変数に好きなキーコードの数値や定数をセットする

キーコード用の変数に、好きなキーコードの数値や定数をセットします。

これで、キーボード操作の割り当てを変更することができます。

例えば W、S、A、D、キー、という操作に変更する例です。

キーコード用変数に、キーコードの数値をセットして、キーボード操作の割り当てを変更する


// 初回に一度だけ実行されるイベント
onClipEvent (load) {
	key_code_up = 87;
	key_code_down = 83;
	key_code_left = 65;
	key_code_right = 68;
}

// 毎フレーム実行されるイベント
onClipEvent (enterFrame) {

	if (Key.isDown(key_code_up))		_y -= 10;	// 上に移動
	if (Key.isDown(key_code_down))	_y += 10;	// 下に移動
	if (Key.isDown(key_code_left))	_x -= 10;	// 左に移動
	if (Key.isDown(key_code_right))	_x += 10;	// 右に移動

}

キーコード用変数に、キーコードの数値をセットして、キーボード操作の割り当てを変更する (Flash 6 以降)


// 初期化処理
var key_code_up = 87;
var key_code_down = 83;
var key_code_left = 65;
var key_code_right = 68;

// 毎フレーム実行されるイベント
mc.onEnterFrame = function (){

	if (Key.isDown(key_code_up))		_y -= 10;	// 上に移動
	if (Key.isDown(key_code_down))	_y += 10;	// 下に移動
	if (Key.isDown(key_code_left))	_x -= 10;	// 左に移動
	if (Key.isDown(key_code_right))	_x += 10;	// 右に移動

};

■ユーザーがキーボードを押す事で、キーボード操作の割り当てを変更する

まず、キーボードが押されたかを調べます。

キーボードが押されたか調べるには、onKeyDown イベントを使用します。

次に、最後に押されたキーのキーコードを調べます。

最後に押されたキーのキーコードを調べるには、Key.getCode() メソッドを使用します。

最後に押されたキーのキーコードを取得する


// 初回に一度だけ実行されるイベント
onClipEvent (load) {
	key_code = 0;
}

// キーボードを押したときに実行されるイベント
onClipEvent (keyDown) {
	key_code = Key.getCode();
}

最後に押されたキーのキーコードを取得する


// 初期化処理
var key_code = 0;

// キーボードを押したときに実行されるイベント
onKeyDown = function (){
	key_code = Key.getCode();
};

■キーコードの数値からキーの名称を取得する

配列を用意します。

キーコードの値と同じ番地に、「キーの名称」を文字列で格納しておきます。（255個ほどあります）

キーの名称情報が格納された配列


var KeyboardName = [
	"",
	"Mouse L", 
	"Mouse R", 
	"Cancel", 
	"Mouse M", 
	"", 
	"", 
	"", 
	"BackSpace", 
	"Tab",
	"", 
	"", 
	"Clear", 
	"Enter", 
	"", 
	"", 
	"Shift", 
	"Ctrl", 
	"Alt",
	"Pause", 
	"CapsLock",
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"Esc", 
	"", 
	"",
	"", 
	"", 
	"Space", 
	"PageUp", 
	"PageDown", 
	"End", 
	"Home", 
	"Left", 
	"Up", 
	"Right",
	"Down",
	"", 
	"",
	"", 
	"PrtSc", 
	"Insert", 
	"Delete", 
	"Help", 
	"0",
	"1",
	"2",
	"3",
	"4",
	"5",
	"6",
	"7",
	"8",
	"9",
	"",
	"",
	"",
	"",
	"",
	"",
	"",
	"A",
	"B",
	"C",
	"D",
	"E",
	"F",
	"G",
	"H",
	"I",
	"J",
	"K",
	"L",
	"M",
	"N",
	"O",
	"P",
	"Q",
	"R",
	"S",
	"T",
	"U",
	"V",
	"W",
	"X",
	"Y",
	"Z",
	"",
	"",
	"",
	"",
	"",
	"Ten 0", 
	"Ten 1", 
	"Ten 2",
	"Ten 3", 
	"Ten 4", 
	"Ten 5", 
	"Ten 6", 
	"Ten 7", 
	"Ten 8",
	"Ten 9",
	"*", "+", 
	"Enter", 
	"-", 
	".", 
	"/", 
	"F1",
	"F2", 
	"F3", 
	"F4", 
	"F5", 
	"F6", 
	"F7", 
	"F8", 
	"F9", 
	"F10", 
	"F11", 
	"F12", 
	"F13", 
	"F14", 
	"F15", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"NumLock", 
	"ScrLk", 
	"", 
	"", 
	"", 
	"", 
	"",
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	": *", 
	"; +", 
	", <", 
	"- =", 
	". >", 
	"/ ?", 
	"@ `", 
	"", 
	"", 
	"", 
	"",
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"[ {", 
	"\\|",
	"] }", 
	"^ ~", 
	"",
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	"", 
	""
];

調べたいキーコードがあれば、キーコードの値と同じ番地にアクセスします。

キーコード 65 の名称を調べる


var key_code = 65;

trace( KeyboardName[key_code] );

上に戻る

前のページに戻る