ファイルの操作について

import flash.filesystem.File;

// ファイルオブジェクトを作成する
var file0 : File = new File();
var file1 : File = new File("C:\\test.txt");
var file2 : File = new File("file:///C:/test.txt");
var file3 : File = new File("/home/user/test.txt");

import flash.filesystem.File;

// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var new_file : File = desktop_dir.resolvePath("test.txt");

trace(new_file.nativePath);

import flash.filesystem.File;
import flash.net.FileFilter;

// 選択するファイルの種類をフィルタリング
var txtFilter0:FileFilter = new FileFilter("テキスト関連のファイル", "*.txt;*.doc;*.html");
var txtFilter1:FileFilter = new FileFilter("Flash関連のファイル", "*.fla;*.swf;");

// ファイルオブジェクトを作成する
var file:File = new File();

// １つのファイルを開くためのダイアログを表示する(非同期)
file.browseForOpen("ファイルを開く",[txtFilter0,txtFilter1]);

import flash.filesystem.File;
import flash.events.Event;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT , FileBrowseForOpenSelectFunc);
function FileBrowseForOpenSelectFunc(e:Event):void {

	// 選択したファイル
	var select : File = e.target as File;

	trace("開く : " + select.nativePath);

};

// キャンセルされた時に呼び出されるイベント
file.addEventListener(Event.CANCEL , FileBrowseForOpenCancelFunc);
function FileBrowseForOpenCancelFunc(e:Event):void {

	trace("閉じるボタンが押された");

};

// １つのファイルを開くためのダイアログを表示する(非同期)
file.browseForOpen("ファイルを開く");

import flash.filesystem.File;
import flash.net.FileFilter;

// 選択するファイルの種類をフィルタリング
var txtFilter0:FileFilter = new FileFilter("テキスト関連のファイル", "*.txt;*.doc;*.html");
var txtFilter1:FileFilter = new FileFilter("Flash関連のファイル", "*.fla;*.swf;");

// ファイルオブジェクトを作成する
var file:File = new File();

// 複数のファイルを開くためのダイアログを表示する(非同期)
file.browseForOpenMultiple("複数のファイルを開く",[txtFilter0,txtFilter1]);

import flash.filesystem.File;
import flash.events.Event;
import flash.events.FileListEvent;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(FileListEvent.SELECT_MULTIPLE , FileBrowseForOpenSelectMultipleFunc);
function FileBrowseForOpenSelectMultipleFunc(e:FileListEvent):void {

	// 選択した複数ファイル
	var files : Array = e.files;

	// 配列の中身を列挙
	var i : int;
	for(i=0;i < files.length;i++){
		var select : File = files[i];
		trace("開く : " + select.nativePath);
	}

};

// キャンセルされた時に呼び出されるイベント
file.addEventListener(Event.CANCEL , FileBrowseForOpenCancelFunc);
function FileBrowseForOpenCancelFunc(e:Event):void {

	trace("閉じるボタンが押された");

};

// 複数のファイルを開くためのダイアログを表示する(非同期)
file.browseForOpenMultiple("複数のファイルを開く");

import flash.filesystem.File;

// ファイルオブジェクトを作成する
var file:File = new File();

// ファイルを保存するためのダイアログを表示する(非同期)
file.browseForSave ("ファイルを保存する");

import flash.filesystem.File;
import flash.filesystem.FileStream;
import flash.filesystem.FileMode;
import flash.events.Event;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT , FileBrowseForSaveSelectFunc);
function FileBrowseForSaveSelectFunc(e:Event):void {

	// 選択したファイル
	var select : File = e.target as File;

	trace("保存 : " + select.nativePath);
	
	// ファイルに書き込む（実行注意）
	/*
	var stream:FileStream = new FileStream();
	stream.open(select, FileMode.WRITE);
	stream.writeUTFBytes("保存テスト");
	stream.close();
	*/

};

