DisplayObject クラスについて

// 座標を変更する
mc.x = 100;
mc.y = 200;

import flash.display.Sprite;
import flash.display.Graphics;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawRect (-20,-20,40,40);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 200;

import flash.display.Sprite;
import flash.display.Graphics;
import flash.events.Event;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawRect (-20,-20,40,40);

// スプライトの初期位置をセット
sprite.x = 50;
sprite.y = 50;

// 毎フレーム実行されるイベント
sprite.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// スプライトの座標を加算
	sprite.x += 1;
	sprite.y += 1;

});

mc.rotation = 50;

import flash.display.Sprite;
import flash.display.Graphics;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawRect (-20,-20,40,40);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;

// スプライトの角度を変更する
sprite.rotation = 50;

import flash.display.Sprite;
import flash.display.Graphics;
import flash.events.Event;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawRect (-20,-20,40,40);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;

// スプライトの初期角度をセット
sprite.rotation = 15;

// 毎フレーム実行されるイベント
sprite.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// スプライトの角度を加算
	sprite.rotation += 1;

});

mc.scaleX = 0.8;
mc.scaleY = 1.2;

import flash.display.Sprite;
import flash.display.Graphics;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawRect (-20,-20,40,40);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;

// スプライトの拡大率を変更する
sprite.scaleX = 0.8;
sprite.scaleY = 1.2;

mc.width = 50;
mc.height = 150;

import flash.display.Sprite;
import flash.display.Graphics;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawRect (-20,-20,40,40);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;

// スプライトの幅と高さを設定する
sprite.width = 50;
sprite.height = 150;

import flash.display.Sprite;
import flash.display.Graphics;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawRect (-20,-20,80,40);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;

// スプライトの角度を変更する
sprite.rotation = 15;

// ------------------------------------------------------------
// 幅と高さを設定する
// ------------------------------------------------------------
// 角度を変数に残す
var r:Number = sprite.rotation;

// 角度を 0 に設定する
sprite.rotation = 0;

// 幅と高さを設定する
sprite.width = 50;
sprite.height = 150;

// 角度を戻す
sprite.rotation = r;

mc.scaleX = -1.0;

mc.scaleY = -1.0;

import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Matrix;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginGradientFill ( GradientType.LINEAR , [0xFF4444,0xFFCCCC] , [1.0,1.0] , [0,255] , new Matrix(100/1638.4,0,0,1,-50,-50));
g.drawRect (-50,-50,100,100);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;

// スプライトを水平方向に反転させる
sprite.scaleX = -1.0;

mc.width = 100;
mc.scaleX *= -1;

mc.alpha = 0.5;

import flash.display.Sprite;
import flash.display.Graphics;
import flash.events.Event;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawRect (-20,-20,40,40);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;

// スプライトの初期透明度をセット
sprite.alpha = 1.0;

// 毎フレーム実行されるイベント
sprite.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// スプライトの透明度を 0 に近づける
	sprite.alpha *= 0.98;

});

mc.visible = false;

mc.visible = true;

mc.mask = source;

import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Matrix;

var g:Graphics;

// ------------------------------------------------------------
// スプライトＡ
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite_a:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite_a);

// 矩形を描画
g = sprite_a.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginGradientFill ( GradientType.LINEAR , [0xFF4444,0xFFCCCC] , [1.0,1.0] , [0,255] , new Matrix(200/1638.4,0,0,1,0,0));
g.drawRect (0,0,200,200);


// ------------------------------------------------------------
// スプライトＢ
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite_b:Sprite = new Sprite();

// ステージに配置
//stage.addChild(sprite_b);

// 円を描画
g = sprite_b.graphics;
g.beginFill (0x000000, 1.0);
g.drawCircle (0,0,50);

// スプライトの座標を変更する
sprite_b.x = 100;
sprite_b.y = 100;


// ------------------------------------------------------------
// マスクの設定
// ------------------------------------------------------------
// スプライトＡに、スプライトＢの形状でマスクをかける
sprite_a.mask = sprite_b;

import flash.display.Sprite;

// ------------------------------------------------------------
// スプライトＡ
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite_a:Sprite = new Sprite();

// "my_sprite_a" というインスタンス名を付ける
sprite_a.name = "my_sprite_a";

// ステージに配置
stage.addChild(sprite_a);


