Graphics クラスについて

import flash.display.Sprite;
import flash.display.Graphics;

// ------------------------------------------------------------
// Sprite オブジェクトを作成
// ------------------------------------------------------------
var sprite:Sprite = new Sprite();

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var graphics:Graphics = sprite.graphics;

// 出力テスト
trace(graphics);

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// 出力テスト
trace(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var graphics:Graphics = shape.graphics;

// 出力テスト
trace(graphics);

// ------------------------------------------------------------
// ステージに配置
// ------------------------------------------------------------
stage.addChild(shape);

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GraphicsPathCommand;
import flash.display.GraphicsPathWinding;
import flash.geom.Point;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// 描画パスのコマンドと座標データ
// ------------------------------------------------------------
// コマンドリスト
var command_list:Vector.<int> = new Vector.<int>();

// 座標データリスト
var data_list:Vector.<Number> = new Vector.<Number>();

// 描画パスを開始する
command_list.push(GraphicsPathCommand.MOVE_TO);
data_list.push(219.9); // x
data_list.push(123.5); // y

// 描画パスを指定して囲む
command_list.push(GraphicsPathCommand.LINE_TO);
data_list.push(147.5); // x
data_list.push(216.1); // y

command_list.push(GraphicsPathCommand.LINE_TO);
data_list.push( 37.1); // x
data_list.push(175.9); // y

command_list.push(GraphicsPathCommand.LINE_TO);
data_list.push( 41.2); // x
data_list.push( 58.4); // y

command_list.push(GraphicsPathCommand.LINE_TO);
data_list.push(154.2); // x
data_list.push( 26.0); // y

command_list.push(GraphicsPathCommand.LINE_TO);
data_list.push(219.9); // x
data_list.push(123.5); // y

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 描画パスをまとめて高速描画する
// ------------------------------------------------------------
g.drawPath (command_list , data_list , GraphicsPathWinding.EVEN_ODD);

// 描画パスを閉じて、塗りつぶしを確定する
g.endFill ();

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GraphicsPath;
import flash.display.GraphicsPathWinding;
import flash.geom.Point;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// 描画パスのコマンドと座標データ
// ------------------------------------------------------------
// GraphicsPath オブジェクトを作成する
var graphics_path:GraphicsPath = new GraphicsPath();

// 描画パスを開始する
graphics_path.moveTo(219.9 , 123.5);

// 描画パスを指定して囲む
graphics_path.lineTo(147.5 , 216.1);
graphics_path.lineTo( 37.1 , 175.9);
graphics_path.lineTo( 41.2 ,  58.4);
graphics_path.lineTo(154.2 ,  26.0);
graphics_path.lineTo(219.9 , 123.5);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 描画パスをまとめて高速描画する
// ------------------------------------------------------------
g.drawPath (graphics_path.commands , graphics_path.data , GraphicsPathWinding.EVEN_ODD);

// 描画パスを閉じて、塗りつぶしを確定する
g.endFill ();

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape_a:Shape = new Shape();
var shape_b:Shape = new Shape();

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var graphics_a:Graphics = shape_a.graphics;
var graphics_b:Graphics = shape_b.graphics;

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
graphics_a.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
graphics_a.beginFill (0x808080 , 1.0);
// 矩形を描画する
graphics_a.drawRect ( 0.0 , 0.0 , 100.0 , 100.0 );

// ------------------------------------------------------------
// グラフィックをコピーする
// ------------------------------------------------------------
graphics_b.copyFrom(graphics_a);

// ------------------------------------------------------------
// ステージに配置
// ------------------------------------------------------------
stage.addChild(shape_a);
stage.addChild(shape_b);
shape_a.x =  20;
shape_a.y =  20;
shape_b.x = 200;
shape_b.y =  20;

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineStyle(10 , 0x000000 , 1.0);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
g.moveTo (  10.0 ,  10.0 );
// 終了位置
g.lineTo ( 100.0 ,  50.0 );

// ------------------------------------------------------------
// 描画済みグラフィックをすべてクリアする
// ------------------------------------------------------------
g.clear();

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineStyle (10 , 0x000000 , 1.0);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
g.moveTo (  10.0 ,  10.0 );
// 直線を描画
g.lineTo ( 100.0 ,  50.0 );

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.LineScaleMode;
import flash.display.CapsStyle;
import flash.display.JointStyle;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 線の単一色塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 20;
// 線の色 (RGBカラー値)
var line_color:uint = 0x000000;
// 線の透明度 (0.0 ～ 1.0)
var line_alpha:Number = 1.0;
// ヒンティングの有無
var pixel_hinting:Boolean = true;
// スケールモード
var scale_mode:String = LineScaleMode.NORMAL;
// 線先の種類
var caps_style:String = CapsStyle.SQUARE;
// 角の種類
var joints_style:String = JointStyle.MITER;
// マイターの尖りの延長サイズ (1.0 ～)
var miter_limit:Number = 255;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineStyle ( thickness , line_color , line_alpha , pixel_hinting , scale_mode , caps_style , joints_style , miter_limit );

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
g.moveTo (  20.0 ,  20.0 );
// 直線を描画
g.lineTo ( 200.0 , 100.0 );
// 直線を描画
g.lineTo (  20.0 , 100.0 );

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 線のグラデーション塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 30;
// グラデーションの種類
var gradient_type:String = GradientType.RADIAL;
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [      1.0 ,      1.0 ,      1.0 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = SpreadMethod.PAD;
// 補間の種類
var interpolation_method:String = InterpolationMethod.LINEAR_RGB;
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// グラデーションの行列
// ------------------------------------------------------------
// 単位行列化
gradient_mtx.identity();
// 拡大縮小成分を乗算
gradient_mtx.scale( 256/1638.4 , 256/1638.4 );
// 角度成分を乗算
gradient_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
gradient_mtx.translate( 128.0 , 128.0 );

// ------------------------------------------------------------
// 線の基礎的なスタイルを指定する
// ------------------------------------------------------------
g.lineStyle( thickness );

// ------------------------------------------------------------
// 線に「グラデーション塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineGradientStyle( gradient_type , gradient_colors , gradient_alphas , gradient_ratios , gradient_mtx , spread_method , interpolation_method , focal_point_ratio );

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
var i:int = 0;
for(i=0;i < 8;i++){

	var pos_y:Number = i * 32.0 + 16.0;

	// 開始位置
	g.moveTo (   0.0 , pos_y );
	// 直線を描画
	g.lineTo ( 256.0 , pos_y );
}

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// ２つの座標
// ------------------------------------------------------------
var pos_a:Point = new Point( stage.stageWidth/2 , stage.stageHeight/2 );
var pos_b:Point = new Point( 0 , 0 );

// ------------------------------------------------------------
// 線のグラデーション塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 100;
// グラデーションの種類
var gradient_type:String = GradientType.LINEAR;
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [      0.0 ,      1.0 ,      0.0 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = SpreadMethod.PAD;
// 補間の種類
var interpolation_method:String = InterpolationMethod.LINEAR_RGB;
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
stage.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// ------------------------------------------------------------
	// 座標Ｂにマウス座標をセット
	// ------------------------------------------------------------
	pos_b.x = stage.mouseX;
	pos_b.y = stage.mouseY;

	// ------------------------------------------------------------
	// グラデーションの行列
	// ------------------------------------------------------------
	// 差分ベクトル
	var vec:Point = pos_b.subtract(pos_a);
	// 法線ベクトルの角度
	var rad:Number = Math.atan2(vec.y , vec.x) + Math.PI * 0.5;

	// 単位行列化
	gradient_mtx.identity();
	// 拡大縮小成分を乗算
	gradient_mtx.scale(thickness/1638.4 , 1.0);
	// 角度成分を乗算
	gradient_mtx.rotate(rad);
	// 移動成分を乗算
	gradient_mtx.translate(pos_a.x , pos_a.y);

	// ------------------------------------------------------------
	// 描画済みグラフィックをすべてクリアする
	// ------------------------------------------------------------
	g.clear();

	// ------------------------------------------------------------
	// 線の基礎的なスタイルを指定する
	// ------------------------------------------------------------
	g.lineStyle( thickness );

	// ------------------------------------------------------------
	// 線に「グラデーション塗り」スタイルを指定する
	// ------------------------------------------------------------
	g.lineGradientStyle(
		gradient_type,
		gradient_colors,
		gradient_alphas,
		gradient_ratios,
		gradient_mtx,
		spread_method,
		interpolation_method,
		focal_point_ratio
	);

	// ------------------------------------------------------------
	// 直線を描画する
	// ------------------------------------------------------------
	// 開始位置
	g.moveTo ( pos_a.x , pos_a.y );
	// 直線を描画
	g.lineTo ( pos_b.x , pos_b.y );

});

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// ２つの座標
// ------------------------------------------------------------
var pos_a:Point = new Point( stage.stageWidth/2 , stage.stageHeight/2 );
var pos_b:Point = new Point( 0 , 0 );

// ------------------------------------------------------------
// 線のグラデーション塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 100;
// グラデーションの種類
var gradient_type:String = GradientType.LINEAR;
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [      1.0 ,      1.0 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = SpreadMethod.PAD;
// 補間の種類
var interpolation_method:String = InterpolationMethod.RGB;
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
stage.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// ------------------------------------------------------------
	// 座標Ｂにマウス座標をセット
	// ------------------------------------------------------------
	pos_b.x = stage.mouseX;
	pos_b.y = stage.mouseY;

	// ------------------------------------------------------------
	// グラデーションの行列
	// ------------------------------------------------------------
	// 差分ベクトル
	var vec:Point = pos_b.subtract(pos_a);
	// 中間座標
	var pos:Point = Point.interpolate(pos_a , pos_b , 0.5);
	// ベクトルの角度
	var rad:Number = Math.atan2(vec.y , vec.x);
	// ベクトルの長さ
	var len:Number = vec.length;

	// 単位行列化
	gradient_mtx.identity();
	// 拡大縮小成分を乗算
	gradient_mtx.scale(len/1638.4 , 1.0);
	// 角度成分を乗算
	gradient_mtx.rotate(rad);
	// 移動成分を乗算
	gradient_mtx.translate(pos.x , pos.y);

	// ------------------------------------------------------------
	// 描画済みグラフィックをすべてクリアする
	// ------------------------------------------------------------
	g.clear();

	// ------------------------------------------------------------
	// 線の基礎的なスタイルを指定する
	// ------------------------------------------------------------
	g.lineStyle( thickness );

	// ------------------------------------------------------------
	// 線に「グラデーション塗り」スタイルを指定する
	// ------------------------------------------------------------
	g.lineGradientStyle(
		gradient_type,
		gradient_colors,
		gradient_alphas,
		gradient_ratios,
		gradient_mtx,
		spread_method,
		interpolation_method,
		focal_point_ratio
	);

	// ------------------------------------------------------------
	// 直線を描画する
	// ------------------------------------------------------------
	// 開始位置
	g.moveTo ( pos_a.x , pos_a.y );
	// 直線を描画
	g.lineTo ( pos_b.x , pos_b.y );

});

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 埋め込みアセットクラス
// ------------------------------------------------------------
[Embed( source="./texture.png" )]
var MyBitmap:Class;

