ビットマップについて

import flash.display.Bitmap;

// Bitmap オブジェクトを作成する
var bitmap_obj:Bitmap = new Bitmap();

// 出力テスト
trace(bitmap_obj);

import flash.display.BitmapData;
import flash.display.Bitmap;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 256 , 256 , true , 0xffcc8800 );

// ------------------------------------------------------------
// Bitmap オブジェクトを作成する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap();

// ------------------------------------------------------------
// BitmapData をセットする
// ------------------------------------------------------------
bitmap_obj.bitmapData = bmp_data;

// ------------------------------------------------------------
// ステージの表示リストに登録する
// ------------------------------------------------------------
stage.addChild(bitmap_obj);

import flash.display.BitmapData;
import flash.display.Bitmap;

// ------------------------------------------------------------
// 初期化パラメータ
// ------------------------------------------------------------
// ビットマップの幅
var width:int = 400;
// ビットマップの高さ
var height:int = 300;
// 単一色で塗りつぶす RGB カラー
var color_rgb:uint = 0xFFCC88;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（24bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( width , height , false , color_rgb );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.Bitmap;

// ------------------------------------------------------------
// 初期化パラメータ
// ------------------------------------------------------------
// ビットマップの幅
var width:int = 400;
// ビットマップの高さ
var height:int = 300;
// 単一色で塗りつぶす ARGB カラー
var color_argb:uint = 0x80FFCC88;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( width , height , true , color_argb );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 400 , 300 );

// ------------------------------------------------------------
// BitmapData オブジェクトを解放する
// ------------------------------------------------------------
bmp_data.dispose();
bmp_data = null;

import flash.display.BitmapData;
import flash.display.Bitmap;

// ------------------------------------------------------------
// 埋め込んだ画像ファイルから、BitmapData オブジェクトを作成する (自作クラス "MyBitmapData" )
// ------------------------------------------------------------
var bmp_data:BitmapData = new MyBitmapData( 0 , 0 );

// 出力テスト
trace(bmp_data);

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

package 
{
	import flash.display.Sprite;

	// ------------------------------------------------------------
	// Main クラス
	// ------------------------------------------------------------
	public class Main extends Sprite 
	{

		// ------------------------------------------------------------
		// 埋め込みアセットクラス
		// ------------------------------------------------------------
		[Embed(source = "../resource/sample.png")]
		private var MyBitmap:Class;

		// ------------------------------------------------------------
		// コンストラクタ
		// ------------------------------------------------------------
		public function Main():void {

		}

	}

}

package 
{
	import flash.display.Sprite;
	import flash.display.BitmapData;
	import flash.display.Bitmap;

	// ------------------------------------------------------------
	// Main クラス
	// ------------------------------------------------------------
	public class Main extends Sprite 
	{

		// ------------------------------------------------------------
		// 埋め込みコード
		// ------------------------------------------------------------
		[Embed(source = "../resource/sample.png")]
		private var MyBitmap:Class;

		// ------------------------------------------------------------
		// コンストラクタ
		// ------------------------------------------------------------
		public function Main():void {

			// ------------------------------------------------------------
			// 埋め込んだ画像ファイルから、Bitmap オブジェクトを作成する (自作クラス "MyBitmap" )
			// ------------------------------------------------------------
			var bitmap_obj:Bitmap = new MyBitmap();

			// 出力テスト
			trace(bitmap_obj);

			// ------------------------------------------------------------
			// BitmapData オブジェクトを取得する
			// ------------------------------------------------------------
			var bmp_data:BitmapData = bitmap_obj.bitmapData;

			// 出力テスト
			trace(bmp_data);

			// ------------------------------------------------------------
			// ステージに配置する
			// ------------------------------------------------------------
			stage.addChild( bitmap_obj );
			
		}

	}

}

import flash.display.BitmapData;
import flash.display.Bitmap;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xFF00FF00 );

// ------------------------------------------------------------
// ビットマップに描画する（ソースはステージ全体）
// ------------------------------------------------------------
bmp_data.draw( stage );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Matrix;
import flash.geom.ColorTransform;
import flash.geom.Rectangle;

// ------------------------------------------------------------
// ソース用の表示オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = (function():Shape{

	// ------------------------------------------------------------
	// Shape オブジェクトを作成
	// ------------------------------------------------------------
	var shape:Shape = new Shape();

	// ------------------------------------------------------------
	// 矩形を描画
	// ------------------------------------------------------------
	var g:Graphics = shape.graphics;
	var mtx:Matrix = new Matrix(320/1638.4,0,0,1,160,0);
	g.lineStyle (5, 0x505050, 100);
	g.beginGradientFill ( GradientType.LINEAR , [0xFF8080,0x8080FF] , [1.0,1.0] , [0,255] , mtx);
	g.moveTo (    0 ,   0 );
	g.lineTo (    0 , 240 );
	g.lineTo (  320 , 240 );
	g.lineTo (  320 ,   0 );
	g.endFill();

	return shape;
})();