// ------------------------------------------------------------
// スプライトＢ
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite_b:Sprite = new Sprite();

// "my_sprite_b" というインスタンス名を付ける
sprite_b.name = "my_sprite_b";

// ステージに配置
stage.addChild(sprite_b);


// ------------------------------------------------------------
// インスタンス名から表示オブジェクトを取得
// ------------------------------------------------------------
// インスタンス名を指定して表示オブジェクトを取得する
var a:Sprite = stage.getChildByName("my_sprite_a");
var b:Sprite = stage.getChildByName("my_sprite_b");

// トレーステスト
trace(a.name);
trace(b.name);

mc.cacheAsBitmap = true

mc.opaqueBackground = 0xFF0000;

import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Matrix;

// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 円を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawCircle (0,0,50);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;

// スプライトの抜き部分に色を付ける
sprite.opaqueBackground = 0x0000FF;

import flash.display.BlendMode;

mc.blendMode = BlendMode.ADD;

import flash.display.BlendMode;

mc.blendMode = BlendMode.SUBTRACT;

import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Matrix;
import flash.filters.BlurFilter;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 円を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawCircle (0,0,50);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;


// ------------------------------------------------------------
// フィルタ
// ------------------------------------------------------------
// ブラーフィルタオブジェクトを作成
var blur_filter:BlurFilter = new BlurFilter();


// ------------------------------------------------------------
// フィルタを適用
// ------------------------------------------------------------
// スプライトに、フィルタを適用
sprite.filters = [blur_filter];

import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Matrix;
import flash.filters.BlurFilter;
import flash.filters.DropShadowFilter;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 円を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawCircle (0,0,50);

// スプライトの座標を変更する
sprite.x = 100;
sprite.y = 100;


// ------------------------------------------------------------
// フィルタ
// ------------------------------------------------------------
// ブラーフィルタオブジェクトを作成
var blur_filter:BlurFilter = new BlurFilter();

// ドロップシャドウフィルタオブジェクトを作成
var drop_filter:DropShadowFilter = new DropShadowFilter();


// ------------------------------------------------------------
// フィルタを適用
// ------------------------------------------------------------
// スプライトに、フィルタを適用
sprite.filters = [blur_filter,drop_filter];

import flash.geom.ColorTransform;

// カラートランスフォームオブジェクトを作成する
var color_transform : ColorTransform = new ColorTransform();

import flash.geom.ColorTransform;

// カラートランスフォームオブジェクトを作成する
var color_transform : ColorTransform = new ColorTransform();

// RGB カラーを設定する
color_transform.color = 0xFF8822;

import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Matrix;
import flash.geom.ColorTransform;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginGradientFill ( GradientType.LINEAR , [0xFFCCCC,0xCCCCFF] , [1.0,1.0] , [0,255] , new Matrix(300/1638.4,0,0,1,0,0));
g.drawRect (0,0,300,300);


// ------------------------------------------------------------
// カラートランスフォーム
// ------------------------------------------------------------
// カラートランスフォームオブジェクトを作成する
var color_transform : ColorTransform = new ColorTransform();

// RGB カラーを設定する
color_transform.color = 0xFF8822;


// ------------------------------------------------------------
// カラーを適用
// ------------------------------------------------------------
// スプライトに、カラートランスフォームオブジェクトを渡す
sprite.transform.colorTransform = color_transform;

import flash.geom.ColorTransform;

// カラートランスフォームオブジェクトを作成する
var color_transform : ColorTransform = new ColorTransform();

新しい赤色   = (元の赤色   * redMultiplier)   + redOffset;
新しい緑色   = (元の緑色   * greenMultiplier) + greenOffset;
新しい青色   = (元の青色   * blueMultiplier)  + blueOffset;
新しい透過色 = (元の透過色 * alphaMultiplier) + alphaOffset;

import flash.geom.ColorTransform;

// RGB カラー(0xFFFFFF)を指定
var color_rgb:uint = 0xFF8800;

// 濃淡 (0.0 ～ 1.0)
var shade:Number = 0.5;

// カラートランスフォームオブジェクトを作成
var color_transform : ColorTransform = new ColorTransform();

