Vector クラスについて(Flash 10以降)

Vector.< 型名 >

// Vector オブジェクトを作成する（Boolean 型）
var vector : Vector.<Boolean> = new Vector.<Boolean>();

vector[0] = true;
vector[1] = false;
vector[2] = true;

// Vector オブジェクトを作成する（String 型）
var vector : Vector.<String> = new Vector.<String>();

vector[0] = "abc";
vector[1] = "def";
vector[2] = "ghi";

import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.display.MovieClip;

// Vector オブジェクトを作成する（DisplayObject 型）
var vector : Vector.<DisplayObject> = new Vector.<DisplayObject>();

vector[0] = new Sprite();
vector[1] = new MovieClip();

import flash.geom.Vector3D;

// Vector オブジェクトを作成する（Vector3D 型）(初期サイズは 1024) (サイズは固定)
var vector : Vector.<Vector3D> = new Vector.<Vector3D>(1024 , true);

// 初期データを格納しつつ Vector オブジェクトを作成する（Number 型）
var vector : Vector.<Number> = Vector.<Number>([0,123,456]);

// 初期データを格納しつつ Vector オブジェクトを作成する（Number 型）
var vector : Vector.<Number> = new <Number>[0,123,456];

// Vector オブジェクトを作成する（String 型）
var vector:Vector.<String> = Vector.<String>(["A","B","C","D","E","F"]);

// 0 から順番に、すべての番地のデータにアクセスする
var i:uint;
var num:uint = vector.length;
for(i=0;i < num;i++){
	trace("---");
	trace("index:" + i);
	trace("data:" + vector[i]);
}

// Vector オブジェクトを作成する（String 型）
var vector:Vector.<String> = Vector.<String>(["A","B","C","D","E","F"]);

// for..in 文を使用して、すべての番地のデータにアクセスする
var key:String;
for (key in vector){
	trace("---");
	trace("index:" + key);
	trace("data:" + vector[key]);
}

// Vector オブジェクトを作成する（String 型）
var vector:Vector.<String> = Vector.<String>(["A","B","C","D","E","F"]);

// for each..in 文を使用して、すべての番地のデータにアクセスする
var data:String;
for each (data in vector){
	trace("data:" + data);
}

// Vector オブジェクトを作成する（Number 型）
var vector:Vector.<Number> = Vector.<Number>([0,1,2,3,4]);

// 配列のサイズを取得
var num:uint = vector.length;

// 出力テスト
trace(num);

// Vector オブジェクトを作成する（Number 型）（初期サイズは 10）
var vector:Vector.<Number> = new Vector.<Number>(10);

// 配列のサイズを固定する
vector.fixed = true;


try{
	// サイズを超える番地にアクセスを試みる
	vector[10] = 9;
}catch(e:Error){
	// エラーを出力
	trace(e);
}

try{
	// 配列の最後尾にデータの追加を試みる
	vector.push(0);
}catch(e:Error){
	// エラーを出力
	trace(e);
}

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C"]);
var b:Vector.<String> = Vector.<String>(["D","E","F"]);

// ２つの配列を連結して新しい配列を取得する
var c:Vector.<String> = a.concat(b);

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B"]);
var b:Vector.<String> = Vector.<String>(["C","D"]);
var c:Vector.<String> = Vector.<String>(["E","F","G"]);
var d:Vector.<String> = Vector.<String>(["H"]);

// 複数の配列を連結して新しい配列を取得する
var e:Vector.<String> = a.concat(b,c,d);

// ２つずつ結合する場合
//var e:Vector.<String>;
//e = a.concat(b);
//e = e.concat(c);
//e = e.concat(d);

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C"]);

// 配列の先頭にデータを追加して、新しいサイズを取得する
var num:uint = a.unshift("D");

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C"]);

// 配列の先頭に複数のデータを追加して、新しいサイズを取得する
var num:uint = a.unshift("D" ,"E" ,"F");

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C"]);

// 配列の最後尾にデータを追加して、新しいサイズを取得する
var num:uint = a.push("D");

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C"]);

// 配列の最後尾に複数のデータを追加して、新しいサイズを取得する
var num:uint = a.push("D" ,"E" ,"F");

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E"]);

// 配列の最先頭を削除して、格納されていたデータを取得する
var b:String = a.shift();

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D"]);

// 配列の最後尾を削除して、格納されていたデータを取得する
var b:String = a.pop();

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C"]);

// 配列を複製する
var b:Vector.<String> = a.slice();

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E","F"]);

// 開始位置と終了位置を指定して、新しい配列を取得する
var b:Vector.<String> = a.slice(1, 5);

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E","F"]);