// ------------------------------------------------------------
// BitmapData オブジェクト
// ------------------------------------------------------------
var bmp_data:BitmapData = (function():BitmapData{

	// ------------------------------------------------------------
	// BitmapData オブジェクトを作成する（32bit）
	// ------------------------------------------------------------
	var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0x20000000 );

	// ------------------------------------------------------------
	// ソースの姿勢
	// ------------------------------------------------------------
	// 行列を作成（単位行列）
	var mtx:Matrix = new Matrix();
	// 移動成分を乗算
	mtx.translate(20 , 20);

	// ------------------------------------------------------------
	// ソースのカラートランスフォーム
	// ------------------------------------------------------------
	var color_transform:ColorTransform = new ColorTransform();

	// ------------------------------------------------------------
	// ターゲット側の描画範囲
	// ------------------------------------------------------------
	var target_clip:Rectangle = new Rectangle(0 , 0 , 512 , 512);

	// ------------------------------------------------------------
	// ビットマップに描画する（ソースは表示オブジェクト）
	// ------------------------------------------------------------
	bmp_data.draw( shape , mtx , color_transform , "normal" , target_clip );

	return bmp_data;
})();


// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xFFFFFFFF );

// ------------------------------------------------------------
// RGB カラー（24bit）を取得する
// ------------------------------------------------------------
var color_rgb0:uint = bmp_data.getPixel(  0 ,  0 );
var color_rgb1:uint = bmp_data.getPixel(  1 ,  5 );
var color_rgb2:uint = bmp_data.getPixel( 20 , 10 );

// ------------------------------------------------------------
// ARGB カラー（32bit）を取得する
// ------------------------------------------------------------
var color_argb0:uint = bmp_data.getPixel32(  0 ,  0 );
var color_argb1:uint = bmp_data.getPixel32(  1 ,  5 );
var color_argb2:uint = bmp_data.getPixel32( 20 , 10 );

// ------------------------------------------------------------
// 各カラー成分を取得
// ------------------------------------------------------------
var a:uint = (color_argb0 >>> 24) & 0xff;
var r:uint = (color_argb0 >>> 16) & 0xff;
var g:uint = (color_argb0 >>>  8) & 0xff;
var b:uint = (color_argb0 >>>  0) & 0xff;

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.utils.ByteArray;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 4 , 4 , true , 0xFFFFFFFF );

// ------------------------------------------------------------
// 取得する句形範囲
// ------------------------------------------------------------
var rect:Rectangle = bmp_data.rect;
var i:int;
var num:int = rect.width * rect.height;

// ------------------------------------------------------------
// ByteArray 型でまとめて取得する
// ------------------------------------------------------------
var byte_array:ByteArray = bmp_data.getPixels(rect);
byte_array.position = 0;
for(i=0;i < num;i++){
	// 位置と、ARGB カラーを取得
	var x:int = (i % rect.width) + rect.x;
	var y:int = Math.floor(i / rect.width) + rect.y;
	var color_argb:uint = byte_array.readUnsignedInt();

	// 出力テスト
	trace(x , y , color_argb.toString(16));
}

// ------------------------------------------------------------
// Vector 型でまとめて取得する
// ------------------------------------------------------------
var vector:Vector.<uint> = bmp_data.getVector(rect);
for(i=0;i < num;i++){
	// 位置と、ARGB カラーを取得
	var x:int = (i % rect.width) + rect.x;
	var y:int = Math.floor(i / rect.width) + rect.y;
	var color_argb:uint = vector[i];

	// 出力テスト
	trace(x , y , color_argb.toString(16));
}

import flash.display.BitmapData;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xFFFFFFFF );

// ------------------------------------------------------------
// RGB カラー（24bit）を書き込む
// ------------------------------------------------------------
bmp_data.setPixel(  0 ,  0 , 0x001122 );
bmp_data.setPixel(  1 ,  5 , 0xaabbcc );
bmp_data.setPixel( 20 , 10 , 0xff8800 );

// ------------------------------------------------------------
// ARGB カラー（32bit）を書き込む
// ------------------------------------------------------------
bmp_data.setPixel32(  0 ,  0 , 0xff001122 );
bmp_data.setPixel32(  1 ,  5 , 0xffaabbcc );
bmp_data.setPixel32( 20 , 10 , 0x20ff8800 );

// ------------------------------------------------------------
// RGB カラー（24bit）を取得する
// ------------------------------------------------------------
var color_rgb0:uint = bmp_data.getPixel(  0 ,  0 );
var color_rgb1:uint = bmp_data.getPixel(  1 ,  5 );
var color_rgb2:uint = bmp_data.getPixel( 20 , 10 );

// ------------------------------------------------------------
// ARGB カラー（32bit）を取得する
// ------------------------------------------------------------
var color_argb0:uint = bmp_data.getPixel32(  0 ,  0 );
var color_argb1:uint = bmp_data.getPixel32(  1 ,  5 );
var color_argb2:uint = bmp_data.getPixel32( 20 , 10 );