// ------------------------------------------------------------
// 埋め込んだ画像ファイルから、BitmapData オブジェクトを作成する (自作クラス "MyBitmap" )
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new MyBitmap();
var bitmap_data:BitmapData = bitmap_obj.bitmapData;

// ------------------------------------------------------------
// 線のテクスチャ塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 30;
// テクスチャの行列
var texture_mtx:Matrix = new Matrix();
// タイリング描画の有無
var texture_repeat:Boolean = false;
// スムージングの有無
var texture_smooth:Boolean = true;

// ------------------------------------------------------------
// テクスチャの行列
// ------------------------------------------------------------
// 単位行列化
texture_mtx.identity();
// 拡大縮小成分を乗算
texture_mtx.scale( 1.0 , 1.0 );
// 角度成分を乗算
texture_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
texture_mtx.translate( 0.0 , 0.0 );

// ------------------------------------------------------------
// 線の基礎的なスタイルを指定する
// ------------------------------------------------------------
g.lineStyle( thickness );

// ------------------------------------------------------------
// 線に「テクスチャ塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineBitmapStyle( bitmap_data , texture_mtx , texture_repeat , texture_smooth );

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
var i:int = 0;
for(i=0;i < 16;i++){

	var pos_y:Number = i * 32.0 + 16.0;

	// 開始位置
	g.moveTo (   0.0 , pos_y );
	// 直線を描画
	g.lineTo ( 512.0 , pos_y );
}

