サウンドについて

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトを作成してストリーム読み込みを開始
var sound_obj : Sound = new Sound(url);

// サウンドファイルのURL
var url : URLRequest = new URLRequest("../sound/test.mp3");

// サウンドオブジェクトを作成してストリーム読み込みを開始
var sound_obj : Sound = new Sound(url);

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトの作成
var sound_obj : Sound = new Sound();

// ストリーム読み込みを開始
sound_obj.load(url);

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトを作成
var sound_obj : Sound = new Sound();

// サウンドのストリーム読み込みを開始
sound_obj.load(url);

try{
	// ストリーム読み込みを閉じる
	sound_obj.close();

}catch(e:Error){
	trace("エラー");
}

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトを作成
var sound_obj : Sound = new Sound(url);

// サウンドを再生
sound_obj.play(0,3);

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトを作成
var sound_obj : Sound = new Sound(url);

// サウンドトランスフォームオブジェクトを作成
var trans : SoundTransform = new SoundTransform();
trans.volume = 0.1;	// ボリューム
trans.pan = -1;		// パン

// サウンドを再生
sound_obj.play(0,0,trans);

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトを作成
var sound_obj : Sound = new Sound(url);

// サウンドを再生
var channel : SoundChannel = sound_obj.play(0,3);

// サウンドを停止
channel.stop();

var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");
var sound_obj : Sound = new Sound(url);


sound_obj.addEventListener (Event.OPEN,SoundOpenFunc);
function SoundOpenFunc (event : Event):void {
	trace ("ストリーム読み込みを開始した");
}

sound_obj.addEventListener (ProgressEvent.PROGRESS,SoundProgressFunc);
function SoundProgressFunc (event : ProgressEvent):void {
	trace ("読込:" + event.bytesLoaded);
	trace ("全体:" + event.bytesTotal);
	trace ("パーセント:" + Math.floor(event.bytesLoaded/event.bytesTotal*100));
}

sound_obj.addEventListener (Event.COMPLETE,SoundCompleteFunc);
function SoundCompleteFunc (event : Event):void {
	trace ("読み込みを完了");
}

sound_obj.addEventListener (IOErrorEvent.IO_ERROR,SoundIOErrorFunc);
function SoundIOErrorFunc (event : IOErrorEvent):void {
	trace ("ファイル入出力のエラー");
}

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトを作成
var sound_obj : Sound = new Sound();

// サウンドローダーコンテキストを作成
var sound_loader_context : SoundLoaderContext = new SoundLoaderContext(5000);

// サウンドのストリーム読み込みを開始
sound_obj.load(url,sound_loader_context);

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトを作成
var sound_obj : Sound = new Sound();

// サウンドローダーコンテキストを作成
var sound_loader_context : SoundLoaderContext = new SoundLoaderContext(1000,true);

// サウンドのストリーム読み込みを開始
sound_obj.load(url,sound_loader_context);

// リンケージプロパティで設定したサウンドクラスを使ってサウンドオブジェクトを作成
var sound_obj : Sound = new MySound( );

// リンケージプロパティで設定したサウンドクラスを使ってサウンドオブジェクトを作成
var sound_obj : Sound = new MySound();

// サウンドを再生
sound_obj.play(0,3);

// リンケージプロパティで設定したサウンドクラスを使ってサウンドオブジェクトを作成
var sound_obj : Sound = new MySound();

// サウンドトランスフォームオブジェクトを作成
var trans : SoundTransform = new SoundTransform();
trans.volume = 0.1;	// ボリューム
trans.pan = -1;		// パン

// サウンドを再生
sound_obj.play(0,0,trans);

// リンケージプロパティで設定したサウンドクラスを使ってサウンドオブジェクトを作成
var sound_obj : Sound = new MySound();

// サウンドを再生
var channel : SoundChannel = sound_obj.play(0,3);

// サウンドを停止
channel.stop();

SoundMixer.bufferTime = 0.5;