// キャンセルされた時に呼び出されるイベント
file.addEventListener(Event.CANCEL , FileBrowseForSaveCancelFunc);
function FileBrowseForSaveCancelFunc(e:Event):void {

	trace("閉じるボタンが押された");

};

// ファイルを保存するためのダイアログを表示する(非同期)
file.browseForSave("ファイルを保存");

import flash.filesystem.File;

// ファイルオブジェクトを作成する
var file:File = new File();

// フォルダを選択するためのダイアログを表示する(非同期)
file.browseForDirectory("ディレクトリを選択");

import flash.filesystem.File;
import flash.events.Event;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT , FileBrowseForDirectorySelectFunc);
function FileBrowseForDirectorySelectFunc(e:Event):void {

	// 選択したファイル
	var select : File = e.target as File;

	trace("開く : " + select.nativePath);

};

// キャンセルされた時に呼び出されるイベント
file.addEventListener(Event.CANCEL , FileBrowseForDirectoryCancelFunc);
function FileBrowseForDirectoryCancelFunc(e:Event):void {

	trace("閉じるボタンが押された");

};

// フォルダを選択するためのダイアログを表示する(非同期)
file.browseForDirectory("ディレクトリを選択");

import flash.filesystem.File;
import flash.events.Event;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT,FileBrowseForOpenSelectFunc);
function FileBrowseForOpenSelectFunc(e:Event):void {

	// 選択したファイル
	var select : File = e.target as File;
	
	trace("ファイル名 : " + select.name);				// ファイル名
	trace("拡張子 : " + select.extension);			// 拡張子
	trace("サイズ : " + select.size);				// サイズ
	trace("ファイル形式 : " + select.type);			// ファイル形式
	trace("作成日 : " + select.creationDate);			// 作成日
	trace("最終更新日 : " + select.modificationDate);		// 最終更新日
	trace("クリエータタイプ(Macintosh用) : " + select.creator);	// クリエータタイプ(Macintosh用)

};

// １つのファイルを開くためのダイアログを表示する(非同期)
file.browseForOpen("ファイルを開く");

import flash.filesystem.File;
import flash.events.Event;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT , FileBrowseForOpenSelectFunc);
function FileBrowseForOpenSelectFunc(e:Event):void {

	// 選択したファイル
	var select : File = e.target as File;

	trace("ファイルのURLパス : " + select.url);			// ファイルのURLパス
	trace("各ＯＳでのファイルパス名称 : " + select.nativePath);	// 各ＯＳでのディレクトリパス名称
	trace("アイコン : " + select.icon);				// アイコン
	trace("ディレクトリか : " + select.isDirectory);		// ディレクトリならtrue ファイルなら false
	trace("隠し属性か : " + select.isHidden);			// 隠し（非表示）属性が付いているか
	trace("アーカイブ属性か : " + select.isPackage);		// アーカイブ属性が付いているか
	trace("ファイルが存在するか : " + select.exists);		// ファイルが存在するか
	trace("ショートカットか : " + select.isSymbolicLink);		// ショートカット（シンボリックリンク）であるか

};

// １つのファイルを開くためのダイアログを表示する(非同期)
file.browseForOpen("ファイルを開く");

import flash.filesystem.File;

trace("OS の行終了文字 : " + File.lineEnding);			// OS の行終了文字
trace("OS のコンポーネントの区切り文字 : " + File.separator);		// OS のコンポーネントの区切り文字
trace("OS のデフォルトのエンコーディング : " + File.systemCharset);	// OS のデフォルトのエンコーディング

import flash.filesystem.File;

// 実行ファイルが格納されているディレクトリ（インストールされているディレクトリ）を取得する
var app_dir:File = File.applicationDirectory;
trace("実行ディレクトリ : " + app_dir.nativePath);

// 記憶領域ディレクトリを取得する
var app_storage_dir:File = File.applicationStorageDirectory;
trace("記憶領域ディレクトリ : " + app_storage_dir.nativePath);