// ------------------------------------------------------------
// 出力テスト
// ------------------------------------------------------------
trace( color_rgb0.toString(16) ); // 00001122
trace( color_rgb1.toString(16) ); // 00aabbcc
trace( color_rgb2.toString(16) ); // 00ff8700
trace( color_argb0.toString(16) ); // ff001122
trace( color_argb1.toString(16) ); // ffaabbcc
trace( color_argb2.toString(16) ); // 20ff8700

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Rectangle;
import flash.utils.ByteArray;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xFFE0E0E0 );

// ------------------------------------------------------------
// 書き込む句形範囲
// ------------------------------------------------------------
var rect:Rectangle = new Rectangle(10 , 10 , 100 , 50);

// ------------------------------------------------------------
// ByteArray オブジェクトを作成
// ------------------------------------------------------------
var byte_array:ByteArray = new ByteArray();

// ------------------------------------------------------------
// 適当な色をセット
// ------------------------------------------------------------
byte_array.position = 0;
var i:int;
var num:int = rect.width * rect.height;
for(i=0;i < num;i++){
	var a:uint = Math.floor(Math.random() * 0xff);
	var r:uint = Math.floor(Math.random() * 0xff);
	var g:uint = Math.floor(Math.random() * 0xff);
	var b:uint = Math.floor(Math.random() * 0xff);
	var color_argb:uint = (a << 24) | (r << 16) | (g << 8) | (b << 0);

	byte_array.writeUnsignedInt(color_argb);
}

// ------------------------------------------------------------
// ByteArray 型でまとめて書き込む
// ------------------------------------------------------------
byte_array.position = 0;
bmp_data.setPixels( rect , byte_array );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Rectangle;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xFFE0E0E0 );

// ------------------------------------------------------------
// 書き込む句形範囲
// ------------------------------------------------------------
var rect:Rectangle = new Rectangle(10 , 10 , 100 , 50);
var num:int = rect.width * rect.height;

// ------------------------------------------------------------
// Vector オブジェクトを作成
// ------------------------------------------------------------
var vector:Vector.<uint> = new Vector.<uint>(num);

// ------------------------------------------------------------
// 適当な色をセット
// ------------------------------------------------------------
var i:int;
for(i=0;i < num;i++){
	var a:uint = Math.floor(Math.random() * 0xff);
	var r:uint = Math.floor(Math.random() * 0xff);
	var g:uint = Math.floor(Math.random() * 0xff);
	var b:uint = Math.floor(Math.random() * 0xff);
	var color_argb:uint = (a << 24) | (r << 16) | (g << 8) | (b << 0);

	vector[i] = color_argb;
}

// ------------------------------------------------------------
// Vector 型でまとめて書き込む
// ------------------------------------------------------------
bmp_data.setVector( rect , vector );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Rectangle;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xFFE0E0FF );

// ------------------------------------------------------------
// 各カラーを用意
// ------------------------------------------------------------
var a:uint = 255;
var r:uint = 255;
var g:uint = 192;
var b:uint = 128;

// ------------------------------------------------------------
// 各カラーから ARGB 値を計算
// ------------------------------------------------------------
var color_argb:uint = (a << 24) | (r << 16) | (g << 8) | (b << 0);

// ------------------------------------------------------------
// Rectangle オブジェクトを作成
// ------------------------------------------------------------
var rect:Rectangle = new Rectangle( 10 , 10 , 200 , 100 );

// ------------------------------------------------------------
// ビットマップを塗りつぶす（矩形指定）
// ------------------------------------------------------------
bmp_data.fillRect(  rect , color_argb );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.Bitmap;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xFFE0E0FF );

// ------------------------------------------------------------
// 各カラーを用意
// ------------------------------------------------------------
var a:uint = 255;
var r:uint = 255;
var g:uint = 192;
var b:uint = 128;

// ------------------------------------------------------------
// 各カラーから ARGB 値を計算
// ------------------------------------------------------------
var color_argb:uint = (a << 24) | (r << 16) | (g << 8) | (b << 0);

// ------------------------------------------------------------
// ビットマップを塗りつぶす（塗りつぶしツール方式）
// ------------------------------------------------------------
bmp_data.floodFill(  1 , 1 , color_argb );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.geom.Rectangle;

// ------------------------------------------------------------
// ARGB 値を用意
// ------------------------------------------------------------
var color_argb0:uint = 0xFF998877;
var color_argb1:uint = 0xff112233;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new flash.display.BitmapData( 512 , 512 , true , color_argb0 );

// ------------------------------------------------------------
// 適当な位置にピクセルカラーを書き込む
// ------------------------------------------------------------
bmp_data.setPixel32(  40 , 150 , color_argb1 );
bmp_data.setPixel32( 200 ,  60 , color_argb1 );
bmp_data.setPixel32( 420 , 220 , color_argb1 );

// ------------------------------------------------------------
// マスクを用意（ここでは青色成分を無視）
// ------------------------------------------------------------
var mask:uint = 0xFFFFFF00;

// ------------------------------------------------------------
// 「指定カラー」をすべて含む、矩形サイズを取得する
// ------------------------------------------------------------
var rect0:Rectangle = bmp_data.getColorBoundsRect(  mask , (color_argb1 & mask) );