// 開始位置と個数を指定して配列を削除し、削除した範囲は新しい配列として取得する
var b:Vector.<String> = a.splice(3,2);

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E","F"]);

// 開始位置を指定し、データを追加する（第02引数に 0 を指定）
var b:Vector.<String> = a.splice(1,0,"G");

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E","F"]);

// 指定した位置から、配列の削除と追加を行う
var b:Vector.<String> = a.splice(1,4,"G","H","I");

// Vector オブジェクトを作成する（Number 型）
var a:Vector.<Number> = Vector.<Number>([2,4,1,3,0]);

// 配列をソートする（数値として比較）
a.sort(Array.NUMERIC);

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["C","B","A","a","c","b"]);

// 配列をソートする（文字列として比較）（大文字と小文字を区別する）
a.sort(0);

// Vector オブジェクトを作成する（Number 型）
var a:Vector.<Number> = Vector.<Number>([2,4,1,3,0]);

// 配列をソートする（数値として比較）(降順)
a.sort(Array.NUMERIC | Array.DESCENDING);

// ------------------------------------------------------------
// ソート用コールバック関数（数値として比較）
// ------------------------------------------------------------
function VectorSortNumeric(prev:Number,next:Number):Number{
	return (prev - next);
}


// ------------------------------------------------------------
// 配列をソートする
// ------------------------------------------------------------
// Vector オブジェクトを作成する（Number 型）
var a:Vector.<Number> = Vector.<Number>([2,4,1,3,0]);

// 配列をソートする（数値として比較）
a.sort(VectorSortNumeric);

// ------------------------------------------------------------
// ソート用コールバック関数（文字列として比較）
// ------------------------------------------------------------
function VectorSortString(prev:String,next:String):Number{
	var i:uint = 0;
	while(true){
		var p:Number = prev.charCodeAt(i) || 0;
		var n:Number = next.charCodeAt(i) || 0;
		var s:Number = p - n;
		if(s) return s;
		if(!p) break;
		i++;
	}
	return 0;
}


// ------------------------------------------------------------
// 配列をソートする
// ------------------------------------------------------------
// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["C","E","B","D","A"]);

// 配列をソートする（文字列として比較）
a.sort(VectorSortString);

// ------------------------------------------------------------
// ソート用コールバック関数（連番付き文字列として比較）
// ------------------------------------------------------------
function VectorSortSerialNumberString(prev:String,next:String):Number{
	var re:RegExp = new RegExp("^(.*?)([0-9]+)$","i");
	var p:Array = prev.match(re);
	var n:Array = next.match(re);
	if(p && n && (p[1] === n[1])){
		return parseInt(p[2]) - parseInt(n[2]);
	}
	return prev.localeCompare(next);
}


// ------------------------------------------------------------
// 配列をソートする
// ------------------------------------------------------------
// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["Ba","A64","B10","B2","A123","A0","A"]);

// 配列をソートする（連番付き文字列として比較）
a.sort(VectorSortSerialNumberString);

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E"]);

// 配列を反転する
a.reverse();

// Vector オブジェクトを作成する（Number 型）
var a:Vector.<Number> = Vector.<Number>([0,1,2,3,4]);

// 各データの間に任意の文字列を挟み、すべて繋げたストリングを取得する
var str:String = a.join("-");

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E"]);

// 各データの間にカンマを挟み、すべて繋げたストリングを取得する
var str:String = a.toString();

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E","A","B","C"]);

// 配列の前から後へデータを検索し、一致した位置を取得する
var pos:int = a.indexOf("B",0);

// 検索結果
if(pos >= 0){
	trace("検索結果:" + pos);
}else{
	trace("見つからない");
}

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E","A","B","C"]);

// 配列の後から前へデータを検索し、一致した位置を取得する
var pos:int = a.lastIndexOf("B",-1);

// 検索結果
if(pos >= 0){
	trace("検索結果:" + pos);
}else{
	trace("見つからない");
}

// ------------------------------------------------------------
// コールバック関数
// ------------------------------------------------------------
function VectorForEachFunc(item:String,index:int,vector:Vector.<String>):void{
	trace("---");
	trace("index:" + index);
	trace("data:" + item);
	trace("this:" + this);
}


// ------------------------------------------------------------
// データを順番に調べる
// ------------------------------------------------------------
// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E"]);

// データを順番に調べる
a.forEach(VectorForEachFunc);

// Vector オブジェクトを作成する（Number 型）
var a:Vector.<Number> = Vector.<Number>([111,222,333,444,555]);