// デスクトップのディレクトリを取得する
var desktop_dir:File = File.desktopDirectory;
trace("デスクトップ : " + desktop_dir.nativePath);

// マイドキュメントのディレクトリを取得する
var document_dir:File = File.documentsDirectory;
trace("マイドキュメント : " + document_dir.nativePath);

// ユーザーディレクトリを取得する
var user_dir:File = File.userDirectory;
trace("ユーザーディレクトリ : " + user_dir.nativePath);

import flash.filesystem.File;

// すべてのルートディレクトリを取得する
var root_directries : Array = File.getRootDirectories();

// 配列の中身を列挙
var i:int;
for(i=0;i < root_directries.length;i++){
	var root_directroy : File = root_directries[i];
	trace("ルートディレクトリ : " + root_directroy.nativePath);
}

import flash.filesystem.File;
import flash.events.Event;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT,FileBrowseForDirectorySelectFunc);
function FileBrowseForDirectorySelectFunc(e:Event):void {

	// 選択したフォルダ
	var select : File = e.target as File;

	// 選択したフォルダから 1 つ上のフォルダ
	var parent_dir : File = select.parent;

	trace("１つ上のパス : " + parent_dir.nativePath);		

};

// フォルダを選択するためのダイアログを表示する(非同期)
file.browseForDirectory("ディレクトリを選択");

import flash.filesystem.File;
import flash.events.Event;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT,FileBrowseForDirectorySelectFunc);
function FileBrowseForDirectorySelectFunc(e:Event):void {

	// 選択したディレクトリ
	var select : File = e.target as File;

	// フォルダ内のすべてのファイルとフォルダを取得
	var files : Array = select.getDirectoryListing();

	// 配列の中身を列挙
	var i:int;
	for(i=0;i < files.length;i++){
		var file : File = files[i];
		trace(file.nativePath);
	}
};

// ファイルを保存するためのダイアログを表示する(非同期)
file.browseForDirectory("ディレクトリを選択");

import flash.filesystem.File;
import flash.events.Event;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT,FileBrowseForDirectorySelectFunc);
function FileBrowseForDirectorySelectFunc(e:Event):void {

	// 選択したディレクトリ
	var select : File = e.target as File;

	// 再帰的にすべてのファイルとフォルダを調べる
	FileFindFiles(select);
};

// ファイルを保存するためのダイアログを表示する(非同期)
file.browseForDirectory("ディレクトリを選択");


// ------------------------------------------------------------
// 再帰的にすべてのファイルとフォルダを調べる関数
// ------------------------------------------------------------
function FileFindFiles(file:File):void {

	// フォルダ内のすべてのファイルとフォルダを取得
	var files : Array = file.getDirectoryListing();

	var i:int;
	for(i=0;i < files.length;i++){
		var f:File = files[i];

		// ディレクトリである
		if (f.isDirectory) {
			// 再帰実行
			FileFindFiles(f);
		}

		trace(f.nativePath);
	}
}

import flash.filesystem.File;
import flash.events.Event;
import flash.events.FileListEvent;
import flash.events.IOErrorEvent;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT , FileBrowseForDirectorySelectFunc);
function FileBrowseForDirectorySelectFunc(e:Event):void {

	// 選択したファイル
	var select : File = e.target as File;

	// フォルダ内の調査が終了した時に呼ばれる関数
	select.addEventListener(FileListEvent.DIRECTORY_LISTING , DirectoryGetListAsyncFunc);
	function DirectoryGetListAsyncFunc(event:FileListEvent):void {

		// フォルダ内のすべてのファイルとフォルダ
		var files:Array = event.files;

		// 配列の中身を列挙
		var i:int;
		for (i=0;i < files.length;i++) {
			var f:File = files[i];

			// ファイルのパスを取得
			trace(f.nativePath);
		}
	}
	
	// 入出力エラー時に呼ばれる関数
	select.addEventListener(IOErrorEvent.IO_ERROR , DirectoryGetListAsyncIOErrorFunc );
	function DirectoryGetListAsyncIOErrorFunc(event:IOErrorEvent): void{

	    trace("入出力エラー");

	}

	// フォルダ内のすべてのファイルとフォルダを取得(非同期)
	select.getDirectoryListingAsync();

};