// 出力テスト
trace(rect0); // x:40 , y:60 , w:381 , h:161

// ------------------------------------------------------------
// 「指定カラー以外」をすべて含む、矩形サイズを取得する
// ------------------------------------------------------------
var rect1:Rectangle = bmp_data.getColorBoundsRect(  mask , (color_argb0 & mask) , false );

// 出力テスト
trace(rect1); // x:40 , y:60 , w:381 , h:161

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.events.Event;

// ------------------------------------------------------------
// 埋め込んだ画像ファイルから、BitmapData オブジェクトを作成する (自作クラス "MyBitmapData0" )
// ------------------------------------------------------------
var bmp_data:BitmapData = new MyBitmapData0( 0 , 0 );

// ------------------------------------------------------------
// 埋め込んだ画像ファイルから、BitmapData オブジェクトを作成する (自作クラス "MyBitmapData1" )
// ------------------------------------------------------------
var second_obj:BitmapData = new MyBitmapData1( 0 , 0 );

// ------------------------------------------------------------
// Bitmap オブジェクトを作成
// ------------------------------------------------------------
var bitmap_obj0:Bitmap = new Bitmap( bmp_data );
var bitmap_obj1:Bitmap = new Bitmap( second_obj );
stage.addChild( bitmap_obj0 );
stage.addChild( bitmap_obj1 );

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
stage.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// ------------------------------------------------------------
	// 当たり判定用パラメータ
	// ------------------------------------------------------------
	// 自身のビットマップの位置
	var first_pos:Point = new Point( 200 , 200 );

	// 相手のビットマップの位置
	var second_pos:Point = new Point( stage.mouseX , stage.mouseY );

	// ------------------------------------------------------------
	// ２つのビットマップの当たり判定を調べる
	// ------------------------------------------------------------
	var result:Boolean = bmp_data.hitTest( first_pos , 255 , second_obj , second_pos , 255 );
	if(result){
		trace("当たりあり");
	}else{
		trace("当たりなし");
	}

	// ------------------------------------------------------------
	// ムービークリップを移動
	// ------------------------------------------------------------
	bitmap_obj0.x = first_pos.x;
	bitmap_obj0.y = first_pos.y;
	bitmap_obj1.x = second_pos.x;
	bitmap_obj1.y = second_pos.y;

});

import flash.display.BitmapData;
import flash.display.Bitmap;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xFF224466 );

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data_other:BitmapData = new BitmapData( 512 , 512 , true , 0xFF101010 );

// ------------------------------------------------------------
// ２つの BitmapData オブジェクトを比較する
// ------------------------------------------------------------
var result:* = bmp_data.compare( bmp_data_other );

// 出力テスト
trace(result);

// ------------------------------------------------------------
// 一致しているか調べる
// ------------------------------------------------------------
var equal:Boolean = (result === 0);

// 出力テスト
trace(equal); // false

// ------------------------------------------------------------
// 差分 BitmapData が存在するか調べる
// ------------------------------------------------------------
var bmp_data_diff:BitmapData = result as BitmapData;
if(bmp_data_diff){

	// ------------------------------------------------------------
	// ステージに配置する
	// ------------------------------------------------------------
	var bitmap_obj:Bitmap = new Bitmap(bmp_data_diff);
	stage.addChild( bitmap_obj );

	// 出力テスト
	trace( bmp_data_diff.getPixel32(0,0).toString(16) ); // ff123456
}

import flash.display.BitmapData;
import flash.display.Bitmap;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 4 , 4 , true , 0xFF010203 );

// ------------------------------------------------------------
// ビットマップのヒストグラムを取得する
// ------------------------------------------------------------
var histogram_list:Vector.<Vector.<Number>> = bmp_data.histogram();

// ------------------------------------------------------------
// 各チャンネルごとのヒストグラムデータ
// ------------------------------------------------------------
var histogram_r:Vector.<Number> = histogram_list[0];
var histogram_g:Vector.<Number> = histogram_list[1];
var histogram_b:Vector.<Number> = histogram_list[2];
var histogram_a:Vector.<Number> = histogram_list[3];

// ------------------------------------------------------------
// 出力テスト
// ------------------------------------------------------------
trace(histogram_r); // [ 0 , 16 ,  0 ,  0 , 0 ...
trace(histogram_g); // [ 0 ,  0 , 16 ,  0 , 0 ...
trace(histogram_b); // [ 0 ,  0 ,  0 , 16 , 0 ...
trace(histogram_a); // [ 0 ,  0 ,  0 ,  0 , 0 ...

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Rectangle;
import flash.utils.ByteArray;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xFFFFFFFF );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

// ------------------------------------------------------------
// BitmapData のロックを開始する
// ------------------------------------------------------------
bmp_data.lock();

// ------------------------------------------------------------
// BitmapData を書込編集する
// ------------------------------------------------------------
var x:int;
var y:int;
var w:int = bmp_data.width;
var h:int = bmp_data.height;
for(y=0;y < h;y++){
	for(x=0;x < w;x++){
		bmp_data.setPixel( x , y , Math.floor(Math.random() * 0xFFFFFF) );
	}
}