// サウンドトランスフォームオブジェクトを作成
var trans : SoundTransform = new SoundTransform();
trans.volume = 0.1;	// ボリューム
trans.pan = -1;		// パン

// サウンドトランスフォームオブジェクトをセットして反映
SoundMixer.soundTransform = trans;

// サウンドトランスフォームオブジェクトを取得
var trans : SoundTransform = SoundMixer.soundTransform;

trace(trans.volume);	// ボリューム
trace(trans.pan);	// パン

// サウンドトランスフォームオブジェクトを作成する
var trans : SoundTransform = new SoundTransform();

trans.volume = 0.1;	// ボリューム
trans.pan = -1;		// パン

// サウンドトランスフォームオブジェクトを取得する
var trans : SoundTransform = mc.soundTransform;

trace(trans.volume);	// ボリューム
trace(trans.pan);	// パン

// サウンドトランスフォームオブジェクトを取得する
var trans : SoundTransform = mc.soundTransform;
trans.volume = 0.1;	// ボリューム
trans.pan = -1;		// パン

// サウンドオブジェクトをセットして反映
mc.soundTransform = trans;

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトの作成
var sound_obj : Sound = new Sound(url);

// サウンドの再生
var channel : SoundChannel = sound_obj.play();

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトの作成
var sound_obj : Sound = new Sound(url);

// サウンドの再生
var channel : SoundChannel = sound_obj.play();

// サウンドトランスフォームオブジェクトの取得
var trans : SoundTransform = channel.soundTransform;
trans.volume = 0.1;	// ボリューム
trans.pan = -1;		// パン

// サウンドトランスフォームオブジェクトをセットして反映
channel.soundTransform = trans;

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトの作成
var sound_obj : Sound = new Sound(url);

// サウンドの再生
var channel : SoundChannel = sound_obj.play();

// サウンドの再生が終了したときに呼び出されるイベント
channel.addEventListener(Event.SOUND_COMPLETE,SoundCompFunc);
function SoundCompFunc(event:Event):void{
	trace("最後まで再生された");
}

// サウンドファイルのURL
var url : URLRequest = new URLRequest("http://hakuhin.jp/test.mp3");

// サウンドオブジェクトの作成
var sound_obj : Sound = new Sound(url);

// サウンドの再生
var channel : SoundChannel = sound_obj.play();

// 毎フレーム呼び出されるイベント
stage.addEventListener(Event.ENTER_FRAME,EnterFrameFunc);
function EnterFrameFunc(event:Event){

	trace("再生位置 : " + channel.position / 1000);

}

// サウンドミキサーからサウンドトランスフォームオブジェクトを取得
var trans : SoundTransform = SoundMixer.soundTransform;

// サウンドファイルのURL
var url = new URLRequest("test.mp3");

// サウンドオブジェクトの作成
var sound_obj : Sound = new Sound(url);

// サウンドの再生
var channel : SoundChannel = sound_obj.play();

// サウンドチャンネルからサウンドトランスフォームオブジェクトを取得
var trans : SoundTransform = channel.soundTransform;

// スプライトオブジェクトを作成
var sprite : Sprite = new Sprite();

// スプライトからサウンドトランスフォームオブジェクトを取得
var trans : SoundTransform = sprite.soundTransform;

// Microphone オブジェクトを取得
var mic_obj:Microphone = Microphone.getMicrophone();

// Microphone オブジェクトからサウンドトランスフォームオブジェクトを取得
var trans : SoundTransform = mic_obj.soundTransform;

// サウンドミキサーからサウンドトランスフォームオブジェクトを取得
var trans : SoundTransform = SoundMixer.soundTransform;

// ボリュームを設定
trans.volume = 0.5;

// サウンドトランスフォームオブジェクトをサウンドミキサーにセット
SoundMixer.soundTransform = trans;

// サウンドミキサーからサウンドトランスフォームオブジェクトを取得
var trans : SoundTransform = SoundMixer.soundTransform;