// ファイルを保存するためのダイアログを表示する(非同期)
file.browseForDirectory("ディレクトリを選択");

import flash.filesystem.File;
import flash.events.Event;
import flash.events.FileListEvent;
import flash.events.IOErrorEvent;

// ファイルオブジェクトを作成する
var file:File = new File();

// 選択された時に呼び出されるイベント
file.addEventListener(Event.SELECT , FileBrowseForDirectorySelectFunc);
function FileBrowseForDirectorySelectFunc(e:Event):void {

	// 選択したファイル
	var select : File = e.target as File;

	// 再帰的にすべてのファイルとフォルダを調べる(非同期)
	FileFindFilesAsync(select);

};

// ファイルを保存するためのダイアログを表示する(非同期)
file.browseForDirectory("ディレクトリを選択");


// ------------------------------------------------------------
// 再帰的にすべてのファイルとフォルダを調べる関数(非同期)
// ------------------------------------------------------------
function FileFindFilesAsync(file:File):void {

	// フォルダ内の調査が終了した時に呼ばれる関数
	file.addEventListener(FileListEvent.DIRECTORY_LISTING , DirectoryGetListAsyncFunc);
	function DirectoryGetListAsyncFunc(event:FileListEvent):void {

		// フォルダ内のすべてのファイルとフォルダ
		var files:Array = event.files;

		// 配列の中身を列挙
		var i:int;
		for (i=0;i < files.length;i++) {
			var f:File = files[i];

			// ファイルのパスを取得
			trace(f.nativePath);

			// ディレクトリである
			if (f.isDirectory) {
				// 再帰実行
				FileFindFilesAsync(f);
			}
		}
	}
	
	// 入出力エラー時に呼ばれる関数
	file.addEventListener(IOErrorEvent.IO_ERROR , DirectoryGetListAsyncIOErrorFunc );
	function DirectoryGetListAsyncIOErrorFunc(event:IOErrorEvent): void{

	    trace("入出力エラー");

	}

	// フォルダ内のすべてのファイルとフォルダを取得(非同期)
	file.getDirectoryListingAsync();

}

import flash.filesystem.File;

// Cドライブ直下の "test.txt" ファイルを指定して、ファイルオブジェクトを作成する。(Windows の場合) 
var file : File = new File("C:\\test.txt");

import flash.filesystem.File;

// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var file : File = desktop_dir.resolvePath("test.txt");

import flash.filesystem.File;
import flash.filesystem.FileStream;
import flash.filesystem.FileMode;

// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var file : File = desktop_dir.resolvePath("test.txt");

// 文字列を書き込む
var stream : FileStream = new FileStream();
stream.open (file, FileMode.WRITE);
stream.writeUTFBytes("保存テスト");
stream.close();

import flash.filesystem.File;

// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test" を指定して、新規に File オブジェクトを作成する
var file : File = desktop_dir.resolvePath("test");

// フォルダを作成する
file.createDirectory();

import flash.filesystem.File;

// 一時的な作業用ファイルを作成する
var file : File = File.createTempFile();
trace(file.nativePath);

// ファイルを削除する
//file.deleteFile();

import flash.filesystem.File;

// 一時的な作業用フォルダを作成する
var file : File = File.createTempDirectory();
trace(file.nativePath);

// フォルダを削除する
//file.deleteDirectory(true);

import flash.filesystem.File;

// Cドライブ直下の "test.txt" ファイルを指定して、ファイルオブジェクトを作成する。(Windows の場合) 
var file : File = new File("C:\\test.txt");

import flash.filesystem.File;

// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var file : File = desktop_dir.resolvePath("test.txt");