// ------------------------------------------------------------
// BitmapData のロックを終了する
// ------------------------------------------------------------
bmp_data.unlock();

if( (アルファ値) == 0 ){

	(書込色) = 0;

}else{

	var g = 255 / (アルファ値);

	(書込色) = Math.round((指定色) / g) * g;

}

import flash.display.BitmapData;
import flash.display.Bitmap;

// ------------------------------------------------------------
// BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 256 , 256 , true , 0xffcc8800 );

// ------------------------------------------------------------
// BitmapData オブジェクトを複製する
// ------------------------------------------------------------
var bmp_data_clone:BitmapData = bmp_data.clone();

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.geom.Rectangle;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xffe0e0e0 );

// ------------------------------------------------------------
// ソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source:BitmapData = new BitmapData( 256 , 256 , true , 0xffcc8800 );

// ------------------------------------------------------------
// コピー用パラメータ
// ------------------------------------------------------------
// ソースの矩形範囲
var source_rect:Rectangle = new Rectangle( 50 , 50 , 256 , 128 );
// ターゲットの位置
var target_pos:Point = new Point( 20 , 20 );

// ------------------------------------------------------------
// ピクセルカラーを高速コピーする
// ------------------------------------------------------------
bmp_data.copyPixels( source , source_rect , target_pos );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.geom.Matrix;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xffc0c0ff );

// ------------------------------------------------------------
// ソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source0:BitmapData = new BitmapData( 256 , 256 , true , 0xffaa6600 );

// ------------------------------------------------------------
// アルファソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source1:BitmapData = (function():BitmapData{

	// Shape オブジェクトを作成
	var shape:Shape = new Shape();

	// Shape に矩形を描画
	var g:Graphics = shape.graphics;
	var mtx:Matrix = new Matrix(256/1638.4,0,0,1,128,0);
	g.beginGradientFill ( GradientType.LINEAR , [0x000000,0x000000] , [0.0,1.0] , [0,255] , mtx );
	g.moveTo (   0 ,   0 );
	g.lineTo (   0 , 256 );
	g.lineTo ( 256 , 256 );
	g.lineTo ( 256 ,   0 );
	g.endFill();

	// BitmapData オブジェクトを作成する（32bit）
	var bmp_data1:BitmapData = new BitmapData( 256 , 256 , true , 0x00000000 );

	// ビットマップに Shape を描画
	bmp_data1.draw(shape);

	return bmp_data1;
})();

// ------------------------------------------------------------
// コピー用パラメータ
// ------------------------------------------------------------
// ソースの矩形範囲
var source_rect:Rectangle = new Rectangle( 50 , 50 , 256 , 128 );
// ターゲットの位置
var target_pos:Point = new Point( 20 , 20 );
// アルファソースの位置
var alpha_pos:Point = new Point( 0 , 0 );

// ------------------------------------------------------------
// ピクセルカラーを高速コピーする
// ------------------------------------------------------------
bmp_data.copyPixels( source0 , source_rect , target_pos , source1 , alpha_pos , true );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xffe0e0e0 );

// ------------------------------------------------------------
// ソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source:BitmapData = new BitmapData( 256 , 256 , true , 0xffef8912 );

// ------------------------------------------------------------
// コピー用パラメータ
// ------------------------------------------------------------
// ソースの矩形範囲
var source_rect:Rectangle = new Rectangle( 50 , 50 , 256 , 128 );
// ターゲットの位置
var target_pos:Point = new Point( 20 , 20 );

// ------------------------------------------------------------
// カラーチャンネル単位で高速コピーする
// ------------------------------------------------------------
bmp_data.copyChannel( source , source_rect , target_pos , BitmapDataChannel.RED   , BitmapDataChannel.GREEN ); // 赤を緑チャンネルへ
bmp_data.copyChannel( source , source_rect , target_pos , BitmapDataChannel.GREEN , BitmapDataChannel.BLUE  ); // 緑を青チャンネルへ
bmp_data.copyChannel( source , source_rect , target_pos , BitmapDataChannel.BLUE  , BitmapDataChannel.RED   ); // 青を赤チャンネルへ

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

// 出力テスト
trace( bmp_data.getPixel(20,20).toString(16) ); // 12ef89

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.events.Event;

// ------------------------------------------------------------
// 埋め込んだ画像ファイルから、BitmapData オブジェクトを作成する (自作クラス "MyBitmapData" )
// ------------------------------------------------------------
var bmp_data:BitmapData = new MyBitmapData( 0 , 0 );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
stage.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// ビットマップをスクロールする
	bmp_data.scroll(2,1);

});

var d = (ソース色) - (ターゲット色);
var m = (引数値) / 255.0;

(新しい色) = (ターゲット色) + (d * m);

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.geom.Rectangle;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xffffb800 );

// ------------------------------------------------------------
// ソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source:BitmapData = new BitmapData( 256 , 256 , true , 0xff0047ff );