// パンを設定
trans.pan = 1;

// サウンドトランスフォームオブジェクトをサウンドミキサーにセット
SoundMixer.soundTransform = trans;

// サウンドミキサーからサウンドトランスフォームオブジェクトを取得
var trans : SoundTransform = SoundMixer.soundTransform;

// 詳細な出力を設定
trans.leftToLeft   = 0.5;	// 元は左から出力されていた音を左から出力
trans.leftToRight  = 0.5;	// 元は左から出力されていた音を右から出力
trans.rightToLeft  = 0.5;	// 元は右から出力されていた音を左から出力
trans.rightToRight = 0.5;	// 元は右から出力されていた音を右から出力

// サウンドトランスフォームオブジェクトをサウンドミキサーにセット
SoundMixer.soundTransform = trans;

// サウンドミキサーからサウンドトランスフォームオブジェクトを取得
var trans : SoundTransform = SoundMixer.soundTransform;

// 詳細な出力を設定
trans.leftToLeft   = 0.0;	// 元は左から出力されていた音を左から出力
trans.leftToRight  = 1.0;	// 元は左から出力されていた音を右から出力
trans.rightToLeft  = 1.0;	// 元は右から出力されていた音を左から出力
trans.rightToRight = 0.0;	// 元は右から出力されていた音を右から出力

// サウンドトランスフォームオブジェクトをサウンドミキサーにセット
SoundMixer.soundTransform = trans;

// サウンドオブジェクト作成
var sound_obj:Sound = new Sound();

var url : URLRequest = new URLRequest("../sound/test.png");
loader_obj.load(url);

// ID3Info オブジェクトを取得
var id3info:ID3Info = sound_obj.id3;

// サウンドオブジェクトを作成
var sound_obj : Sound = new Sound();

// // ストリーム読み込みを開始
var url : URLRequest = new URLRequest("../sound/test.mo3");
sound_obj.load(url);

// ID3タグの情報が含まれていれば呼び出されるイベント
sound_obj.addEventListener(Event.ID3,function (e:Event):void {

	// ID3Info オブジェクトを取得
	var id3info:ID3Info = sound_obj.id3;

	trace("アルバム名:" + id3info.album);
	trace("アーティスト名:" + id3info.artist);
	trace("コメント:" + id3info.comment);
	trace("曲のジャンル:" + id3info.genre);
	trace("曲名:" + id3info.songName);
	trace("トラック番号:" + id3info.track);
	trace("録音された年:" + id3info.year);

});

// サウンドオブジェクトを作成
var sound_obj : Sound = new Sound();

// // ストリーム読み込みを開始
var url : URLRequest = new URLRequest("../sound/test.mo3");
sound_obj.load(url);

// ID3タグの情報が含まれていれば呼び出されるイベント
sound_obj.addEventListener(Event.ID3,function (e:Event):void {

	// ID3Info オブジェクトを取得
	var id3info:ID3Info = sound_obj.id3;

});

var url : URLRequest = new URLRequest("test.mp3");
var sound_obj : Sound = new Sound(url);	// サウンドオブジェクト

// 読み込みが終了した
sound_obj.addEventListener (Event.COMPLETE,SoundCompleteFunc);
function SoundCompleteFunc (event : Event) {

	var buffer:ByteArray = new ByteArray();

	// サウンドデータを取得
	var sampling = sound_obj.extract(buffer,8192);
}

// パラメータ
var sampling = 2048;		// １度に転送するサンプリング数

// ソース用サウンドオブジェクト作成
var url : URLRequest = new URLRequest("test.mp3");
var src_obj : Sound = new Sound(url);

// 出力用サウンドオブジェクト
var out_obj = null;
var channel = null;