import flash.filesystem.File;

// ------------------------------------------------------------
// 移動元のファイルオブジェクト
// ------------------------------------------------------------
// 一時的な作業用ファイルを作成する
var source_file : File = File.createTempFile();


// ------------------------------------------------------------
// 移動後のファイルオブジェクト
// ------------------------------------------------------------
// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var move_file : File = desktop_dir.resolvePath("test.txt");


// ------------------------------------------------------------
// ファイルの移動
// ------------------------------------------------------------
try {
	// ファイルを移動する
	source_file.moveTo(move_file, true);

	trace("移動が完了しました");

}catch (error:Error){
	trace("エラー");
}

import flash.filesystem.File;

// ------------------------------------------------------------
// 移動元のファイルオブジェクト
// ------------------------------------------------------------
// 一時的な作業フォルダを作成する
var source_dir : File = File.createTempDirectory();


// ------------------------------------------------------------
// 移動後のファイルオブジェクト
// ------------------------------------------------------------
// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test" を指定して、新規に File オブジェクトを作成する
var move_dir : File = desktop_dir.resolvePath("test");


// ------------------------------------------------------------
// フォルダの移動
// ------------------------------------------------------------
try {
	// フォルダを移動する
	source_dir.moveTo(move_dir , true);

	trace("移動が完了しました");

}catch (error:Error){
	trace("エラー");
}

import flash.filesystem.File;
import flash.events.Event;
import flash.events.IOErrorEvent;

// ------------------------------------------------------------
// 移動元のファイルオブジェクト
// ------------------------------------------------------------
// 一時的な作業用ファイルを作成する
var source_file : File = File.createTempFile();


// ------------------------------------------------------------
// 移動後のファイルオブジェクト
// ------------------------------------------------------------
// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var move_file : File = desktop_dir.resolvePath("test.txt");


// ------------------------------------------------------------
// フォルダの移動
// ------------------------------------------------------------
// 移動終了時に呼ばれるイベント
source_file.addEventListener(Event.COMPLETE, FileMoveToAsyncCompleteFunc );
function FileMoveToAsyncCompleteFunc(event:Event): void{
    trace("移動が終了しました");
}

// 入出力エラー時に呼ばれるイベント
source_file.addEventListener(IOErrorEvent.IO_ERROR, FileMoveToAsyncIOErrorFunc );
function FileMoveToAsyncIOErrorFunc(event:IOErrorEvent): void{
    trace("入出力エラー");
}

// ファイルを移動する(非同期)
source_file.moveToAsync(move_file, true);

import flash.filesystem.File;
import flash.events.Event;
import flash.events.IOErrorEvent;

// ------------------------------------------------------------
// 移動元のファイルオブジェクト
// ------------------------------------------------------------
// 一時的な作業フォルダを作成する
var source_dir : File = File.createTempDirectory();


// ------------------------------------------------------------
// 移動後のファイルオブジェクト
// ------------------------------------------------------------
// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test" を指定して、新規に File オブジェクトを作成する
var move_dir : File = desktop_dir.resolvePath("test");


// ------------------------------------------------------------
// フォルダの移動
// ------------------------------------------------------------
// 移動終了時に呼ばれるイベント
source_file.addEventListener(Event.COMPLETE, FileMoveToAsyncCompleteFunc );
function FileMoveToAsyncCompleteFunc(event:Event): void{
    trace("移動が終了しました");
}

// 入出力エラー時に呼ばれるイベント
source_file.addEventListener(IOErrorEvent.IO_ERROR, FileMoveToAsyncIOErrorFunc );
function FileMoveToAsyncIOErrorFunc(event:IOErrorEvent): void{
    trace("入出力エラー");
}

// フォルダを移動する(非同期)
source_dir.moveToAsync(move_dir, true);

import flash.filesystem.File;

// Cドライブ直下の "test.txt" ファイルを指定して、ファイルオブジェクトを作成する。(Windows の場合) 
var file : File = new File("C:\\test.txt");