<languageVersion : 1.0;>

// ------------------------------------------------------------
// カーネルを宣言
// ------------------------------------------------------------
kernel MyKernel < namespace:""; vendor:""; version:1; > {

	// ------------------------------------------------------------
	// 出力変数の宣言（ピクセルカラー）
	// ------------------------------------------------------------
	output pixel4 dst;

	// ------------------------------------------------------------
	// ピクセルごとに実行される関数
	// ------------------------------------------------------------
	void evaluatePixel() {

		// 現在のピクセル位置を取得する
		float2 pos = outCoord();

		// x座標値を赤色、y座標値を青色に変換
		pixel4 color;
		color.r = pos.x / 255.0;
		color.g = 0.0;
		color.b = pos.y / 255.0;
		color.a = 1.0;

		// ピクセルカラーを出力する
		dst = color;
	}
}

import flash.utils.ByteArray;
import flash.display.Shader;
import flash.display.Shape;
import flash.display.Graphics;
import flash.geom.Matrix;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 埋め込みアセットクラス
// ------------------------------------------------------------
[Embed( source="./style.pbj" , mimeType="application/octet-stream" )]
var MyByteCode:Class;

// ------------------------------------------------------------
// 埋め込んだファイルから、ByteArray オブジェクトを作成する (自作クラス "MyByteCode" )
// ------------------------------------------------------------
var byte_code:ByteArray = new MyByteCode();

// ------------------------------------------------------------
// 線のシェーダー塗り設定
// ------------------------------------------------------------
// 線の太さ (0 ～ 255) (0 で極細線)
var thickness:Number = 30;
// Shader オブジェクトを作成
var shader_obj:Shader = new Shader(byte_code);
// シェーダーの行列
var shader_mtx:Matrix = new Matrix();

// ------------------------------------------------------------
// シェーダーの行列
// ------------------------------------------------------------
// 単位行列化
shader_mtx.identity();
// 拡大縮小成分を乗算
shader_mtx.scale( 1.0 , 1.0 );
// 角度成分を乗算
shader_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
shader_mtx.translate( 0.0 , 0.0 );

// ------------------------------------------------------------
// 線の基礎的なスタイルを指定する
// ------------------------------------------------------------
g.lineStyle( thickness );

// ------------------------------------------------------------
// 線に「シェーダー塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineShaderStyle( shader_obj , shader_mtx );

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
var i:int = 0;
for(i=0;i < 8;i++){

	var pos_y:Number = i * 32.0 + 16.0;

	// 開始位置
	g.moveTo (   0.0 , pos_y );
	// 直線を描画
	g.lineTo ( 256.0 , pos_y );
}

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineStyle (10 , 0x000000 , 1.0);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
g.moveTo (  20.0 ,  10.0 );
// 直線を描画
g.lineTo ( 420.0 ,  10.0 );

// ------------------------------------------------------------
// 線の描画スタイルをリセットする（引数を省略した場合）
// ------------------------------------------------------------
g.lineStyle ();