// ソース用サウンドオブジェクトの読み込みが完了
src_obj.addEventListener (Event.COMPLETE,SoundCompleteFunc);
function SoundCompleteFunc (event : Event) {

	// 出力用サウンドオブジェクト作成
	out_obj = new Sound();

	// 新しいオーディオデータ要求時に呼び出されるイベント
	out_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, SampleDataFunc);

	// 再生開始
	channel = out_obj.play();
}


// サウンドデータ要求時に呼び出されるイベント
function SampleDataFunc(event:SampleDataEvent):void{

	var i;

	// ソース用と出力用のバッファ
	var src_buffer:ByteArray = new ByteArray();
	var out_buffer:ByteArray = event.data;
	
	// サウンドデータを取得
	var get_sampling = src_obj.extract(src_buffer,sampling);

	// サウンドバッファが足りない場合は空白を埋める
	for(i=get_sampling;i < sampling;i++){
		src_buffer.writeFloat(0.0);
		src_buffer.writeFloat(0.0);
	}


	// サウンドデータを出力バッファにコピー
	var data;
	src_buffer.position = 0;
	for(i=0;i < sampling;i++){
		// 左チャンネル
		data = src_buffer.readFloat();
		out_buffer.writeFloat(data);
	
		// 右チャンネル
		data = src_buffer.readFloat();
		out_buffer.writeFloat(data);
	}

}

// パラメータ
var frequency = 25;	// 周波数
var sampling = 2048;	// 1 度に転送するサンプリング数

// 周波数を徐々に上げるテスト
addEventListener(Event.ENTER_FRAME,function (e){
	frequency += 10;
	if(frequency > 2000)	frequency = 25;
});


// 波形用ワーク
var wave = {
	count : 0,	// カウント
	cycle : 0	// 周期
};

// サウンドオブジェクト
var sound_obj = new Sound();

// サンプルデータイベント登録
sound_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, SampleDataFunc);

// 再生開始
sound_obj.play();

// サウンドデータ要求時に呼び出されるイベント
function SampleDataFunc(event:SampleDataEvent):void{
	
	var i;

	// サウンドバッファ
	var buffer = event.data;

	// 開始直後のノイズ対策
	if(event.position == 0){
		for(i=0;i < 4096;i++){
			// 左チャンネル
			buffer.writeFloat(0.0);
			// 右チャンネル
			buffer.writeFloat(0.0);
		}
		return;
	}

	for(i=0;i < sampling;i++){
		wave.count --;
		if(wave.count < 0){
			// 周期更新
			wave.cycle = wave.count = 44100 / frequency;
		}

		// 位相(0.0～1.0)
		var d = 1.0 - wave.count / wave.cycle;
		
		// 矩形波
		if(d < 0.5)	d = -1.0;
		else		d =  1.0;

		// 左チャンネル
		buffer.writeFloat(d);
		// 右チャンネル
		buffer.writeFloat(d);
	}
}

// パラメータ
var frequency = 25;	// 周波数
var sampling = 2048;	// 1 度に転送するサンプリング数

// 周波数を徐々に上げるテスト
addEventListener(Event.ENTER_FRAME,function (e){
	frequency += 10;
	if(frequency > 2000)	frequency = 25;
});


// 波形用ワーク
var wave = {
	count : 0,	// カウント
	cycle : 0	// 周期
};

// サウンドオブジェクト
var sound_obj = new Sound();

// サンプルデータイベント登録
sound_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, SampleDataFunc);

// 再生開始
sound_obj.play();

// サウンドデータ要求時に呼び出されるイベント
function SampleDataFunc(event:SampleDataEvent):void{
	
	var i;

	// サウンドバッファ
	var buffer = event.data;

	// 開始直後のノイズ対策
	if(event.position == 0){
		for(i=0;i < 4096;i++){
			// 左チャンネル
			buffer.writeFloat(0.0);
			// 右チャンネル
			buffer.writeFloat(0.0);
		}
		return;
	}

	for(i=0;i < sampling;i++){
		wave.count --;
		if(wave.count < 0){
			// 周期更新
			wave.cycle = wave.count = 44100 / frequency;
		}

		// 位相(0.0～1.0)
		var d = 1.0 - wave.count / wave.cycle;
		
		// ノコギリ波
		d = d * 2 - 1;

		// 左チャンネル
		buffer.writeFloat(d);
		// 右チャンネル
		buffer.writeFloat(d);
	}
}