import flash.filesystem.File;

// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var file : File = desktop_dir.resolvePath("test.txt");

import flash.filesystem.File;

// ------------------------------------------------------------
// コピー元のファイルオブジェクト
// ------------------------------------------------------------
// 一時的な作業用ファイルを作成する
var source_file : File = File.createTempFile();


// ------------------------------------------------------------
// コピー後のファイルオブジェクト
// ------------------------------------------------------------
// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var copy_file : File = desktop_dir.resolvePath("test.txt");


// ------------------------------------------------------------
// ファイルのコピー
// ------------------------------------------------------------
try {
	// ファイルをコピーする
	source_file.copyTo(copy_file, true);

	trace("コピーが完了しました");

}catch (error:Error){
	trace("エラー");
}

import flash.filesystem.File;

// ------------------------------------------------------------
// コピー元のファイルオブジェクト
// ------------------------------------------------------------
// 一時的な作業フォルダを作成する
var source_dir : File = File.createTempDirectory();


// ------------------------------------------------------------
// コピー後のファイルオブジェクト
// ------------------------------------------------------------
// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test" を指定して、新規に File オブジェクトを作成する
var copy_dir : File = desktop_dir.resolvePath("test");


// ------------------------------------------------------------
// フォルダのコピー
// ------------------------------------------------------------
try {
	// フォルダをコピーする
	source_dir.copyTo(copy_dir , true);

	trace("コピーが完了しました");

}catch (error:Error){
	trace("エラー");
}

import flash.filesystem.File;
import flash.events.Event;
import flash.events.IOErrorEvent;

// ------------------------------------------------------------
// コピー元のファイルオブジェクト
// ------------------------------------------------------------
// 一時的な作業用ファイルを作成する
var source_file : File = File.createTempFile();


// ------------------------------------------------------------
// コピー後のファイルオブジェクト
// ------------------------------------------------------------
// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var copy_file : File = desktop_dir.resolvePath("test.txt");


// ------------------------------------------------------------
// フォルダのコピー
// ------------------------------------------------------------
// コピー終了時に呼ばれるイベント
source_file.addEventListener(Event.COMPLETE, FileCopyToAsyncCompleteFunc );
function FileCopyToAsyncCompleteFunc(event:Event): void{
    trace("コピーが終了しました");
}

// 入出力エラー時に呼ばれるイベント
source_file.addEventListener(IOErrorEvent.IO_ERROR, FileCopyToAsyncIOErrorFunc );
function FileCopyToAsyncIOErrorFunc(event:IOErrorEvent): void{
    trace("入出力エラー");
}

// ファイルをコピーする(非同期)
source_file.copyToAsync(copy_file, true);

import flash.filesystem.File;
import flash.events.Event;
import flash.events.IOErrorEvent;

// ------------------------------------------------------------
// コピー元のファイルオブジェクト
// ------------------------------------------------------------
// 一時的な作業フォルダを作成する
var source_dir : File = File.createTempDirectory();


// ------------------------------------------------------------
// コピー後のファイルオブジェクト
// ------------------------------------------------------------
// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test" を指定して、新規に File オブジェクトを作成する
var copy_dir : File = desktop_dir.resolvePath("test");


// ------------------------------------------------------------
// フォルダのコピー
// ------------------------------------------------------------
// コピー終了時に呼ばれるイベント
source_file.addEventListener(Event.COMPLETE, FileCopyToAsyncCompleteFunc );
function FileCopyToAsyncCompleteFunc(event:Event): void{
    trace("コピーが終了しました");
}

// 入出力エラー時に呼ばれるイベント
source_file.addEventListener(IOErrorEvent.IO_ERROR, FileCopyToAsyncIOErrorFunc );
function FileCopyToAsyncIOErrorFunc(event:IOErrorEvent): void{
    trace("入出力エラー");
}

// フォルダをコピーする(非同期)
source_dir.copyToAsync(copy_dir, true);