// ------------------------------------------------------------
// 面に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.beginFill ( 0xff8800 , 1.0 );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
g.drawRect( 20 , 20, 400, 300 );

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 面に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.beginFill ( 0xff8800 , 1.0 );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
g.drawRect( 20 , 20, 400, 300 );

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 面のグラデーション塗り設定
// ------------------------------------------------------------
// グラデーションの種類
var gradient_type:String = GradientType.RADIAL;
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [      1.0 ,      1.0 ,      1.0 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = SpreadMethod.PAD;
// 補間の種類
var interpolation_method:String = InterpolationMethod.LINEAR_RGB;
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// グラデーションの行列
// ------------------------------------------------------------
// 単位行列化
gradient_mtx.identity();
// 拡大縮小成分を乗算
gradient_mtx.scale( 256/1638.4 , 256/1638.4 );
// 角度成分を乗算
gradient_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
gradient_mtx.translate( 128.0 , 128.0 );

// ------------------------------------------------------------
// 面に「グラデーション塗り」スタイルを指定する
// ------------------------------------------------------------
g.beginGradientFill( gradient_type , gradient_colors , gradient_alphas , gradient_ratios , gradient_mtx , spread_method , interpolation_method , focal_point_ratio );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
var i:int = 0;
for(i=0;i < 8;i++){

	var pos_y:Number = i * 32.0;

	// 矩形を描画
	g.drawRect( 0.0 , pos_y , 256.0 , 30.0 );
}

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.geom.Rectangle;
import flash.geom.Matrix;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 矩形
// ------------------------------------------------------------
var rect:Rectangle = new Rectangle( 10 , 10 , stage.stageWidth - 20 , stage.stageHeight - 20 );

// ------------------------------------------------------------
// 面のグラデーション塗り設定
// ------------------------------------------------------------
// グラデーションの種類
var gradient_type:String = GradientType.RADIAL;
// グラデーション
var gradient_colors:Array = [ 0xff0000 , 0x00ff00 , 0x0000ff ];	// RGB カラーリスト
var gradient_alphas:Array = [      1.0 ,      1.0 ,      1.0 ];	// 透明度リスト
var gradient_ratios:Array = [        0 ,    127.5 ,      255 ];	// 配分リスト
// グラデーションの行列
var gradient_mtx:Matrix = new Matrix();
// スプレッドの種類
var spread_method:String = SpreadMethod.PAD;
// 補間の種類
var interpolation_method:String = InterpolationMethod.LINEAR_RGB;
// 焦点位置 (-1.0 ～ 1.0)
var focal_point_ratio:Number = 0.0;

// ------------------------------------------------------------
// 毎フレーム実行されるイベント
// ------------------------------------------------------------
stage.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

	// ------------------------------------------------------------
	// 矩形の右下端をマウス座標にフィット
	// ------------------------------------------------------------
	rect.width  = stage.mouseX - rect.x;
	rect.height = stage.mouseY - rect.y;

	// ------------------------------------------------------------
	// グラデーションの行列
	// ------------------------------------------------------------
	// 中間座標
	var pos_x:Number = rect.x + rect.width  * 0.5;
	var pos_y:Number = rect.y + rect.height * 0.5;

	// 単位行列化
	gradient_mtx.identity();
	// 拡大縮小成分を乗算
	gradient_mtx.scale(rect.width/1638.4 , rect.height/1638.4);
	// 角度成分を乗算
	gradient_mtx.rotate(0.0 * (Math.PI / 180));
	// 移動成分を乗算
	gradient_mtx.translate(pos_x , pos_y);

	// ------------------------------------------------------------
	// 描画済みグラフィックをすべてクリアする
	// ------------------------------------------------------------
	g.clear();

	// ------------------------------------------------------------
	// 面に「グラデーション塗り」スタイルを指定する
	// ------------------------------------------------------------
	g.beginGradientFill(
		gradient_type,
		gradient_colors,
		gradient_alphas,
		gradient_ratios,
		gradient_mtx,
		spread_method,
		interpolation_method,
		focal_point_ratio
	);

	// ------------------------------------------------------------
	// 矩形を描画する
	// ------------------------------------------------------------
	g.drawRect( rect.x , rect.y , rect.width , rect.height );

});

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Matrix;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 埋め込みアセットクラス
// ------------------------------------------------------------
[Embed( source="./texture.png" )]
var MyBitmap:Class;

// ------------------------------------------------------------
// 埋め込んだ画像ファイルから、BitmapData オブジェクトを作成する (自作クラス "MyBitmap" )
// ------------------------------------------------------------
var bitmap_obj:Bitmap = new MyBitmap();
var bitmap_data:BitmapData = bitmap_obj.bitmapData;

// ------------------------------------------------------------
// 面のテクスチャ塗り設定
// ------------------------------------------------------------
// テクスチャの行列
var texture_mtx:Matrix = new Matrix();
// タイリング描画の有無
var texture_repeat:Boolean = false;
// スムージングの有無
var texture_smooth:Boolean = true;

// ------------------------------------------------------------
// テクスチャの行列
// ------------------------------------------------------------
// 単位行列化
texture_mtx.identity();
// 拡大縮小成分を乗算
texture_mtx.scale( 1.0 , 1.0 );
// 角度成分を乗算
texture_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
texture_mtx.translate( 0.0 , 0.0 );

// ------------------------------------------------------------
// 面に「テクスチャ塗り」スタイルを指定する
// ------------------------------------------------------------
g.beginBitmapFill( bitmap_data , texture_mtx , texture_repeat , texture_smooth );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
var i:int = 0;
for(i=0;i < 16;i++){

	var pos_y:Number = i * 32.0;

	// 矩形を描画
	g.drawRect( 0.0 , pos_y , 512.0 , 30.0 );

}

<languageVersion : 1.0;>

// ------------------------------------------------------------
// カーネルを宣言
// ------------------------------------------------------------
kernel MyKernel < namespace:""; vendor:""; version:1; > {

	// ------------------------------------------------------------
	// 出力変数の宣言（ピクセルカラー）
	// ------------------------------------------------------------
	output pixel4 dst;

	// ------------------------------------------------------------
	// ピクセルごとに実行される関数
	// ------------------------------------------------------------
	void evaluatePixel() {

		// 現在のピクセル位置を取得する
		float2 pos = outCoord();

		// x座標値を赤色、y座標値を青色に変換
		pixel4 color;
		color.r = pos.x / 255.0;
		color.g = 0.0;
		color.b = pos.y / 255.0;
		color.a = 1.0;

		// ピクセルカラーを出力する
		dst = color;
	}
}

import flash.utils.ByteArray;
import flash.display.Shader;
import flash.display.Shape;
import flash.display.Graphics;
import flash.geom.Matrix;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 埋め込みアセットクラス
// ------------------------------------------------------------
[Embed( source="./style.pbj" , mimeType="application/octet-stream" )]
var MyByteCode:Class;