color_transform.redMultiplier   = 1.0 - shade;
color_transform.greenMultiplier = 1.0 - shade;
color_transform.blueMultiplier  = 1.0 - shade;
color_transform.redOffset   = ((color_rgb >> 16) & 0xFF) * shade;
color_transform.greenOffset = ((color_rgb >>  8) & 0xFF) * shade;
color_transform.blueOffset  = ((color_rgb >>  0) & 0xFF) * shade;

import flash.geom.ColorTransform;

// 明度 (-1.0 ～ 1.0)
var lightness:Number = 0.5;

// カラートランスフォームオブジェクトを作成
var color_transform : ColorTransform = new ColorTransform();

if(lightness < 0){
	color_transform.redMultiplier   = 1.0 + lightness;
	color_transform.greenMultiplier = 1.0 + lightness;
	color_transform.blueMultiplier  = 1.0 + lightness;
	color_transform.redOffset   = 0;
	color_transform.greenOffset = 0;
	color_transform.blueOffset  = 0;
}else{
	color_transform.redMultiplier   = 1.0 - lightness;
	color_transform.greenMultiplier = 1.0 - lightness;
	color_transform.blueMultiplier  = 1.0 - lightness;
	color_transform.redOffset   = 255 * lightness;
	color_transform.greenOffset = 255 * lightness;
	color_transform.blueOffset  = 255 * lightness;
}

import flash.geom.ColorTransform;

// カラートランスフォームオブジェクトを作成
var color_transform : ColorTransform = new ColorTransform(-1.0,-1.0,-1.0,1.0,255,255,255,0);

import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Matrix;
import flash.geom.ColorTransform;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginGradientFill ( GradientType.LINEAR , [0xFFCCCC,0xCCCCFF] , [1.0,1.0] , [0,255] , new Matrix(300/1638.4,0,0,1,0,0));
g.drawRect (0,0,300,300);


// ------------------------------------------------------------
// カラートランスフォーム
// ------------------------------------------------------------
// カラートランスフォームオブジェクトを作成する
var color_transform : ColorTransform = new ColorTransform();

// カラートランスフォームを設定する
color_transform.redMultiplier = 0.5;
color_transform.greenMultiplier = 1.0;
color_transform.blueMultiplier = 0.5;
color_transform.alphaMultiplier = 1.0;
color_transform.redOffset = 0;
color_transform.greenOffset = 0;
color_transform.blueOffset = 0;
color_transform.alphaOffset = 0;


// ------------------------------------------------------------
// カラーを適用
// ------------------------------------------------------------
// スプライトに、カラートランスフォームオブジェクトを渡す
sprite.transform.colorTransform = color_transform;

import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.geom.Matrix;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// ステージに配置
stage.addChild(sprite);

// 矩形を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginGradientFill ( GradientType.LINEAR , [0xFF4444,0xFFCCCC] , [1.0,1.0] , [0,255] , new Matrix(100/1638.4,0,0,1,-50,-50));
g.drawRect (-50,-50,100,100);


// ------------------------------------------------------------
// マトリックスオブジェクトを用意
// ------------------------------------------------------------
// マトリックスオブジェクトを作成する
var mtx : Matrix = new Matrix();

// 単位行列化
mtx.identity();
// スケーリング行列を乗算
mtx.scale(0.8,1.2);
// 回転行列を乗算
mtx.rotate(Math.PI / 180 * 30);
// 平行移動行列を乗算
mtx.translate(100,100);


// ------------------------------------------------------------
// マトリックスオブジェクトを適用
// ------------------------------------------------------------
// スプライトに、マトリックスオブジェクトを渡す
sprite.transform.matrix = mtx;

import flash.display.MovieClip;
import flash.events.Event;

// ムービークリップオブジェクトを作成
var mc0:MovieClip = new MovieClip();
var mc1:MovieClip = new MovieClip();
var mc2:MovieClip = new MovieClip();
var mc3:MovieClip = new MovieClip();
var mc4:MovieClip = new MovieClip();

// ムービークリップに名前をつける
mc0.name = "mc0";
mc1.name = "mc1";
mc2.name = "mc2";
mc3.name = "mc3";
mc4.name = "mc4";

// 表示リストに登録 (stage-mc0-mc1-mc2-mc3-mc4)
stage.addChild(mc0);
mc0.addChild(mc1);
mc1.addChild(mc2);
mc2.addChild(mc3);
mc3.addChild(mc4);