// ------------------------------------------------------------
// マージ用パラメータ
// ------------------------------------------------------------
// ソースの矩形範囲
var source_rect:Rectangle = new Rectangle( 50 , 50 , 256 , 128 );
// ターゲットの位置
var target_pos:Point = new Point( 20 , 20 );

// ------------------------------------------------------------
// イメージをマージする
// ------------------------------------------------------------
bmp_data.merge( source , source_rect , target_pos , 128 , 128 , 128 , 128 );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

// 出力テスト
trace( bmp_data.getPixel(20,20).toString(16) ); // 7f7f7f

// ------------------------------------------------------------
// パレットマップ用の配列を作成する
// ------------------------------------------------------------
var map_a:Array = new Array(); // 透過チャンネル用のパレットマップ
var map_r:Array = new Array(); // 赤チャンネル用のパレットマップ
var map_g:Array = new Array(); // 緑チャンネル用のパレットマップ
var map_b:Array = new Array(); // 青チャンネル用のパレットマップ

// ------------------------------------------------------------
// パレットマップを初期化する
// ------------------------------------------------------------
var i:uint;
for(i=0;i < 256;i++){
	map_a[i] = (i << 24);
	map_r[i] = (i << 16);
	map_g[i] = (i <<  8);
	map_b[i] = (i <<  0);
}

// ------------------------------------------------------------
// パレットマップ用の配列を作成する
// ------------------------------------------------------------
var map_a:Array = new Array(); // 透過チャンネル用のパレットマップ
var map_r:Array = new Array(); // 赤チャンネル用のパレットマップ
var map_g:Array = new Array(); // 緑チャンネル用のパレットマップ
var map_b:Array = new Array(); // 青チャンネル用のパレットマップ

// ------------------------------------------------------------
// パレットマップを初期化する
// ------------------------------------------------------------
var i:uint;
for(i=0;i < 256;i++){
	map_a[i] = ((      i) << 24);
	map_r[i] = ((256 - i) << 16);
	map_g[i] = ((256 - i) <<  8);
	map_b[i] = ((256 - i) <<  0);
}

// ------------------------------------------------------------
// パレットマップ用の配列を作成する
// ------------------------------------------------------------
var map_a:Array = new Array(); // 透過チャンネル用のパレットマップ
var map_r:Array = new Array(); // 赤チャンネル用のパレットマップ
var map_g:Array = new Array(); // 緑チャンネル用のパレットマップ
var map_b:Array = new Array(); // 青チャンネル用のパレットマップ

// ------------------------------------------------------------
// パレットマップをデフォルト値で初期化する
// ------------------------------------------------------------
var i:uint;
for(i=0;i < 256;i++){
	map_a[i] = (i << 24);
	map_r[i] = (i << 16);
	map_g[i] = (i <<  8);
	map_b[i] = (i <<  0);
}

// ------------------------------------------------------------
// 赤が 0x80 である場合、赤(+1) 緑(-2) 青(-3) を加算する
// ------------------------------------------------------------
map_r[0x80] += ((1) << 16) + ((-2) << 8) + ((-3) << 0);

// ------------------------------------------------------------
// 青が 0xc0 である場合、赤(-4) 緑(+5) 青(-6) を加算する
// ------------------------------------------------------------
map_b[0xc0] += ((-4) << 16) + ((5) << 8) + ((-6) << 0);

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.geom.Rectangle;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0x00000000 );

// ------------------------------------------------------------
// ソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source:BitmapData = new BitmapData( 256 , 256 , true , 0xffa8b8c8 );

// ------------------------------------------------------------
// パレットマップ用パラメータ
// ------------------------------------------------------------
// ソースの矩形範囲
var source_rect:Rectangle = new Rectangle( 50 , 50 , 256 , 128 );
// ターゲットの位置
var target_pos:Point = new Point( 20 , 20 );

// ------------------------------------------------------------
// デフォルトのパレットマップを用意する
// ------------------------------------------------------------
var map_a:Array = new Array();
var map_r:Array = new Array();
var map_g:Array = new Array();
var map_b:Array = new Array();

var i:uint;
for(i=0;i < 256;i++){
	map_a[i] = (i << 24);
	map_r[i] = (i << 16);
	map_g[i] = (i <<  8);
	map_b[i] = (i <<  0);
}

// ------------------------------------------------------------
// 赤が 0xa8 である場合、赤(+2) 緑(-3) 青(-5) を加算する
// ------------------------------------------------------------
map_r[0xa8] += ((2) << 16) + ((-3) << 8) + ((-5) << 0);

// ------------------------------------------------------------
// パレットマップを使って、イメージをコピーする
// ------------------------------------------------------------
bmp_data.paletteMap( source , source_rect , target_pos , map_r , map_g , map_b , map_a );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

// 出力テスト
trace( bmp_data.getPixel(20,20).toString(16) ); // aab5c3

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.geom.Matrix;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0x00000000 );