// パラメータ
var frequency = 25;	// 周波数
var sampling = 2048;	// 1 度に転送するサンプリング数

// 周波数を徐々に上げるテスト
addEventListener(Event.ENTER_FRAME,function (e){
	frequency += 10;
	if(frequency > 2000)	frequency = 25;
});


// 波形用ワーク
var wave = {
	count : 0,	// カウント
	cycle : 0	// 周期
};

// サウンドオブジェクト
var sound_obj = new Sound();

// サンプルデータイベント登録
sound_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, SampleDataFunc);

// 再生開始
sound_obj.play();

// サウンドデータ要求時に呼び出されるイベント
function SampleDataFunc(event:SampleDataEvent):void{
	
	var i;

	// サウンドバッファ
	var buffer = event.data;

	// 開始直後のノイズ対策
	if(event.position == 0){
		for(i=0;i < 4096;i++){
			// 左チャンネル
			buffer.writeFloat(0.0);
			// 右チャンネル
			buffer.writeFloat(0.0);
		}
		return;
	}

	for(i=0;i < sampling;i++){
		wave.count --;
		if(wave.count < 0){
			// 周期更新
			wave.cycle = wave.count = 44100 / frequency;
		}

		// 位相(0.0～1.0)
		var d = 1.0 - wave.count / wave.cycle;
		
		// 三角波
		if(d < 0.25)	d = d / 0.25;
		else if(d < 0.75)	d = (0.75 - d) * 4 - 1;
		else		d = (d - 0.75) / 0.25 - 1;

		// 左チャンネル
		buffer.writeFloat(d);
		// 右チャンネル
		buffer.writeFloat(d);
	}
}

// パラメータ
var frequency = 25;	// 周波数
var sampling = 2048;	// 1 度に転送するサンプリング数

// 周波数を徐々に上げるテスト
addEventListener(Event.ENTER_FRAME,function (e){
	frequency += 10;
	if(frequency > 2000)	frequency = 25;
});


// 波形用ワーク
var wave = {
	count : 0,	// カウント
	cycle : 0	// 周期
};

// サウンドオブジェクト
var sound_obj = new Sound();

// サンプルデータイベント登録
sound_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, SampleDataFunc);

// 再生開始
sound_obj.play();

// サウンドデータ要求時に呼び出されるイベント
function SampleDataFunc(event:SampleDataEvent):void{
	
	var i;

	// サウンドバッファ
	var buffer = event.data;

	// 開始直後のノイズ対策
	if(event.position == 0){
		for(i=0;i < 4096;i++){
			// 左チャンネル
			buffer.writeFloat(0.0);
			// 右チャンネル
			buffer.writeFloat(0.0);
		}
		return;
	}

	for(i=0;i < sampling;i++){
		wave.count --;
		if(wave.count < 0){
			// 周期更新
			wave.cycle = wave.count = 44100 / frequency;
		}

		// 位相(0.0～1.0)
		var d = 1.0 - wave.count / wave.cycle;
		
		// 正弦波
		d = Math.sin(d * 2 * Math.PI);

		// 左チャンネル
		buffer.writeFloat(d);
		// 右チャンネル
		buffer.writeFloat(d);
	}
}

// パラメータ
var sampling = 2048;	// 1 度に転送するサンプリング数

// サウンドオブジェクト
var sound_obj = new Sound();

// サンプルデータイベント登録
sound_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, SampleDataFunc);

// 再生開始
sound_obj.play();