// ------------------------------------------------------------
// 埋め込んだファイルから、ByteArray オブジェクトを作成する (自作クラス "MyByteCode" )
// ------------------------------------------------------------
var byte_code:ByteArray = new MyByteCode();

// ------------------------------------------------------------
// 面のシェーダー塗り設定
// ------------------------------------------------------------
// Shader オブジェクトを作成
var shader_obj:Shader = new Shader(byte_code);
// シェーダーの行列
var shader_mtx:Matrix = new Matrix();

// ------------------------------------------------------------
// シェーダーの行列
// ------------------------------------------------------------
// 単位行列化
shader_mtx.identity();
// 拡大縮小成分を乗算
shader_mtx.scale( 1.0 , 1.0 );
// 角度成分を乗算
shader_mtx.rotate( 0.0 * (Math.PI / 180) );
// 移動成分を乗算
shader_mtx.translate( 0.0 , 0.0 );

// ------------------------------------------------------------
// 面に「シェーダー塗り」スタイルを指定する
// ------------------------------------------------------------
g.beginShaderFill( shader_obj , shader_mtx );

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
var i:int = 0;
for(i=0;i < 8;i++){

	var pos_y:Number = i * 32.0;

	// 矩形を描画
	g.drawRect( 0.0 , pos_y , 256.0 , 30.0 );

}

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineStyle (1 , 0x000000 , 1.0);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
g.moveTo (  20.0 ,  40.0 );
// 直線を描画
g.lineTo ( 200.0 , 100.0 );

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineStyle (1 , 0x000000 , 1.0);

// ------------------------------------------------------------
// 直線を描画する
// ------------------------------------------------------------
// 開始位置
g.moveTo (  20.0 ,  40.0 );
// 直線を描画
g.lineTo ( 100.0 , 100.0 );
// 直線を描画
g.lineTo ( 200.0 ,  80.0 );
// 直線を描画
g.lineTo ( 300.0 , 150.0 );

import flash.display.Shape;
import flash.display.Graphics;
import flash.geom.Point;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineStyle (1 , 0x000000 , 1.0);

// ------------------------------------------------------------
// ２次ベジェ曲線を描画する
// ------------------------------------------------------------
// ３つの座標
var pos0:Point = new Point(  20.0 , 280.0 );
var pos1:Point = new Point( 150.0 ,  20.0 );
var pos2:Point = new Point( 400.0 , 150.0 );

// 開始位置
g.moveTo ( pos0.x,pos0.y );
// ２次ベジェ曲線を描画
g.curveTo ( pos1.x,pos1.y , pos2.x,pos2.y );

import flash.display.Shape;
import flash.display.Graphics;
import flash.geom.Point;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
// ------------------------------------------------------------
g.lineStyle (1 , 0x000000 , 1.0);

// ------------------------------------------------------------
// ３次ベジェ曲線を描画する
// ------------------------------------------------------------
// ４つの座標
var pos0:Point = new Point(  20.0 , 280.0 );
var pos1:Point = new Point( 140.0 ,  40.0 );
var pos2:Point = new Point( 300.0 , 300.0 );
var pos3:Point = new Point( 380.0 ,  20.0 );

// 開始位置
g.moveTo ( pos0.x,pos0.y );
// ３次ベジェ曲線を描画
g.cubicCurveTo ( pos1.x,pos1.y , pos2.x,pos2.y , pos3.x,pos3.y );

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.LineScaleMode;
import flash.display.CapsStyle;
import flash.display.JointStyle;
import flash.geom.Point;
import flash.events.Event;
import flash.events.MouseEvent;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

(function():void{

	// マウス座標のリスト
	var mouse_pos_list:Array = new Array();

	// ------------------------------------------------------------
	// マウスの左ボタンを押すと実行されるイベント
	// ------------------------------------------------------------
	stage.addEventListener(MouseEvent.MOUSE_DOWN , function (e:MouseEvent):void {
		// マウスカーソルの位置を取得
		var pos:Point = new Point(e.localX , e.localY);
		// 座標リストを初期化 (要素数:1)
		mouse_pos_list = [pos];
	});

	// ------------------------------------------------------------
	// マウスの左ボタンを離すと実行されるイベント
	// ------------------------------------------------------------
	stage.addEventListener(MouseEvent.MOUSE_UP , function (e:MouseEvent):void {
		// 座標リストをクリア (要素数:0)
		mouse_pos_list = new Array();
	});

	// ------------------------------------------------------------
	// マウスカーソルを移動すると実行されるイベント
	// ------------------------------------------------------------
	stage.addEventListener(MouseEvent.MOUSE_MOVE , function (e:MouseEvent):void {
		// ドラッグ操作中か
		if(mouse_pos_list.length < 1) return;

		// マウスカーソルの位置を取得
		var pos:Point = new Point(e.localX , e.localY);
		// 座標リストに追加
		mouse_pos_list.push(pos);
	});

	// ------------------------------------------------------------
	// 毎フレーム実行されるイベント
	// ------------------------------------------------------------
	stage.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

		// ------------------------------------------------------------
		// 座標リストの総数
		// ------------------------------------------------------------
		var num:int = mouse_pos_list.length
		if(num < 2) return;

		// ------------------------------------------------------------
		// 線に「単一色塗り」スタイルを指定する
		// ------------------------------------------------------------
		g.lineStyle ( 5 , 0x000000 , 1.0 , true , LineScaleMode.NORMAL , CapsStyle.ROUND , JointStyle.ROUND );

		// ------------------------------------------------------------
		// 開始位置を指定する
		// ------------------------------------------------------------
		var pos:Point = mouse_pos_list[0];
		g.moveTo ( pos.x , pos.y );

		// ------------------------------------------------------------
		// 連続で直線を描画する
		// ------------------------------------------------------------
		var i:int;
		for(i=1;i < num;i++){
			pos = mouse_pos_list[i];

			// 直線を描画する
			g.lineTo ( pos.x , pos.y );
		}

		// ------------------------------------------------------------
		// 座標リストを初期化する
		// ------------------------------------------------------------
		mouse_pos_list = [pos];
	});

})();