// データを順番に調べる
a.forEach(function (item:Number,index:int,vector:Vector.<Number>):void{

	trace("---");
	trace("index:" + index);
	trace("data:" + item);
	trace("this:" + this);

},stage);

// ------------------------------------------------------------
// コールバック関数
// ------------------------------------------------------------
function VectorEveryFunc(item:String,index:int,vector:Vector.<String>):Boolean{

	trace("---");
	trace("index:" + index);
	trace("data:" + item);
	trace("this:" + this);

	// 何らかのチェック
	if(false){
		// 検証処理を終了する
		return false;
	}

	// 検証処理を継続する
	return true;
}


// ------------------------------------------------------------
// データの検証テストを行う
// ------------------------------------------------------------
// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E"]);

// データの検証テストを行う
var result:Boolean = a.every(VectorEveryFunc);

// Vector オブジェクトを作成する（Number 型）
var a:Vector.<Number> = Vector.<Number>([0,1,2,-3,4]);

// データの検証テストを行う
var result:Boolean = a.every(function (item:Number,index:int,vector:Vector.<Number>):Boolean{

	// マイナスのデータが見つかった
	if(item < 0){

		// 検証処理を終了する
		return false;
	}

	// 検証処理を継続する
	return true;
});

// 結果を出力
trace("配列内のデータは、すべてプラス値である:" + result);

// ------------------------------------------------------------
// コールバック関数
// ------------------------------------------------------------
function VectorSomeFunc(item:String,index:int,vector:Vector.<String>):Boolean{

	trace("---");
	trace("index:" + index);
	trace("data:" + item);
	trace("this:" + this);

	// 何らかのチェック
	if(false){
		// 検証処理を終了する
		return true;
	}

	// 検証処理を継続する
	return false;
}


// ------------------------------------------------------------
// データの検証テストを行う
// ------------------------------------------------------------
// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E"]);

// データの検証テストを行う
var result:Boolean = a.some(VectorSomeFunc);

// Vector オブジェクトを作成する（Number 型）
var a:Vector.<Number> = Vector.<Number>([0,1,2,-3,4]);

// データの検証テストを行う
var result:Boolean = a.some(function (item:Number,index:int,vector:Vector.<Number>):Boolean{

	// マイナスのデータが見つかった
	if(item < 0){

		// 検証処理を終了する
		return true;
	}

	// 検証処理を継続する
	return false;
});

// 結果を出力
trace("配列内のデータに、マイナス値が１つでも含まれる:" + result);

// ------------------------------------------------------------
// コールバック関数
// ------------------------------------------------------------
function VectorFilterFunc(item:String,index:int,vector:Vector.<String>):Boolean{

	trace("---");
	trace("index:" + index);
	trace("data:" + item);
	trace("this:" + this);

	// 何らかのチェック
	if(true){
		// データを抽出対象に含める
		return true;
	}

	// データを抽出対象に含めない
	return false;
}


// ------------------------------------------------------------
// データを抽出する
// ------------------------------------------------------------
// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E"]);

// データを抽出し、新しい配列を取得する
var b:Vector.<String> = a.filter(VectorFilterFunc);

// Vector オブジェクトを作成する（Number 型）
var a:Vector.<Number> = Vector.<Number>([0,-1,2,-3,4]);

// データを抽出し、新しい配列を取得する
var b:Vector.<Number> = a.filter(function (item:Number,index:int,vector:Vector.<Number>):Boolean{

	// マイナスのデータが見つかった
	if(item < 0){

		// データを抽出対象に含める
		return true;
	}

	// データを抽出対象に含めない
	return false;
});

// ------------------------------------------------------------
// コールバック関数
// ------------------------------------------------------------
function VectorMapFunc(item:String,index:int,vector:Vector.<String>):String{

	trace("---");
	trace("index:" + index);
	trace("data:" + item);
	trace("this:" + this);

	// 変換後のデータを返す
	return ("convert_" + item);
}


// ------------------------------------------------------------
// データを変換する
// ------------------------------------------------------------
// Vector オブジェクトを作成する（Number 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E"]);

// データを変換し、新しい配列を取得する
var b:Vector.<String> = a.map(VectorMapFunc);

// Vector オブジェクトを作成する（String 型）
var a:Vector.<String> = Vector.<String>(["A","B","C","D","E"]);

// データを変換し、新しい配列を取得する
var b:Vector.<String> = a.map(function (item:String,index:int,vector:Vector.<String>):String{

	// 小文字に変換
	var lower:String = item.toLocaleLowerCase();

	// 変換後のデータを返す
	return lower;
});