// 表示オブジェクトが、ステージから消えた瞬間に実行されるイベント
function RemovedFromStageFunc(e:Event):void{
	var current:MovieClip = e.currentTarget as MovieClip;

	trace("ステージから消えた表示オブジェクト:" + current.name);
}

// 関数を登録
mc0.addEventListener(Event.REMOVED_FROM_STAGE,RemovedFromStageFunc);
mc1.addEventListener(Event.REMOVED_FROM_STAGE,RemovedFromStageFunc);
mc2.addEventListener(Event.REMOVED_FROM_STAGE,RemovedFromStageFunc);
mc3.addEventListener(Event.REMOVED_FROM_STAGE,RemovedFromStageFunc);
mc4.addEventListener(Event.REMOVED_FROM_STAGE,RemovedFromStageFunc);

// mc1 から　mc2 を外す
mc1.removeChild(mc2);

import flash.display.MovieClip;
import flash.events.Event;

// ムービークリップオブジェクトを作成
var mc0:MovieClip = new MovieClip();
var mc1:MovieClip = new MovieClip();
var mc2:MovieClip = new MovieClip();
var mc3:MovieClip = new MovieClip();
var mc4:MovieClip = new MovieClip();

// ムービークリップに名前をつける
mc0.name = "mc0";
mc1.name = "mc1";
mc2.name = "mc2";
mc3.name = "mc3";
mc4.name = "mc4";

// 表示リストに登録 (stage-mc0-mc1-mc2-mc3-mc4)
stage.addChild(mc0);
mc0.addChild(mc1);
mc1.addChild(mc2);
mc2.addChild(mc3);
mc3.addChild(mc4);

//「自身の表示オブジェクト」か「自身の子である表示オブジェクト」が、表示リストから外れた瞬間に実行される関数
function RemovedFunc(e:Event):void{
	var current:MovieClip = e.currentTarget as MovieClip;
	var target:MovieClip = e.target as MovieClip;
	
	trace("表示リストが外れた ---");
	trace("　イベントが発生した表示オブジェクト:" + current.name);
	trace("　表示リストから外れた表示オブジェクト:" + target.name);
}

// 関数を登録
mc0.addEventListener(Event.REMOVED,RemovedFunc);
mc1.addEventListener(Event.REMOVED,RemovedFunc);
mc2.addEventListener(Event.REMOVED,RemovedFunc);
mc3.addEventListener(Event.REMOVED,RemovedFunc);
mc4.addEventListener(Event.REMOVED,RemovedFunc);

// mc2 から　mc3 を外す
mc2.removeChild(mc3);

import flash.display.Sprite;
import flash.geom.Point;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトを生成
var sprite:Sprite = new Sprite();

// 適当に姿勢を変更
sprite.x = 40;
sprite.y = 90;
sprite.rotation = -30;

// ステージに配置
stage.addChild(sprite);


// ------------------------------------------------------------
// 座標変換
// ------------------------------------------------------------
// ローカル座標を用意
var pos_local : Point = new Point(10,20);

// スプライトのローカル座標からグローバル座標に変換
var pos_global : Point = sprite.localToGlobal(pos_local);

// 出力テスト
trace("x : " + pos_global.x + " y : " + pos_global.y);

import flash.display.Sprite;
import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトを生成
var sprite:Sprite = new Sprite();

// 適当に姿勢を変更
sprite.x = 40;
sprite.y = 90;
sprite.rotation = -30;

// ステージに配置
stage.addChild(sprite);


// ------------------------------------------------------------
// 座標変換
// ------------------------------------------------------------
// ローカル座標を用意
var pos_local : Point = new Point(10,20);

// ローカルベクトルを用意
var vec_local : Point = new Point(1,0);

// スプライトのグローバル行列を取得
var mtx_global : Matrix = sprite.transform.concatenatedMatrix;

// スプライト上のローカル座標をグローバル座標に変換
var pos_global : Point = mtx_global.transformPoint(pos_local);

// スプライト上のローカルベクトルをグローバルベクトルに変換
var vec_global : Point = mtx_global.deltaTransformPoint(vec_local);

// 出力テスト
trace("pos x:" + pos_global.x + " y:" + pos_global.y);
trace("vec x:" + vec_global.x + " y:" + vec_global.y);