import flash.display.Shape;
import flash.display.Graphics;
import flash.geom.Point;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 描画パスで囲んで面を描画する
// ------------------------------------------------------------
// 描画パスを開始する
g.moveTo ( 25.0 , 100.0 );

// 描画パスを指定して囲む
g.lineTo (  75.0 ,  35.0 );
g.lineTo ( 165.0 ,  55.0 );
g.lineTo ( 325.0 ,  25.0 );
g.lineTo ( 375.0 ,  95.0 );
g.lineTo ( 265.0 , 165.0 );
g.lineTo ( 205.0 , 135.0 );
g.lineTo (  75.0 , 165.0 );

// 描画パスを閉じて、塗りつぶしを確定する
g.endFill ();

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// 正多角形を描画する関数
// ------------------------------------------------------------
function GraphicsDrawRegularPolygon (g:Graphics , x:Number , y:Number , radius:Number , vertex:uint , angle:Number ):Boolean {

	if(vertex < 3) return false;

	angle -= Math.PI * 0.5;
	g.moveTo (
		x + Math.cos(angle) * radius,
		y + Math.sin(angle) * radius
	);

	var a:Number = 1 / vertex * Math.PI * 2;
	var i:int;
	for(i=0;i < vertex;i++){
		angle += a;
		g.lineTo(
			x + Math.cos(angle) * radius,
			y + Math.sin(angle) * radius
		);
	}

	return true;
}


// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 正多角形を描画する
// ------------------------------------------------------------
GraphicsDrawRegularPolygon ( g , 120.0 , 150.0 , 100.0 , 5 ,  15.0 * (Math.PI/180) );
GraphicsDrawRegularPolygon ( g , 350.0 , 150.0 ,  80.0 , 7 ,   0.0 * (Math.PI/180) );

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// 星を描画する関数
// ------------------------------------------------------------
function GraphicsDrawStar (g:Graphics , x:Number , y:Number , radius:Number , vertex:uint , angle:Number , indent:Number ):Boolean {

	if(vertex < 3) return false;

	vertex *= 2;
	angle -= Math.PI * 0.5;
	g.moveTo (
		x + Math.cos(angle) * radius,
		y + Math.sin(angle) * radius
	);

	var a:Number = 1 / vertex * Math.PI * 2;
	var r:Number;
	var i:int;
	for(i=0;i < vertex;i++){
		angle += a;
		r = (i % 2) ? (radius):(radius * indent);
		g.lineTo(
			x + Math.cos(angle) * r,
			y + Math.sin(angle) * r
		);
	}

	return true;
}


// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 星を描画する
// ------------------------------------------------------------
GraphicsDrawStar ( g , 120.0 , 150.0 , 100.0 , 5 ,  15.0 * (Math.PI/180) , 0.5 );
GraphicsDrawStar ( g , 350.0 , 150.0 ,  80.0 , 7 ,   0.0 * (Math.PI/180) , 0.8 );

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 円を描画する
// ------------------------------------------------------------
g.drawCircle ( 200.0 , 150.0 , 100.0 );

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 楕円を描画する
// ------------------------------------------------------------
g.drawEllipse ( 10.0 , 10.0 , 250.0 , 150.0 );

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 矩形を描画する
// ------------------------------------------------------------
g.drawRect ( 10.0 , 10.0 , 250.0 , 150.0 );

import flash.display.Shape;
import flash.display.Graphics;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 角丸矩形を描画する
// ------------------------------------------------------------
g.drawRoundRect ( 10.0 , 10.0 , 250.0 , 150.0 , 60.0 , 40.0 );

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.TriangleCulling;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 頂点バッファを用意する
// ------------------------------------------------------------
var vertices:Vector.<Number> = Vector.<Number>([

	// １つ目の三角形
	 35.0,  50.0, // １つ目の座標 (x,y)
	205.0,  35.0, // ２つ目の座標 (x,y)
	135.0, 165.0, // ３つ目の座標 (x,y)

	// ２つ目の三角形
	325.0,  35.0, // １つ目の座標 (x,y)
	405.0, 145.0, // ２つ目の座標 (x,y)
	225.0, 165.0  // ３つ目の座標 (x,y)

]);

// ------------------------------------------------------------
// トライアングルリストを描画する
// ------------------------------------------------------------
g.drawTriangles ( vertices , null , null , TriangleCulling.NONE );

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.TriangleCulling;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// 描画スタイルを指定する
// ------------------------------------------------------------
// 線に「単一色塗り」スタイルを指定する
g.lineStyle (5 , 0x000000 , 1.0);
// 面に「単一色塗り」スタイルを指定する
g.beginFill (0x808080 , 1.0);

// ------------------------------------------------------------
// 頂点バッファを用意する
// ------------------------------------------------------------
var vertices:Vector.<Number> = Vector.<Number>([
	 35.0,  35.0, // 0 番目の座標 (x,y)
	165.0,  40.0, // 1 番目の座標 (x,y)
	330.0,  30.0, // 2 番目の座標 (x,y)
	 45.0, 180.0, // 3 番目の座標 (x,y)
	185.0, 185.0, // 4 番目の座標 (x,y)
	335.0, 165.0, // 5 番目の座標 (x,y)
	 55.0, 310.0, // 6 番目の座標 (x,y)
	180.0, 320.0, // 7 番目の座標 (x,y)
	345.0, 315.0  // 8 番目の座標 (x,y)
]);