// ------------------------------------------------------------
// ソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source:BitmapData = (function():BitmapData{

	// Shape オブジェクトを作成
	var shape:Shape = new Shape();

	// Shape に矩形を描画
	var g:Graphics = shape.graphics;
	var mtx:Matrix = new Matrix( 256/1638.4 , 0 , 0 , 256/1638.4 , 128 , 128 );
	g.beginGradientFill ( GradientType.RADIAL , [0x000000,0xFFFFFF] , [1.0,1.0] , [0,255] , mtx );
	g.moveTo (   0 ,   0 );
	g.lineTo (   0 , 256 );
	g.lineTo ( 256 , 256 );
	g.lineTo ( 256 ,   0 );
	g.endFill();

	// BitmapData オブジェクトを作成する（32bit）
	var bmp_data1:BitmapData = new BitmapData( 256 , 256 , true , 0x00000000 );

	// ビットマップに Shape を描画
	bmp_data1.draw(shape);

	return bmp_data1;
})();

// ------------------------------------------------------------
// スレッショルド用パラメータ
// ------------------------------------------------------------
// ソースの矩形範囲
var source_rect:Rectangle = source.rect;
// ターゲットの位置
var target_pos:Point = new Point( 0 , 0 );
// 比較演算子
var operation:String = "<";
// しきい値
var threshold:uint = 0xFF000000 + (128 << 8);
// 塗りつぶしカラー
var color:uint = 0xFF0000FF;
// マスク値
var mask:uint = 0xFF00FF00;
// 比較結果が偽である場合、ソースからターゲットにコピー
var copy_source:Boolean = true;

// ------------------------------------------------------------
// しきい値を使って、イメージを転送する
// ------------------------------------------------------------
bmp_data.threshold( source , source_rect , target_pos , operation , threshold , color , mask , copy_source );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.ColorTransform;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0xffffb800 );

// ------------------------------------------------------------
// ColorTransform オブジェクトを作成
// ------------------------------------------------------------
var color_transform:ColorTransform = new ColorTransform();

color_transform.redMultiplier   = 0.5;
color_transform.greenMultiplier = 0.5;
color_transform.blueMultiplier  = 1.0;
color_transform.redOffset   = 0;
color_transform.greenOffset = 0;
color_transform.blueOffset  = 255;

// ------------------------------------------------------------
// カラートランスフォーム変換後の結果を描画する
// ------------------------------------------------------------
bmp_data.colorTransform( bmp_data.rect , color_transform );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

// ------------------------------------------------------------
// ソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source:BitmapData = new BitmapData( 64 , 64 , true , 0xff884400 );

// ------------------------------------------------------------
// BlurFilter オブジェクトを作成する
// ------------------------------------------------------------
var blur_filter:BlurFilter = new BlurFilter( 8 , 8 , 1 );

// ------------------------------------------------------------
// フィルタ適用後のサイズを取得する
// ------------------------------------------------------------
var filter_rect:Rectangle = source.generateFilterRect( source.rect , blur_filter );

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( filter_rect.width , filter_rect.height , true , 0x00000000 );

// ------------------------------------------------------------
// フィルタ描画用パラメータ
// ------------------------------------------------------------
// ターゲットの位置
var target_pos:Point = new Point( -filter_rect.x , -filter_rect.y );

// ------------------------------------------------------------
// フィルタ適用後の結果を描画する
// ------------------------------------------------------------
bmp_data.applyFilter( source , source.rect , target_pos , blur_filter );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

// ------------------------------------------------------------
// ソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source:BitmapData = new BitmapData( 64 , 64 , true , 0xff884400 );

// ------------------------------------------------------------
// BlurFilter オブジェクトを作成する
// ------------------------------------------------------------
var blur_filter:BlurFilter = new BlurFilter( 8 , 8 , 1 );

// ------------------------------------------------------------
// フィルタ適用後のサイズを取得する
// ------------------------------------------------------------
var filter_rect:Rectangle = source.generateFilterRect( source.rect , blur_filter );

// 出力テスト
trace( source.rect ); // x: 0, y: 0, w:64, h:64
trace( filter_rect ); // x:-4, y:-4, w:72, h:72

import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.display.Bitmap;
import flash.events.Event;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 512 , 512 , true , 0x00000000 );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
stage.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// ------------------------------------------------------------
	// ランダムノイズ描画用パラメータ
	// ------------------------------------------------------------
	// 乱数の種
	var random_seed:int = Math.floor(Math.random() * 0x7FFFFFFF);
	// カラー成分の最小値
	var color_low:uint  = 0;
	// カラー成分の最大値
	var color_high:uint = 255;
	// 使用するカラーチャンネル
	var channel_options:uint = (BitmapDataChannel.ALPHA | BitmapDataChannel.RED | BitmapDataChannel.GREEN | BitmapDataChannel.BLUE );
	// グレースケール化
	var gray_scale:Boolean = false;

	// ------------------------------------------------------------
	// イメージにランダムノイズを描画する
	// ------------------------------------------------------------
	bmp_data.noise( random_seed , color_low , color_high , channel_options , gray_scale );

});

import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.display.Bitmap;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new flash.display.BitmapData( 512 , 512 , true , 0x00000000 );