import flash.display.Sprite;
import flash.geom.Point;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトを生成
var sprite:Sprite = new Sprite();

// 適当に姿勢を変更
sprite.x = 40;
sprite.y = 90;
sprite.rotation = -30;

// ステージに配置
stage.addChild(sprite);


// ------------------------------------------------------------
// 座標変換
// ------------------------------------------------------------
// グローバル座標を用意
var pos_global : Point = new Point(10,20);

// ステージ上のグローバル座標からスプライト上のローカル座標に変換
var pos_local : Point = sprite.globalToLocal(pos_global);

// 出力テスト
trace("x : " + pos_local.x + " y : " + pos_local.y);

import flash.display.Sprite;
import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトを生成
var sprite:Sprite = new Sprite();

// 適当に姿勢を変更
sprite.x = 40;
sprite.y = 90;
sprite.rotation = -30;

// ステージに配置
stage.addChild(sprite);


// ------------------------------------------------------------
// 座標変換
// ------------------------------------------------------------
// グローバル座標を用意
var pos_global : Point = new Point(10,20);

// グローバルベクトルを用意
var vec_global : Point = new Point(1,0);

// スプライトのグローバル行列を取得
var mtx : Matrix = sprite.transform.concatenatedMatrix;

// グローバル行列を逆行列に変換する
mtx.invert();

// グローバル座標をスプライト上のローカル座標に変換
var pos_local : Point = mtx.transformPoint(pos_global);

// グローバルベクトルをスプライト上のローカルベクトルに変換
var vec_local : Point = mtx.deltaTransformPoint(vec_global);

// 出力テスト
trace("pos x:" + pos_local.x + " y:" + pos_local.y);
trace("vec x:" + vec_local.x + " y:" + vec_local.y);

import flash.display.Sprite;
import flash.display.Graphics;
import flash.events.MouseEvent;

// ------------------------------------------------------------
// スプライト
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite:Sprite = new Sprite();

// スプライトの設定
sprite.x = 200;
sprite.y = 200;

// 円を描画
var g:Graphics = sprite.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawCircle (0,0,50);

// ステージの表示リストの最後尾に登録する
stage.addChild(sprite);


// ------------------------------------------------------------
// マウスカーソルが移動したときに呼び出されるイベント
// ------------------------------------------------------------
stage.addEventListener(MouseEvent.MOUSE_MOVE, function (e:MouseEvent):void{

	// スプライトとマウスカーソルの座標とで当たり判定を調べる
	var check:Boolean = sprite.hitTestPoint(stage.mouseX,stage.mouseY,true);

	if(check){
		trace("当たりあり");
	}else{
		trace("当たりなし");
	}

});

import flash.display.Sprite;
import flash.display.Graphics;
import flash.events.MouseEvent;

var g:Graphics;

// ------------------------------------------------------------
// スプライトＡ
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite_a:Sprite = new Sprite();

// スプライトの設定
sprite_a.x = 200;
sprite_a.y = 200;

// 円を描画
g = sprite_a.graphics;
g.lineStyle (5, 0xAA0000, 1.0);
g.beginFill (0xFF4444, 1.0);
g.drawCircle (0,0,50);

// ステージの表示リストの最後尾に登録する
stage.addChild(sprite_a);


// ------------------------------------------------------------
// スプライトＢ
// ------------------------------------------------------------
// スプライトオブジェクトを作成
var sprite_b:Sprite = new Sprite();

// 矩形を描画
g = sprite_b.graphics;
g.lineStyle (5, 0x0000AA, 1.0);
g.beginFill (0x4444FF, 1.0);
g.drawRect (-50,-50,100,100);

// ステージの表示リストの最後尾に登録する
stage.addChild(sprite_b);


// ------------------------------------------------------------
// マウスカーソルが移動したときに呼び出されるイベント
// ------------------------------------------------------------
stage.addEventListener(MouseEvent.MOUSE_MOVE, function (e:MouseEvent):void{

	// スプライトＢを移動
	sprite_b.x = stage.mouseX;
	sprite_b.y = stage.mouseY;

	// スプライトＡとスプライトＢとの当たり判定を調べる
	var check:Boolean = sprite_a.hitTestObject(sprite_b);

	if(check){
		trace("当たりあり");
	}else{
		trace("当たりなし");
	}

});