// ------------------------------------------------------------
// 頂点インデックスバッファを用意する
// ------------------------------------------------------------
var indices:Vector.<int> = Vector.<int>([
	0,1,3, // １つ目の三角形
	3,1,4, // ２つ目の三角形
	1,2,4, // ３つ目の三角形
	4,2,5, // ４つ目の三角形
	3,4,6, // ５つ目の三角形
	6,4,7, // ６つ目の三角形
	4,5,7, // ７つ目の三角形
	7,5,8  // ８つ目の三角形
]);

// ------------------------------------------------------------
// トライアングルリストを描画する
// ------------------------------------------------------------
g.drawTriangles ( vertices , indices , null , TriangleCulling.NONE );

import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.display.Graphics;
import flash.display.TriangleCulling;
import flash.display.StageScaleMode;
import flash.display.StageAlign;
import flash.geom.Vector3D;
import flash.geom.Matrix3D;
import flash.events.Event;

// ------------------------------------------------------------
// ステージの設定
// ------------------------------------------------------------
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;

// ------------------------------------------------------------
// ３Ｄのデータ
// ------------------------------------------------------------
var mesh_obj:Object = {
	vertex:{
		data:Vector.<Number>([
			-1.0, -1.0, -1.0,
			 1.0, -1.0, -1.0,
			-1.0,  1.0, -1.0,
			 1.0,  1.0, -1.0,
			-1.0, -1.0,  1.0,
			 1.0, -1.0,  1.0,
			-1.0,  1.0,  1.0,
			 1.0,  1.0,  1.0
		]),
		indices:[
			0,1,2,
			2,1,3,
			2,3,6,
			6,3,7,
			1,5,3,
			3,5,7,
			1,0,5,
			5,0,4,
			5,4,7,
			7,4,6,
			0,2,4,
			4,2,6
		]
	},
	uv:{
		data:[
			{ u:0.0, v:0.0 },
			{ u:0.5, v:0.0 },
			{ u:1.0, v:0.0 },
			{ u:0.0, v:0.5 },
			{ u:0.5, v:0.5 },
			{ u:1.0, v:0.5 },
			{ u:0.0, v:1.0 },
			{ u:0.5, v:1.0 },
			{ u:1.0, v:1.0 }
		],
		indices:[
			0,1,3,
			3,1,4,
			3,4,6,
			6,4,7,
			0,2,6,
			6,2,8,
			1,2,4,
			4,2,5,
			4,5,7,
			7,5,8,
			0,2,6,
			6,2,8
		]
	}
};

// ------------------------------------------------------------
// テクスチャを用意する
// ------------------------------------------------------------
var bitmap_data:BitmapData = (function():BitmapData{

	// BitmapData オブジェクトを作成する
	var bitmap_data:BitmapData = new BitmapData( 16 , 16 , true , 0x00000000 );

	// ノイズを描画する
	bitmap_data.noise(
		Math.floor(Math.random() * 0x7FFFFFFF),
		0,
		255,
		(BitmapDataChannel.ALPHA),
		true
	);

	return bitmap_data;
})();

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

(function():void{

	var i:int;
	var j:int;
	var k:int;
	var p:int;
	var mtx:Matrix3D;
	var vtx:Vector.<Number>;

	// メッシュの行列
	var mesh_mtx:Matrix3D = new Matrix3D();

	// カメラ行列
	var view_mtx:Matrix3D = new Matrix3D();

	// ３Ｄデータの参照
	var vertex_data:Vector.<Number> = (mesh_obj.vertex.data);
	var vertex_indices:Array = (mesh_obj.vertex.indices);
	var uv_data:Array = (mesh_obj.uv.data);
	var uv_indices:Array = (mesh_obj.uv.indices);

	// ------------------------------------------------------------
	// 毎フレーム実行されるイベント
	// ------------------------------------------------------------
	stage.addEventListener(Event.ENTER_FRAME , function (e:Event):void{

		// ------------------------------------------------------------
		// 少しずつ回転
		// ------------------------------------------------------------
		mesh_mtx.prependRotation (0.05, Vector3D.Z_AXIS);
		mesh_mtx.prependRotation (0.1 , Vector3D.X_AXIS);
		mesh_mtx.appendRotation  (1.0 , Vector3D.Y_AXIS);
		mesh_mtx.position = new Vector3D(0.0 , 0.0, 4.0);

		// ------------------------------------------------------------
		// 頂点データをカメラ座標系に変換
		// ------------------------------------------------------------
		vtx = new Vector.<Number>();
		mtx = view_mtx.clone();
		mtx.invert();
		mtx.prepend(mesh_mtx);
		mtx.transformVectors(vertex_data , vtx);

		// ------------------------------------------------------------
		// 投影変換とビューポート変換
		// ------------------------------------------------------------
		var fov:Number = 60; // 視野角
		var ofs_x:Number = stage.stageWidth  * 0.5;
		var ofs_y:Number = stage.stageHeight * 0.5;
		var scale:Number = 1 / Math.tan(fov * 0.5 * Math.PI / 180) * ofs_y;

		var num:int = vertex_data.length / 3;
		for(i=0;i < num;i++){
			p = i * 3;
			vtx[p + 0] = (vtx[p + 0] / vtx[p + 2]) * scale + ofs_x;
			vtx[p + 1] = (vtx[p + 1] / vtx[p + 2]) * scale + ofs_y;
		}

		// ------------------------------------------------------------
		// Z ソート
		// ------------------------------------------------------------
		var depths:Array = new Array();
		num = vertex_indices.length / 3;
		for(i=0;i < num;i++){
			p = i * 3;
			depths.push({
				z:(
					vtx[vertex_indices[p + 0] * 3 + 2] +
					vtx[vertex_indices[p + 1] * 3 + 2] +
					vtx[vertex_indices[p + 2] * 3 + 2]
				) / 3.0
			});
		}
		depths = depths.sortOn("z" , (Array.NUMERIC | Array.DESCENDING | Array.RETURNINDEXEDARRAY));

		// ------------------------------------------------------------
		// 奥から順番にバッファに出力
		// ------------------------------------------------------------
		var vertices:Vector.<Number> = new Vector.<Number>();
		var uvt_data:Vector.<Number> = new Vector.<Number>();

		num = vertex_indices.length / 3;
		for(i=0;i < num;i++){
			for(j=0;j < 3;j++){
				k = (depths[i] * 3) + j;
				p = vertex_indices[k] * 3;
				var uv:Object = uv_data[uv_indices[k]];
				vertices.push(vtx[p + 0]); // x
				vertices.push(vtx[p + 1]); // y
				uvt_data.push(uv.u); // u
				uvt_data.push(uv.v); // v
				uvt_data.push(1 / vtx[p + 2]); // t
			}
		}

		// ------------------------------------------------------------
		// 描画済みグラフィックをすべてクリアする
		// ------------------------------------------------------------
		g.clear();

		// ------------------------------------------------------------
		// 描画スタイルを指定する
		// ------------------------------------------------------------
		// 線に「単一色塗り」スタイルを指定する
		g.lineStyle (0 , 0x000000 , 1.0);
		// 面に「テクスチャ塗り」スタイルを指定する
		g.beginBitmapFill (bitmap_data , null , true , false);

		// ------------------------------------------------------------
		// トライアングルリストを描画する
		// ------------------------------------------------------------
		g.drawTriangles ( vertices , null , uvt_data , TriangleCulling.NONE );

	});

})();