// ------------------------------------------------------------
// パーリンノイズ描画用パラメータ
// ------------------------------------------------------------
// 水平方向の周波数
var base_x:Number = 64;
// 垂直方向の周波数
var base_y:Number = 64;
// オクターブの個数
var num_octaves:uint = 1;
// 乱数の種
var random_seed:int = Math.floor(Math.random() * 0x7FFFFFFF);
// タイリング化
var stitch:Boolean = false;
// フラクタルノイズを使用
var fractal_noise:Boolean = false;
// 使用するカラーチャンネル
var channel_options:uint = (BitmapDataChannel.RED | BitmapDataChannel.GREEN | BitmapDataChannel.BLUE );
// グレースケール化
var gray_scale:Boolean = false;

// ------------------------------------------------------------
// イメージにパーリンノイズを描画する
// ------------------------------------------------------------
bmp_data.perlinNoise( base_x , base_y , num_octaves , random_seed , stitch , fractal_noise ,channel_options , gray_scale );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.events.Event;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 256 , 256 , true , 0x00000000 );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

// ------------------------------------------------------------
// パーリンノイズ描画用パラメータ
// ------------------------------------------------------------
// 水平方向の周波数
var base_x:Number = 128;
// 垂直方向の周波数
var base_y:Number = 128;
// オクターブの個数
var num_octaves:uint = 3;
// 乱数の種
var random_seed:int = Math.floor(Math.random() * 0x7FFFFFFF);
// タイリング化
var stitch:Boolean = false;
// フラクタルノイズを使用
var fractal_noise:Boolean = false;
// 使用するカラーチャンネル
var channel_options:uint = (0);
// グレースケール化
var gray_scale:Boolean = true;
// オフセットリスト
var offset_list:Array = new Array();
// 速度リスト
var speed_list:Array = new Array();

// ------------------------------------------------------------
// オフセットリストを初期化
// ------------------------------------------------------------
var speed:Number = Math.random() * 0.5 + 2;
var rotate:Number = Math.PI * 2.0 * Math.random();
var i:int;
for(i=0;i < num_octaves;i++){

	// 位置ベクトル
	var pos:Point = new Point( 0 , 0 );

	// 速度ベクトル
	var r:Number = (30 * (Math.random() * 2 - 1) + rotate) * Math.PI / 180;
	var s:Number = (0.25) * (Math.random() * 2 - 1) + speed;
	var spd:Point = new Point( Math.cos(r) * s , Math.sin(r) * s );
	speed *= 0.75;

	offset_list[i] = pos;
	speed_list[i] = spd;
}

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
stage.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// ------------------------------------------------------------
	// オフセットを加算
	// ------------------------------------------------------------
	var i:int;
	for(i=0;i < num_octaves;i++){
		var pos:Point = offset_list[i];
		var spd:Point = speed_list[i];
		pos.x += spd.x;
		pos.y += spd.y;
	}

	// ------------------------------------------------------------
	// イメージにパーリンノイズを描画する
	// ------------------------------------------------------------
	bmp_data.perlinNoise( base_x , base_y , num_octaves , random_seed , stitch , fractal_noise ,channel_options , gray_scale , offset_list );

});

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Rectangle;
import flash.geom.Point;

// ------------------------------------------------------------
// ターゲット用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var bmp_data:BitmapData = new BitmapData( 256 , 256 , true , 0xffffc0c0 );

// ------------------------------------------------------------
// ソース用 BitmapData オブジェクトを作成する（32bit）
// ------------------------------------------------------------
var source:BitmapData = new BitmapData( 256 , 256 , true , 0xff0000ff );

// ------------------------------------------------------------
// ステージに配置する
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new Bitmap(bmp_data);
stage.addChild( bitmap_obj );

// ------------------------------------------------------------
// ピクセルディゾルブ用パラメータ
// ------------------------------------------------------------
// ソースの矩形範囲
var source_rect:Rectangle = source.rect;
// ターゲットの位置
var target_pos:Point = new Point( 0 , 0 );
// 乱数の種
var random_seed:Number = Math.floor(Math.random() * 0x7FFFFFFF);

// ------------------------------------------------------------
// ピクセル数を計算
// ------------------------------------------------------------
// 総ピクセル数
var total:int = (source_rect.width * source_rect.height);

// 残りのピクセル数
var remnant:int = total;

// １回の処理で置換するピクセル数（ここでは 120 フレーム分）
var number_of_pixels:int = Math.ceil(total / 120);

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
stage.addEventListener(Event.ENTER_FRAME , function callee(e:Event):void{

	// ------------------------------------------------------------
	// イメージをピクセルディゾルブで置換する
	// ------------------------------------------------------------
	random_seed = bmp_data.pixelDissolve( source , source_rect , target_pos , random_seed , number_of_pixels );

	// ------------------------------------------------------------
	// 終了チェック
	// ------------------------------------------------------------
	remnant -= number_of_pixels;
	if(remnant <= 0){
		e.currentTarget.removeEventListener(e.type , callee);
	}

});