// サウンドデータ要求時に呼び出されるイベント
function SampleDataFunc(event:SampleDataEvent):void{
	
	var i;

	// サウンドバッファ
	var buffer = event.data;

	// 開始直後のノイズ対策
	if(event.position == 0){
		for(i=0;i < 4096;i++){
			// 左チャンネル
			buffer.writeFloat(0.0);
			// 右チャンネル
			buffer.writeFloat(0.0);
		}
		return;
	}

	for(i=0;i < sampling;i++){
		// ランダム
		var d = Math.random() * 2 - 1;

		// 左チャンネル
		buffer.writeFloat(d);
		// 右チャンネル
		buffer.writeFloat(d);
	}
}

// パラメータ
var sampling = 2048;		// １度に転送するサンプリング数
var sound_speed = 1.5;	// 再生速度(1.0で等速)
var loop = true;		// ループあり
var loop_begin = 0;		// ループ開始地点

// ソース用サウンドオブジェクト作成
var url : URLRequest = new URLRequest("test.mp3");
var src_obj : Sound = new Sound(url);

// 出力用サウンドオブジェクト
var out_obj = null;
var channel = null;

// ソース用サウンドオブジェクトの読み込みが完了
src_obj.addEventListener (Event.COMPLETE,SoundCompleteFunc);
function SoundCompleteFunc (event : Event) {

	// 出力用サウンドオブジェクト作成
	out_obj = new Sound();

	// 新しいオーディオデータ要求時に呼び出されるイベント
	out_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, SampleDataFunc);

	// 再生開始
	channel = out_obj.play();
}


// 波形用ワーク
var wave = {
	pos : 0	// 再生位置
};


// サウンドデータ要求時に呼び出されるイベント
function SampleDataFunc(event:SampleDataEvent):void{

	var i;
	
	// サウンドバッファの開始位置
	var pos = wave.pos - Math.floor(wave.pos);
	
	// ソース用と出力用のバッファ
	var src_buffer:ByteArray = new ByteArray();
	var out_buffer:ByteArray = event.data;
	
	// 開始直後のノイズ対策
	if(event.position == 0){
		for(i=0;i < 4096;i++){
			// 左チャンネル
			out_buffer.writeFloat(0.0);
			// 右チャンネル
			out_buffer.writeFloat(0.0);
		}
		return;
	}
	
	// ソースから取得するサンプリング数
	var copy_sampling = Math.ceil(sampling * sound_speed);
	if(!copy_sampling)	copy_sampling = 1;
	
	// サウンドデータを取得
	var get_sampling = src_obj.extract(src_buffer,copy_sampling,wave.pos);

	// サウンドバッファが埋まるまでループを繰り返す
	while(true){
		wave.pos += get_sampling;
		copy_sampling -= get_sampling;
		if(copy_sampling <= 0)	break;

		if(!loop){
			// ループしないなら空白で埋める
			for(i=0;i < copy_sampling;i++){
				src_buffer.writeFloat(0);
				src_buffer.writeFloat(0);
			}
			break;
		}

		// ループ開始位置をセット
		wave.pos = loop_begin;

		// サウンドデータを再取得
		get_sampling = src_obj.extract(src_buffer,copy_sampling,wave.pos);
		
		// エラー
		if(!get_sampling)	return;
	}

	// 再生速度に合わせてサウンドデータをコピー
	var data;
	for(i=0;i < sampling;i++){
		src_buffer.position = Math.floor(pos) * 4 * 2;
		pos += sound_speed;
	
		// 左チャンネル
		data = src_buffer.readFloat();
		out_buffer.writeFloat(data);
	
		// 右チャンネル
		data = src_buffer.readFloat();
		out_buffer.writeFloat(data);
	}

}

// パラメータ
var sampling = 2048;		// １度に転送するサンプリング数
var loop = true;		// ループあり
var loop_begin = 0;		// ループ開始地点
var delay_sampling = 1000;	// ディレイの時間（サンプリング数）
var delay_decrease_buf = 0.85;	// ディレイの減衰率 (ディレイバッファに乗算)
var delay_decrease_src = 0.5;	// ディレイの減衰率（再生ソースに乗算）