import flash.display.Shape;
import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.IGraphicsData;

// ------------------------------------------------------------
// Document オブジェクト（メインタイムライン）を取得する
// ------------------------------------------------------------
var document_obj:Sprite = stage.getChildAt(0) as Sprite;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = function ():Shape{

	// Shape オブジェクトを作成
	var shape:Shape = new Shape();

	// Graphics オブジェクトを取得
	var g:Graphics = shape.graphics;

	// 線に「単一色塗り」スタイルを指定する
	g.lineStyle (5 , 0x000000 , 1.0);
	// 面に「単一色塗り」スタイルを指定する
	g.beginFill (0x808080 , 1.0);

	// 矩形を描画する
	g.drawRect ( 0.0 , 0.0 , 100.0 , 100.0 );

	return shape;
}();

// Document（メインタイムライン）に配置
document_obj.addChild(shape);

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = document_obj.graphics;

// ------------------------------------------------------------
// GraphicsData のリストを取得する
// ------------------------------------------------------------
var graphics_data_list:Vector.<IGraphicsData> = g.readGraphicsData(true);

// 出力テスト
trace(graphics_data_list);

import flash.display.Shape;
import flash.display.Graphics;
import flash.display.IGraphicsData;
import flash.display.GraphicsStroke;
import flash.display.GraphicsSolidFill;
import flash.display.GraphicsPath;
import flash.display.GraphicsEndFill;

// ------------------------------------------------------------
// Shape オブジェクトを作成
// ------------------------------------------------------------
var shape:Shape = new Shape();

// ステージに配置
stage.addChild(shape);

// ------------------------------------------------------------
// GraphicsData リストを用意する
// ------------------------------------------------------------
var graphics_data_list:Vector.<IGraphicsData> = function ():Vector.<IGraphicsData>{

	// ------------------------------------------------------------
	// 線の「単一色塗り」スタイル
	// ------------------------------------------------------------
	var style_stroke:GraphicsStroke = new GraphicsStroke();
 	style_stroke.thickness = 5;
	style_stroke.fill = new GraphicsSolidFill(0x000000 , 1.0);

	// ------------------------------------------------------------
	// 面の「単一色塗り」スタイル
	// ------------------------------------------------------------
	var style_fill_solid:GraphicsSolidFill = new GraphicsSolidFill();
 	style_fill_solid.color = 0x808080;
	style_fill_solid.alpha = 1.0;

	// ------------------------------------------------------------
	// 描画パスのコマンドと座標データ
	// ------------------------------------------------------------
	var draw_path:GraphicsPath = new GraphicsPath();
	draw_path.moveTo(219.9 , 123.5);
	draw_path.lineTo(147.5 , 216.1);
	draw_path.lineTo( 37.1 , 175.9);
	draw_path.lineTo( 41.2 ,  58.4);
	draw_path.lineTo(154.2 ,  26.0);
	draw_path.lineTo(219.9 , 123.5);

	// ------------------------------------------------------------
	// 描画パスを閉じて、塗りつぶしを確定
	// ------------------------------------------------------------
	var end_fill:GraphicsEndFill = new GraphicsEndFill();

	// ------------------------------------------------------------
	// GraphicsData リストを作成
	// ------------------------------------------------------------
	var list:Vector.<IGraphicsData> = new Vector.<IGraphicsData>();
	list.push(style_stroke);
	list.push(style_fill_solid);
	list.push(draw_path);
	list.push(end_fill);

	return list;
}();

// ------------------------------------------------------------
// Graphics オブジェクトを取得
// ------------------------------------------------------------
var g:Graphics = shape.graphics;

// ------------------------------------------------------------
// GraphicsData のリストを使って描画する
// ------------------------------------------------------------
g.drawGraphicsData(graphics_data_list);