import flash.filesystem.File;

// Cドライブ直下の "test.txt" ファイルを指定して、ファイルオブジェクトを作成する。(Windows の場合) 
var file : File = new File("C:\\test.txt");

import flash.filesystem.File;

// デスクトップのディレクトリを取得する
var desktop_dir : File = File.desktopDirectory;

// 「デスクトップのディレクトリ」を基点として、相対パス "test.txt" を指定して、新規に File オブジェクトを作成する
var file : File = desktop_dir.resolvePath("test.txt");

import flash.filesystem.File;

// 一時的な作業用ファイルを作成する
var file : File = File.createTempFile();

try {
	// ファイルを削除する
	file.deleteFile();

	trace("ファイルの削除が完了しました");

}catch (error:Error){
	trace("エラー");
}

import flash.filesystem.File;
import flash.events.Event;
import flash.events.IOErrorEvent;

// 一時的な作業用ファイルを作成する
var file : File = File.createTempFile();

// ファイルの削除完了時に呼ばれるイベント
file.addEventListener(Event.COMPLETE, FileDeleteFileAsyncCompleteFunc );
function FileDeleteFileAsyncCompleteFunc(event:Event): void{
    trace("ファイルの削除が終了しました");
}

// 入出力エラー時に呼ばれるイベント
file.addEventListener(IOErrorEvent.IO_ERROR, FileDeleteFileAsyncIOErrorFunc );
function FileDeleteFileAsyncIOErrorFunc(event:IOErrorEvent): void{
    trace("入出力エラー");
}

// ファイルを削除する(非同期)
file.deleteFileAsync();

import flash.filesystem.File;

// 一時的な作業用フォルダを作成する
var file : File = File.createTempDirectory();

try {
	// フォルダを削除する
	file.deleteDirectory();

	trace("フォルダの削除が完了しました");

}catch (error:Error){
	trace("エラー");
}

import flash.filesystem.File;
import flash.events.Event;
import flash.events.IOErrorEvent;

// 一時的な作業用フォルダを作成する
var file : File = File.createTempDirectory();

// フォルダの削除完了時に呼ばれるイベント
file.addEventListener(Event.COMPLETE, FileDeleteDirectoryAsyncCompleteFunc );
function FileDeleteDirectoryAsyncCompleteFunc(event:Event): void{
    trace("フォルダの削除が終了しました");
}

// 入出力エラー時に呼ばれるイベント
file.addEventListener(IOErrorEvent.IO_ERROR, FileDeleteDirectoryAsyncIOErrorFunc );
function FileDeleteDirectoryAsyncIOErrorFunc(event:IOErrorEvent): void{
    trace("入出力エラー");
}

// フォルダを削除する(非同期)
file.deleteDirectoryAsync();

import flash.filesystem.File;

// 一時的な作業用ファイルを作成する
var file : File = File.createTempFile();

try {
	// ファイルをゴミ箱へ移動する
	file.moveToTrash();

	trace("ゴミ箱への移動が完了しました");

}catch (error:Error){
	trace("エラー");
}

import flash.filesystem.File;
import flash.events.Event;
import flash.events.IOErrorEvent;

// 一時的な作業用ファイルを作成する
var file : File = File.createTempFile();

// ゴミ箱への移動完了時に呼ばれるイベント
file.addEventListener(Event.COMPLETE, FileDeleteFileAsyncCompleteFunc );
function FileDeleteFileAsyncCompleteFunc(event:Event): void{
    trace("ゴミ箱への移動が終了しました");
}

// 入出力エラー時に呼ばれるイベント
file.addEventListener(IOErrorEvent.IO_ERROR, FileDeleteFileAsyncIOErrorFunc );
function FileDeleteFileAsyncIOErrorFunc(event:IOErrorEvent): void{
    trace("入出力エラー");
}

// ファイルをゴミ箱へ移動する(非同期)
file.moveToTrashAsync();