// ソース用サウンドオブジェクト作成
var url : URLRequest = new URLRequest("test.mp3");
var src_obj : Sound = new Sound(url);

// 出力用サウンドオブジェクト
var out_obj = null;
var channel = null;

// ソース用サウンドオブジェクトの読み込みが完了
src_obj.addEventListener (Event.COMPLETE,SoundCompleteFunc);
function SoundCompleteFunc (event : Event) {

	// 出力用サウンドオブジェクト作成
	out_obj = new Sound();

	// 新しいオーディオデータ要求時に呼び出されるイベント
	out_obj.addEventListener(SampleDataEvent.SAMPLE_DATA, SampleDataFunc);

	// 再生開始
	channel = out_obj.play();
}


// 波形用ワーク
var wave = {
	pos : 0	// 再生位置
};

// ディレイ用ワーク
var delay = {
	pos : 0,			// バッファ位置
	buffer : new ByteArray()	// ディレイ用バッファ
};
var i;
for(i=0;i < delay_sampling;i++){
	delay.buffer.writeFloat(0.0);
	delay.buffer.writeFloat(0.0);

}


// サウンドデータ要求時に呼び出されるイベント
function SampleDataFunc(event:SampleDataEvent):void{

	var i;

	// ソース用と出力用のバッファ
	var src_buffer:ByteArray = new ByteArray();
	var out_buffer:ByteArray = event.data;
	
	// 開始直後のノイズ対策
	if(event.position == 0){
		for(i=0;i < 4096;i++){
			// 左チャンネル
			out_buffer.writeFloat(0.0);
			// 右チャンネル
			out_buffer.writeFloat(0.0);
		}
		return;
	}
	
	// ソースから取得するサンプリング数
	var copy_sampling = sampling;
	
	// サウンドデータを取得
	var get_sampling = src_obj.extract(src_buffer,copy_sampling,wave.pos);

	// サウンドバッファが埋まるまでループを繰り返す
	while(true){
		wave.pos += get_sampling;
		copy_sampling -= get_sampling;
		if(copy_sampling <= 0)	break;

		if(!loop){
			// ループしないなら空白で埋める
			for(i=0;i < copy_sampling;i++){
				src_buffer.writeFloat(0);
				src_buffer.writeFloat(0);
			}
			break;
		}

		// ループ開始位置をセット
		wave.pos = loop_begin;

		// サウンドデータを再取得
		get_sampling = src_obj.extract(src_buffer,copy_sampling,wave.pos);
		
		// エラー
		if(!get_sampling)	return;
	}

	// 再生速度に合わせてサウンドデータをコピー
	var data;
	src_buffer.position = 0;
	for(i=0;i < sampling;i++){

		// ディレイバッファからソースを取得
		delay.buffer.position = delay.pos * 4 * 2;
		var src_l = delay.buffer.readFloat();
		var src_r = delay.buffer.readFloat();

		// 左チャンネル
		data = src_buffer.readFloat();
		data = src_l * delay_decrease_buf + data * delay_decrease_src;	// ディレイソースと再生ソースをブレンド
		out_buffer.writeFloat(data);
		var out_l = data;

		// 右チャンネル
		data = src_buffer.readFloat();
		data = src_r * delay_decrease_buf + data * delay_decrease_src;	// ディレイソースと再生ソースをブレンド
		out_buffer.writeFloat(data);
		var out_r = data;
		
		// 再生したサウンドデータをディレイバッファに格納
		var pos = delay.pos - 1;
		if(pos < 0)	pos += delay_sampling;
		delay.buffer.position = pos * 4 * 2;
		delay.buffer.writeFloat(out_l);
		delay.buffer.writeFloat(out_r);

		// ディレイバッファを進める
		delay.pos ++;
		if(delay_sampling <= delay.pos)	delay.pos = 0;
	}

}